Gnuplot plot-2D-matrix mit Bild, wollen, ziehen Grenzen für jede Zelle

Für Ihren Fall können Sie einen kleinen tic, die liegt dann auf der Grenze zwischen zwei Pixeln, und zeichnen Sie ein raster auf Sie:

set size ratio 1
set palette gray negative
set autoscale xfix
set autoscale yfix
set xtics 1
set ytics 1
set title "Resolution Matrix for E"

set tics scale 0,0.001
set mxtics 2
set mytics 2
set grid front mxtics mytics lw 1.5 lt -1 lc rgb 'white'
plot "Mat" matrix w image noti

Beachten Sie, dass set grid front bringt auch die tics auf der Vorderseite. Um zu vermeiden, dass Sie skaliert werden können, die tics zu 0. Für die kleine tics, die Sie verwenden müssen, eine sehr kleine Zahl, die 0 würde das weglassen der Gitter-Linien auf der minor tics.

Das Ergebnis mit 4.6.3 wird:

EDIT: um die Rasterlinien und tic-Etiketten unabhängig, können Sie die unbenutzte x2 und y2 zum zeichnen des Rasters (inspiriert durch eine Antwort auf Wie erstelle ich eine vertikale Linie in der gnuplot?):

set size ratio 1
set palette gray negative
# grid lines
set x2tics 1 format '' scale 0,0.001
set y2tics 1 format '' scale 0,0.001
set mx2tics 2
set my2tics 2

# labeling
set xtics 5 out nomirror
set ytics 5 out nomirror

set grid front mx2tics my2tics lw 1.5 lt -1 lc rgb 'white'

set xrange[-0.5:39.5]
set yrange[-0.5:39.5]
set x2range[-0.5:39.5]
set y2range[-0.5:39.5]

plot "Mat" matrix w image notitle

Mit gnuplot version 4.6, dies erfordert die Festlegung expliziter reicht, so dass die x und x2 (unbenutzt!) gleich sind. Die Informationen können extrahiert werden, die mit stats aus der Daten-Datei.

Version 5 ermöglicht die Verwendung von set link. Statt alle set *range Zeug. Sie verwenden könnten:

set autoscale fix
set link x
set link y

Ergebnis:

InformationsquelleAutor Christoph