Funktion-Zeiger-arrays in Fortran

Erklärung "real, external :: f" nicht wirklich "f" in eine volle Zeiger, da können Sie nicht ändern Sie die Prozedur, dass es Punkte -- ist es erlaubt die übergabe dieser Funktion an eine andere routine., So müssen Sie auch die "Zeiger" - Attribut. Es gibt Beispiele auf Seite 267 "Fortran 95/2003 explained" von Metcalf, Reid & Cohen -- eine google-Suche nach "fortran-Prozedur-Zeiger" wird die Seite aufzurufen. Ein einfaches Beispiel, in der Nähe zu verkaufen ist "Reale, externe, pointer :: f_ptr". Alternativ: "- Verfahren (f), pointer :: f_ptr". Dies ist eine Fortran 2003-feature -- http://gcc.gnu.org/wiki/Fortran2003 und http://gcc.gnu.org/wiki/ProcedurePointers Listen partielle Unterstützung in gfortran, am besten mit 4.5. Ich bin mir nicht sicher, ob "dimension" ist, direkt erlaubt, aber Sie können zuweisen einer Prozedur auf einen Zeiger, das bietet viel Flexibilität. Sie können auch den Zeiger in einen abgeleiteten Typ, die in ein array.

Edit: hier ist ein code Beispiel, das funktioniert mit gfortran 4.5:
Edit 2: Zeile auskommentiert pro Kommentare unten.

module ExampleFuncs

  implicit none

contains

function f1 (x)
  real :: f1
  real, intent (in) :: x

  f1 = 2.0 * x

  return
end function f1


function f2 (x)
   real :: f2
   real, intent (in) :: x

   f2 = 3.0 * x**2

   return
end function f2


function fancy (func, x)

   real :: fancy
   real, intent (in) :: x

   interface AFunc
      function func (y)
         real :: func
         real, intent (in) ::y
      end function func
   end interface AFunc

   fancy = func (x) + 3.3 * x

end function fancy

end module  ExampleFuncs

program test_proc_ptr

  use ExampleFuncs

  implicit none

  ! REMOVE: pointer :: func
  interface
     function func (z)
        real :: func
        real, intent (in) :: z
     end function func
  end interface

  procedure (func), pointer :: f_ptr => null ()

  type Contains_f_ptr
     procedure (func), pointer, nopass :: my_f_ptr
  end type Contains_f_ptr

  type (Contains_f_ptr), dimension (2) :: NewType


  f_ptr => f1
  write (*, *) f_ptr (2.0)
  write (*, *) fancy (f_ptr, 2.0)

  f_ptr => f2
  write (*, *) f_ptr (2.0)
  write (*, *) fancy (f_ptr, 2.0)

  NewType(1) % my_f_ptr => f1
  NewType(2) % my_f_ptr => f2

  write (*, *) NewType(1) % my_f_ptr (3.0), NewType(2) % my_f_ptr (3.0)

  stop

end program test_proc_ptr