Gradle Android buildTypes überschreiben sich gegenseitig

Ich würde schätzen jede Hilfe mit diesem, seit ich bin ein noobie w/gradle. Ich habe ein build-Skript mit mehreren buildTypes, aber es erscheint Einstellungen für einen von Ihnen überschreiben die andere.

Hier mein build.gradle:

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:0.4.2'
    }
}

apply plugin: 'android'

dependencies {
    compile project(':facebook-android-sdk-3.0.1:facebook')
    compile project(':google-play-services_lib')
    compile project(':nineoldandroids')
    compile project(':SlidingMenu-master:library')
    compile project(':ViewPagerIndicator')
    compile project(':volley')
    compile project(':windowed-seek-bar')
    compile files('compile-libs/androidannotations-2.7.1.jar', 'libs/Flurry_3.2.1.jar', 'libs/google-play-services.jar', 'libs/gson-2.2.4.jar', 'libs/picasso-1.1.1.jar', 'libs/crittercism_v3_0_11_sdkonly.jar', 'libs/gcm.jar', 'libs/apphance-library.jar')
}

android {
    buildToolsVersion "17.0"
    compileSdkVersion 17

    signingConfigs {
        debug {
            storeFile file('keystores/debug.keystore')
        }

        release {
            storeFile file('keystores/release.keystore')
            storePassword "***"
            keyAlias "***"
            keyPassword "***"
        }
    }

    buildTypes {
        debug {
            sourceSets {
                main {
                    manifest.srcFile 'AndroidManifest.xml'
                    java.srcDirs = ['src', 'normal']
                    resources.srcDirs = ['src']
                    aidl.srcDirs = ['src']
                    renderscript.srcDirs = ['src']
                    res.srcDirs = ['res']
                    assets.srcDirs = ['assets']
                }
            }
        }

        release {
            signingConfig signingConfigs.release

            sourceSets {
                main {
                    manifest.srcFile 'AndroidManifest.xml'
                    java.srcDirs = ['src', 'normal']
                    resources.srcDirs = ['src']
                    aidl.srcDirs = ['src']
                    renderscript.srcDirs = ['src']
                    res.srcDirs = ['res']
                    assets.srcDirs = ['assets']
                }
            }
        }

        utest {
            debuggable true
            signingConfig signingConfigs.debug

            sourceSets {
                main {
                    manifest.srcFile 'utest/AndroidManifest.xml'
                    java.srcDirs = ['src', 'utest']
                    resources.srcDirs = ['src']
                    aidl.srcDirs = ['src']
                    renderscript.srcDirs = ['src']
                    res.srcDirs = ['res']
                    assets.srcDirs = ['assets']
                }
            }
        }
    }
}

Den Einstellungen für utest sind, überschreiben die Einstellungen für release und debug. Weiß jemand, warum?

InformationsquelleAutor Karim Varela | 2013-07-13
  1. 12

    Ihre Nutzung der Quelle setzt, ist falsch. Es ist nicht in jedem build-Verschluss. Sie erklärte auf Ihrer eigenen:

    android {
    buildTypes {
        debug {
            ...
        }
        release {
            ...
        }
        utest {
            ...
        }
    }

    sourceSets {
        debug {
            ...
        }
        release {
            ...
        }
        utest {
            ...
        }
    }
}

    Beachten Sie, dass die build-Typen haben Ihre eigene Quelle setzt auf Spitze der 'main' - Quelle setzt. So sollten Sie nicht setzen Sie alle build-Typ sourceset zu verwenden 'src'. Sie konnte tun

    android {
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
        }
        utest {
            manifest.srcFile 'utest/AndroidManifest.xml'
            java.srcDirs = ['utest']
        }
    }
}

    Beachten Sie, dass in diesem Fall das manifest unter utest/AndroidManifest.xml werden zusammengeführt in der Hauptsache manifestieren.

    InformationsquelleAutor Xavier Ducrohet
Schreibe einen Kommentar