Fügen Sie ein Element zum Array in VBScript hinzu

Wie fügen Sie ein Element zu einem vorhandenen array in VBScript?

Ist es ein VBScript-entspricht der push-Funktion in Javascript?

d.h.

myArray hat drei Elemente, "Äpfel", "Orangen", "Bananen" und ich möchte hinzufügen, "Wassermelonen", um das Ende des Arrays.

InformationsquelleAutor der Frage Choy | 2011-01-05

arrays vbscript

59

Arrays sind nicht sehr dynamisch in VBScript. Sie müssen verwenden Sie die ReDim Preserve Aussage zu wachsen, das vorhandene array, so kann es Platz für einen zusätzlichen Element:
```
ReDim Preserve yourArray(UBound(yourArray) + 1)
yourArray(UBound(yourArray)) = "Watermelons"
```
InformationsquelleAutor der Antwort Frédéric Hamidi

Gibt es ein paar Möglichkeiten, nicht einschließlich einer benutzerdefinierten COM-oder ActiveX-Objekt

ReDim Preserve
Dictionary-Objekt, die string-Tasten und die Suche nach Ihnen
ArrayList .Net Framework-Klasse, die viele Methoden, einschließlich:
Sortieren (vorwärts, rückwärts, Benutzerdefiniert), einfügen, entfernen,
binarysearch-Methode, gleich, toArray, und toString

Mit dem code unten, habe ich gefunden Redim Preserve ist am schnellsten unten, 54000, Wörterbuch schnellsten von 54000, 690000, und die Array-Liste ist am schnellsten oben 690000. Ich Neige dazu, verwenden ArrayList zu schieben, weil der Sortier-und array-Konvertierung.

user326639 zur Verfügung gestellt FastArray, das ist so ziemlich das Schnellste.

Wörterbücher sind nützlich bei der Suche für den Wert und die Rückkehr der index (also die Feldnamen), oder für die Gruppierung und aggregation (Histogramme, Gruppe und hinzufügen, Gruppe und verketten von strings, eine Gruppe und drücken Sie sub-arrays). Bei der Gruppierung auf den Tasten, eingestellt CompareMode für den Fall, in/Empfindlichkeit, und überprüfen Sie die "exists" - Eigenschaft, bevor Sie "hinzufügen"-ing.

Redim würde nicht sparen Sie viel Zeit für ein array, aber es ist nützlich für ein Wörterbuch von arrays.

'pushtest.vbs
imax = 10000
value = "Testvalue"
s = imax & " of """ & value & """" 

t0 = timer 'ArrayList Method
Set o = CreateObject("System.Collections.ArrayList")
For i = 0 To imax
  o.Add value
Next
s = s & "[AList " & FormatNumber(timer - t0, 3, -1) & "]"
Set o = Nothing

t0 = timer 'ReDim Preserve Method
a = array()
For i = 0 To imax
  ReDim Preserve a(UBound(a) + 1)
  a(UBound(a)) = value
Next
s = s & "[ReDim " & FormatNumber(timer - t0, 3, -1) & "]"
Set a = Nothing

t0 = timer 'Dictionary Method
Set o = CreateObject("Scripting.Dictionary")
For i = 0 To imax
  o.Add i, value
Next
s = s & "[Dictionary " & FormatNumber(timer - t0, 3, -1) & "]"
Set o = Nothing

t0 = timer 'Standard array
Redim a(imax)
For i = 0 To imax
  a(i) = value
Next
s = s & "[Array " & FormatNumber(timer - t0, 3, -1) & "]" & vbCRLF
Set a = Nothing

t0 = timer 'Fast array
a = array()
For i = 0 To imax
 ub = UBound(a)
 If i>ub Then ReDim Preserve a(Int((ub+10)*1.1))
 a(i) = value
Next
ReDim Preserve a(i-1)
s = s & "[FastArr " & FormatNumber(timer - t0, 3, -1) & "]"
Set a = Nothing

MsgBox s

'  10000 of "Testvalue" [ArrayList 0.156][Redim 0.016][Dictionary 0.031][Array 0.016][FastArr 0.016]
'  54000 of "Testvalue" [ArrayList 0.734][Redim 0.672][Dictionary 0.203][Array 0.063][FastArr 0.109]
' 240000 of "Testvalue" [ArrayList 3.172][Redim 5.891][Dictionary 1.453][Array 0.203][FastArr 0.484]
' 690000 of "Testvalue" [ArrayList 9.078][Redim 44.785][Dictionary 8.750][Array 0.609][FastArr 1.406]
'1000000 of "Testvalue" [ArrayList 13.191][Redim 92.863][Dictionary 18.047][Array 0.859][FastArr 2.031]

InformationsquelleAutor der Antwort Will

Für Ihre Kopie und paste Leichtigkeit

' add item to array
Function AddItem(arr, val)
    ReDim Preserve arr(UBound(arr) + 1)
    arr(UBound(arr)) = val
    AddItem = arr
End Function

Verwendet, wie so

a = Array()
a = AddItem(a, 5)
a = AddItem(a, "foo")

InformationsquelleAutor der Antwort Charles Clayton

3

Leichte Veränderung der FastArray von oben:
```
'pushtest.vbs
imax = 10000000
value = "Testvalue"
s = imax & " of """ & value & """" 

t0 = timer 'Fast array
a = array()
ub = UBound(a)
For i = 0 To imax
 If i>ub Then 
    ReDim Preserve a(Int((ub+10)*1.1))
    ub = UBound(a)
 End If
 a(i) = value
Next
ReDim Preserve a(i-1)
s = s & "[FastArr " & FormatNumber(timer - t0, 3, -1) & "]"

MsgBox s
```
Gibt es keinen Punkt in der Prüfung UBound(a) in jedem Zyklus der, wenn wir genau wissen, Wann es änderungen.

Habe ich es geändert, so dass es überprüft hat UBound(a) kurz vor dem für beginnt und dann nur jedes mal die ReDim heißt

Auf meinem computer die alte Methode nahm 7.52 Sekunden für einen imax von 10 Millionen.

Die neue Methode nahm 5.29 Sekunden für einen imax von 10 Millionen, das bedeutet eine Leistungssteigerung von über 20% (für 10 Millionen wird versucht, offensichtlich ist dieser Prozentsatz hat eine direkte Beziehung zu der Anzahl der versuche)

InformationsquelleAutor der Antwort cog

dies eine Art von spät aber trotzdem und es ist auch etwas schwierig

 dim arrr 
  arr= array ("Apples", "Oranges", "Bananas")
 dim temp_var 
 temp_var = join (arr , "||") ' some character which will not occur is regular strings 
 if len(temp_var) > 0 then 
  temp_var = temp_var&"||Watermelons" 
end if 
arr  = split(temp_var , "||") ' here you got new elemet in array ' 
for each x in arr
response.write(x & "<br />")
next'

abgeben und mir sagen, ob das funktionieren kann
oder zunächst speichern Sie alle Daten in string und später aufgeteilt für die array

InformationsquelleAutor der Antwort ddw147

Nicht eine Antwort Oder Warum 'tricky' ist schlecht:

>> a = Array(1)
>> a = Split(Join(a, "||") & "||2", "||")
>> WScript.Echo a(0) + a(1)
>>
12

InformationsquelleAutor der Antwort Ekkehard.Horner

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.