Gewusst wie: füllen Sie die Daten aus .txt-Datei in Excel in VBA?

Ich versuche etwas zu schaffen, das zum Lesen von Daten von einem .txt-Datei, dann füllen Sie die Daten in .xls, aber nach öffnen der .txt Datei, wie bekomme ich die Daten aus? Grundsätzlich bin ich versucht zu bekommen, der die Dritte Spalte die Zeilen, datiert "04/06/2010'. Nachdem ich öffnen .txt-Datei, wenn ich ActiveSheet.Cells(row, col), die ActiveSheet ist nicht auf .txt-Datei.

Meine .txt-Datei ist wie folgt (Leerzeichen getrennt):

04/05/10 23 29226
04/05/10 24 26942
04/06/10 1 23166
04/06/10 2 22072
04/06/10 3 21583
04/06/10 4 21390

Hier ist der code den ich habe:

Dim BidDate As Date

BidDate = '4/6/2010'

Workbooks.OpenText Filename:=ForecastFile, StartRow:=1, DataType:=xlDelimited, Space:=True

If Err.Number = 1004 Then
    MsgBox ("The forecast file " & ForecastFile & " was not found.")
    Exit Sub
End If

On Error GoTo 0


Dim row As Integer, col As Integer


row = 1
col = 1

cell_value = activeSheet.Cells(row, col)
MsgBox ("the cell_value=" & cell_value)

Do While (cell_value  <> BidDate) And (cell_value <> "")
    row = row + 1
    cell_value = activeSheet.Cells(row, col)
   ' MsgBox ("the value is " & cell_value)
Loop

If cell_value = "" Then
    MsgBox ("A load forecast for " & BidDate & " was not found in your current load forecast file titled '" + ForecastFile + ". " + "Make sure you have a load forecast for the current bid date and then open this spreadsheet again.")
    ActiveWindow.Close
    Exit Sub
End If

Kann jeder Punkt aus, wo es geht hier falsch?

InformationsquelleAutor swei | 2010-04-05

Unten im Beispiel habe ich die variable ws gleich dem Blatt ich will und ich bin in der Lage, verwenden Sie die variable zu finden, um das Blatt später. Das Schlüsselwort ActiveWorkbook sollte zeigen Sie auf der neu geöffneten text-Datei. Ich konnte sagen, was Sie tun wollten, mit der info, wie ich Sie gerade gemacht ein paar Sachen.

Sub GetBidData()

    Dim dtBid As Date
    Dim ws As Worksheet
    Dim rFound As Range
    Dim sFile As String

    dtBid = #4/6/2010#
    sFile = Environ("USERPROFILE") & "\My Documents\ForecastFile.txt"

    Workbooks.OpenText Filename:=sFile, _
        StartRow:=1, _
        DataType:=xlDelimited, _
        Space:=True
    Set ws = ActiveWorkbook.Sheets(1)

    Set rFound = ws.Columns(1).Find( _
        Format(dtBid, ws.Range("A1").NumberFormat), , xlValues, xlWhole)

    If Not rFound Is Nothing Then
        MsgBox rFound.Value & vbCrLf & _
            rFound.Offset(0, 1).Value & vbCrLf & _
            rFound.Offset(0, 2).Value
    End If

End Sub

Ich sollte hinzufügen, dass ich nicht begegnen Fehler mit dem code, es hat einfach nicht scheinen, nichts zu tun.

InformationsquelleAutor Dick Kusleika

0

Generell sollten Sie vermeiden, mit der ActiveWorkbook-Objekt, es sei denn, Sie sind sicher, dass die Arbeitsmappe, die Sie verweisen möchten, wird immer aktiv, wenn der code ausgeführt wird. Stattdessen sollten Sie die Arbeitsmappe, die Sie gerade arbeiten mit einer Variablen. Theoretisch sollten Sie in der Lage sein zu verwenden, die OpenText-Methode, um dies zu tun, aber VBA nicht so. (Ich bin mir ziemlich sicher, dass es ein bug ist.) Also, gleich nachdem Sie öffnen Sie Ihren text-Datei, ich würde dies tun:
```
Workbooks.OpenText Filename:=Forecastfile, StartRow:=1, 
    DataType:=xlDelimited, Space:=True

Dim ForecastWorkbook As Workbook, book As Workbook
Dim ForecastFileName As String

ForecastFileName = "YourFileNameHere.txt"

For Each book In Application.Workbooks

    If book.Name = ForecastFileName Then

        Set ForecastWorkbook = book
        Exit For

    End If

Next book
```
Dann, statt dieser...
```
cell_value = activeSheet.Cells(row, col)
```
...dies tun...
```
cell_value = ForecastWorkbook.Sheets(1).Cells(row, col).Value
```
InformationsquelleAutor Nick Spreitzer

Folgende code liest die Textdatei und einfügen der Werte in die Zelle der Tabelle2. Allerdings, wenn Sie eine Formatierung in der Spalte Datum wird den trick tun

Public Sub Read_text()
Sheet2.Activate
Set fso = New FileSystemObject
Fname = Application.GetOpenFilename
x = 1
y = 1
Set Stream = fso.OpenTextFile(Fname, ForReading, True)
Do While Not Stream.AtEndOfStream
          Str_text = Stream.ReadLine 'Perform your actions
          rdtext = Split(Str_text, " ")
          Sheet2.Cells(x, y) = rdtext(0)
          Sheet2.Cells(x, y + 1) = rdtext(1)
          Sheet2.Cells(x, y + 2) = rdtext(2)
          x = x + 1
          y = 1
Loop
Stream.Close
End Sub

Beispiel : im folgenden code wird das format ändern, in '05/04/2010'

Sheet2.Cells(x, y) = Format(rdtext(0), "mm/dd/yyyy;@")

Es ist immer auch begründen Sie Ihre Antwort, anstatt nur dump code.

InformationsquelleAutor nishit dey

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.