Goto war unerwartet zu diesem Zeitpunkt batch-windows 7 starter

Dieser code wurde entwickelt, um ähneln eine einfachere version von Pokemon battle gameplay. Ich habe nur codiert in den Angriffen. Ich habe getestet, und festgestellt, dass eine Fehlermeldung (Goto war unerwartet zu dieser Zeit), Wann immer der Benutzer bestätigt den Angriff. WARNUNG!! Code 96 Zeilen lang. Am Ende werde ich das problem Abschnitt, so können Sie überspringen diese erste große Brocken.

@echo off
Set H1=20
Set A1=8
Set D1=6
Set S1=5
Set H2=14
Set A2=5
Set D2=4
Set S2=8
:Begin
CLS
Echo Bulbasur
Echo %H2%/14      /\       
Echo           (__) ___  
Echo           l __lo.ol 
Echo           l_\ l_\"  
Echo.        
Echo     _ 
Echo *  /\ 
Echo \\l  )
Echo  \\__l   Charmander
Echo             %H1%/20
Echo -Attack -Capture
Echo -Item   -Run 
Set /p Move=Action?
If %move%==Attack goto Attack
If %move%==Catpure goto capture
If %move%==Item goto Item
If %move%==Run Goto Run
Echo I'm sorry, Charmander can't do that. 
Pause
goto Begin
:Attack
ClS
Echo Attacks
Echo 1)Tackle
Echo 2)Growl
Echo 3)Ember
Echo 4)Scratch
Set /p attack=Which one?
If %attack%==Tackle goto Tackle
If %attack%==1 goto Tackle
If %attack%==Growl Goto Growl
If %attack%==2 goto Growl
If %attack%==Ember goto Ember
If %attack%==3 goto Ember
If %attack%==Scratch goto Scratch
If %attack%==4 goto Scratch
If %attack%==Cancel goto Begin
Echo I didn't get that
Goto Attack
:Tackle
CLS
Echo Tackle Hits The opponent where it hurts. EVERYWHERE.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto Tackle 
:Growl
CLS
Echo Growl lowers the opponents attack.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Status
If %acccept%==No goto Begin
Echo I didn't get that.
goto Growl
:Scratch
CLS
Echo Scratch hits the foe with a claw.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto  Scratch
:Ember
CLS
Echo Ember hits the opponent with a small fire.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto Ember
:Combat
CLS
If NOT %attack%==Growl If NOT %attack%==2 set /a H2=%H2%-(%A1%^2/%D2%)
set /a H1=%H1%-(%A2%^2/%D1%)
goto Begin
:Status
CLS
Set /a A1=%A1%-1
goto Combat

Problem:

:Tackle
CLS
Echo Tackle Hits The opponent where it hurts. EVERYWHERE.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto Tackle

Den code bekommt hier feine, aber sobald ich hier bin, kann es nicht erwarten, dass die goto-Befehle. Jeder kann dieses Problem beheben Rindfleisch? (Hinweis: die Bekämpfung ist nur ein Beispiel. Keiner der Angriffe arbeiten.) EDIT: Wenn der Benutzer legt in "ja","Nein",Kauderwelsch oder nichts, liefert es noch die gleiche Fehlermeldung (goto war unerwartet zu dieser Zeit)

Ich bin gespannt, was die downvotes; Fragesteller geposteten code, ausgesondert-ein Beispiel problem-Gebiet, und gab sogar die Fehlermeldung. Scheint eine gute Frage zu mir. Ist es nur Verachtung für batch-Dateien? Das sollte nicht beeinflussen, ob die Frage gut ist oder nicht.
wahrscheinlich, weil er veröffentlicht seine gesamte Skript. Und dann veröffentlicht eine weitere Kopie von den problematischen code. Er sollte nur gebucht haben, den code, dass war problematisch.
If %move%==Catpure goto capture Ich weiß, dass Katzen purre, aber ich denke, das ist ein Tippfehler ^^

InformationsquelleAutor user1205760 | 2012-03-19

6

Setzen Sie es in Anführungszeichen:
```
if "%accept%"=="yes" goto combat
if "%accept%"=="no" goto begin
```
Oder eher, wenn Sie nicht wollen, um es groß-Kleinschreibung:
```
if /i "%accept%"=="yes" goto combat
if /i "%accept%"=="no" goto begin
```
- Nicht wirklich muss, wohlgemerkt, aber man kann sicherlich, und das ist wahrscheinlich die am weitesten verbreitete Methode zur Lösung des Problems (und auch, dass für einige Grund, warum ich nicht glaube, zu der Zeit).
InformationsquelleAutor Answer

Dein problem ist, dass diese Zeile:

set /p accept=Yes/No?

NICHT die gleichen Variablen-Namen, diese sind:

If %acccept%==Yes goto Combat
If %acccept%==No goto Begin

Oben genannten Variablen haben, "ccc", aber die ersten einfach "cc"

BEARBEITEN

Hallo, user1205760; ich habe mich einige Zeit zu verbringen, so dass ich Ihr Programm und machte es etwas kleiner ist. Dies ist meine version:

@echo off

Setlocal EnableDelayedExpansion
Set Actions=Attack Capture Item Run
Set Attacks=Tackle Growl Ember Scratch Cancel
Set i=0
For %%a in (%Attacks%) do set /A i+=1 & set Attack[!i!]=%%a

Set H1=20
Set A1=8
Set D1=6
Set S1=5
Set H2=14
Set A2=5
Set D2=4
Set S2=8

:Begin
:Cancel
CLS
Echo Bulbasur
Echo %H2%/14      /\       
Echo           (__) ___  
Echo           l __lo.ol 
Echo           l_\ l_\"  
Echo.        
Echo     _ 
Echo *  /\ 
Echo \\l  )
Echo  \\__l   Charmander
Echo             %H1%/20
Echo -Attack -Capture
Echo -Item   -Run 
Set /p Move=Action? 
For %%a in (%Actions%) do if /I %move%==%%a goto %move%
Echo I'm sorry, Charmander can't do that. 
Pause
goto Begin

:Attack
Cls
Echo Attacks
For %%a in (1 2 3 4) do echo %%a)!Attack[%%a]!
Set /p attack=Which one? 
for %%a in (1 2 3 4) do if %attack%==%%a set attack=!Attack[%%a]!
for %%a in (%Attacks%) do if /I %attack%==%%a goto %attack%
Echo I didn't get that
Pause
Goto Attack

:Tackle
call :Confirm Tackle Hits The opponent where it hurts. EVERYWHERE.
If %accept%==Yes goto Combat
goto Begin

:Growl
call :Confirm Growl lowers the opponents attack.
If %accept%==Yes goto Status
goto Begin

:Ember
call :Confirm Ember hits the opponent with a small fire.
If %accept%==Yes goto Combat
goto Begin

:Scratch
call :Confirm Scratch hits the foe with a claw.
If %accept%==Yes goto Combat
goto Begin

:Status
Set /A A1-=1
:Combat
If /I NOT %attack%==Growl set /A H2=H2-(A1^2/D2)
set /A H1=H1-(A2^2/D1)
goto Begin

:Confirm 
Cls
Echo %*
Echo Do you want to?
set /p accept=Yes/No? 
For %%a in (Yes No) do if /I %accept%==%%a exit /B
Echo I didn't get that.
Pause
goto Confirm

Das könnte weh tun. Schönen Fang.

InformationsquelleAutor Aacini

2

Wenn der Benutzer nichts, Ihr If Linien wohl zu bewerten, um so etwas wie dieses:
```
…
If ==Yes goto Combat
If ==No goto Begin
…
```
ist syntaktisch falsch. Ich würde vorschlagen, Initialisierung accept vor der set /p Befehl mit einigen default-Wert:
```
…
set accept=default
set /p accept=Yes/No?
if …
```
So, wenn der Benutzer nur hits Geben, die accept variable behalten default Wert, und die anschließende if wird am Ende nicht in den Fehler.
- oder einen test vor, WENN ==JA gezielt testen, ob %annehmen% ist null - es Aussehen könnte, " WENN .%akzeptieren%==. goto xxxx ...'
- Sie können auch verwenden Sie Anführungszeichen, um Ihre Artikel zu vergleichen, so dass Sie auswerten If ""=="ja". Noch eine gute Idee, verwenden Sie den Standardwert, wie Andriy empfiehlt.
InformationsquelleAutor Andriy M
-1

Entschuldigen Sie mich,

Dies ist nur eine Frage der downvotes.

Die Menschen, die fragt halt NICHT SICHER, muss das problem sein, DASS TEIL.

z.B.
```
set a=
if %a%==1 echo yes
```
Wenn ich nur nach dieser Zeile:
```
if %a%==1 echo yes
```
Dann WIRD JEDER WISSEN, WAS IST DAS PROBLEM?

Erinnern variable, like %abc%, es ist besser, verwenden Sie es mit ",[ oder {, um zu verhindern Fehlermeldung.

z.B.
```
set /p abc=
```
und die Eingaben des Benutzers nichts.

Dann die nächste Zeile sollte sein:
```
if %abc%==1 echo Hi
```
Aber es wurde:
```
if ==1 echo Hi
```
als "%abc%"==""

Aber mit "die", es wird
```
if ""=="1" echo Hi
```
Und "" ungleich "1".

Verstehen?

BEARBEITEN---

Wenn Sie Windows 7 ( oder anderen Versionen ), können Sie auch versuchen, diese:
```
choice /c YN /n /m "Confirm? [Y^|N]
```
Den ^ ist nur die Flucht der "pipe" (|).

Hoffe, dass dies nützlich für Sie sein wird!
- Was ist Los? Ich habe downvotes und HABE MEINEN KOMMENTAR hat ABGESAGT?
InformationsquelleAutor Jamie

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.