Flash / ActionScript 3: Load .FLV-Datei in einen MovieClip, und beginnen Sie zu spielen, FLV Datei

Wie kann ich laden Sie eine FLV-Datei in einen MovieClip (nennen wir die Instanz "flvPlaceHolder") und beginnen Sie zu spielen, FLV Datei.. mit ActionScript 3?

InformationsquelleAutor cllpse | 2009-06-28

  1. 4

    Nicht explizit deine Frage zu beantworten, aber es gibt eine Reihe von open source FLV-Player in freier Wildbahn. Ich würde eine Lösung durch greifen einer von denen, und sehen, wie Sie zu behandeln, die Wiedergabe von video.

    FPlayer wäre ein guter Ausgangspunkt. Hier ist die Klasse , der die Arbeit macht. Es ist ziemlich geradlinig, aber mit einem Projekt wie diesem wäre wahrscheinlich sparen Sie etwas Zeit.

    Diesem snippet sollte den trick tun in einer sehr nackten Knochen fashion:

    var vid:Video = new Video(320, 240);
addChild(vid);

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);
vid.attachNetStream(ns);

var listener:Object = new Object();
listener.onMetaData = function(evt:Object):void {};
ns.client = listener;

ns.play("externalVideo.flv");

    von hier aus

    Danke. Aber.. Ja.. Hat nicht wirklich meine Frage beantworten 🙂
    fügte einen code-snippet.

    InformationsquelleAutor Joel Hooks

  2. 2

    Zu diesem lokal - cut und fügen Sie den folgenden code in den ersten frame deines flash-Datei. Natürlich ändern sich die Namen am Ende.

    stage.displayState = StageDisplayState.FULL_SCREEN; 

var connection:NetConnection = new NetConnection();
var stream:NetStream;
var video:Video = new Video(1280,960);
var metaObj:Object = new Object();

function onMetaData(data:Object):void
{

}

connection.connect(null);
stream = new NetStream(connection);
stream.client = metaObj;
metaObj.onMetaData = onMetaData;
video.attachNetStream(stream);
addChild(video);
stream.play("name_of_flv.flv");
video.x = 0;
video.y = 0;

    InformationsquelleAutor user171699

  3. 1

    Als subha darauf hingewiesen, dass es fertig ist mithilfe der NetStream-Klasse... aber diese Klasse im besonderen ist ziemlich hart, mit zu arbeiten, und sehr uncoherent mit dem rest der Sprache...

    Ich würde dringend empfehlen, dass Sie verwenden einige Bibliothek, die Klasse oder Komponente, um es einpacken. Die FLVPlayback-Komponente in Flash (ohne Felle) im Gegensatz zu allen anderen integrierten Komponenten in Flash, ist wirklich unkompliziert und sehr einfach zu bedienen 😉

    InformationsquelleAutor Cay

  4. 1
    var video:Video = new Video();
addChild(video);

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);
ns.client = {};
ns.client.onMetaData = ns_onMetaData;
ns.client.onCuePoint = ns_onCuePoint;
ns.play("http://www.helpexamples.com/flash/video/cuepoints.flv");

video.attachNetStream(ns);

function ns_onMetaData(item:Object):void {
    trace("metaData");
    //Resize video instance.
    video.width = item.width;
    video.height = item.height;
    //Center video instance on Stage.
    video.x = (stage.stageWidth - video.width) / 2;
    video.y = (stage.stageHeight - video.height) / 2;
}

function ns_onCuePoint(item:Object):void {
    trace("cuePoint");
    trace(item.name + "\t" + item.time);
}

    InformationsquelleAutor

  5. 0
    var flvPlaceHolder:MovieClip = new MovieClip();    

var vid:Video = new Video(320, 240);
flvPlaceHolder.addChild(vid);
addChild(flvPlaceHolder);
flvPlaceHolder.x = stage.stageWidth/2-vid.width/2;
flvPlaceHolder.y = stage.stageHeight/2-vid.height/2;

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);
vid.attachNetStream(ns);

var listener:Object = new Object();
listener.onMetaData = function(evt:Object):void {};
ns.client = listener;

ns.play("mario.flv");

    InformationsquelleAutor Benny

Schreibe einen Kommentar