Highlight (nicht löschen) wiederholen Sie die Sätze oder Ausdrücke in einem word-Dokument

Bin ich immer den Eindruck, dass dies nicht möglich ist, in word, aber ich denke, wenn Sie sind auf der Suche nach einer 3-4 Wörter, die kommen in der gleichen Reihenfolge, die irgendwo in einem sehr langen Papier, das ich finden konnte, Duplikate des gleichen Phrasen.

Ich kopieren und einfügen eine Menge an Dokumentation, die Sie aus der Vergangenheit Papiere und war in der Hoffnung zu finden, einen einfachen Weg zu finden, wiederholt Informationen in diesem 40+ Seiten-Dokument gibt es eine Menge unterschiedlicher Formatierung, aber ich wäre bereit, vorübergehend loswerden formatieren, um zu finden, wiederholt Informationen.

Es würde schwierig werden. Im ersten Absatz deiner Frage, es gibt 81 3-und 4-Wort-Gruppen. Vorstellen, wie viele es sein würden, 40+ Seiten-Dokument.
Ich Frage mich, ob Sie sich auf bestimmte Wörter - Wörter, die länger als, sagen wir, sieben Buchstaben? Es könnte dann möglich sein, sehen Sie sich die Worte auf beiden Seiten oder so wichtige Worte.
Wäre ein Konzept ähnlich wie ein KUMPEL helfen? Ich denke die Suche wird jedes Wort Gruppe in Serie, beginnend mit dem ersten Wort im Dokument (addition der DAWG/Referenzierung, was wurde schon Hinzugefügt, wie Sie gehen, wo jeder Knoten ist ein Wort, nicht ein Brief) wäre nicht unmöglich. Sie würde müssen nur einen Weg finden, um diese Struktur erstellt, die in VBA und/oder eine externe DLL. Ich hatte versucht, etwas ähnliches einmal, aber ich fand es schon eine Herausforderung, mit den standard-Bibliotheken zur Verfügung.

InformationsquelleAutor rparks21 | 2012-04-24

Markieren Sie alle doppelten Sätze, können Sie auch ActiveDocument.Sentences(i). Hier ist ein Beispiel

LOGIK

1) Bekommen alle die Sätze aus dem word-Dokument in ein array

2) Sortieren Sie das array

3) Extrakt Duplikate

4) Markieren Sie Duplikate

CODE

Option Explicit

Sub Sample()
    Dim MyArray() As String
    Dim n As Long, i As Long
    Dim Col As New Collection
    Dim itm

    n = 0
    '~~> Get all the sentences from the word document in an array
    For i = 1 To ActiveDocument.Sentences.Count
        n = n + 1
        ReDim Preserve MyArray(n)
        MyArray(n) = Trim(ActiveDocument.Sentences(i).Text)
    Next

    '~~> Sort the array
    SortArray MyArray, 0, UBound(MyArray)

    '~~> Extract Duplicates
    For i = 1 To UBound(MyArray)
        If i = UBound(MyArray) Then Exit For
        If InStr(1, MyArray(i + 1), MyArray(i), vbTextCompare) Then
            On Error Resume Next
            Col.Add MyArray(i), """" & MyArray(i) & """"
            On Error GoTo 0
        End If
    Next i

    '~~> Highlight duplicates
    For Each itm In Col
        Selection.Find.ClearFormatting
        Selection.HomeKey wdStory, wdMove
        Selection.Find.Execute itm
        Do Until Selection.Find.Found = False
            Selection.Range.HighlightColorIndex = wdPink
            Selection.Find.Execute
        Loop
    Next
End Sub

'~~> Sort the array
Public Sub SortArray(vArray As Variant, i As Long, j As Long)
  Dim tmp As Variant, tmpSwap As Variant
  Dim ii As Long, jj As Long

  ii = i: jj = j: tmp = vArray((i + j) \ 2)

  While (ii <= jj)
     While (vArray(ii) < tmp And ii < j)
        ii = ii + 1
     Wend
     While (tmp < vArray(jj) And jj > i)
        jj = jj - 1
     Wend
     If (ii <= jj) Then
        tmpSwap = vArray(ii)
        vArray(ii) = vArray(jj): vArray(jj) = tmpSwap
        ii = ii + 1: jj = jj - 1
     End If
  Wend
  If (i < jj) Then SortArray vArray, i, jj
  If (ii < j) Then SortArray vArray, ii, j
End Sub

SNAPSHOTS

VOR

Highlight (nicht löschen) wiederholen Sie die Sätze oder Ausdrücke in einem word-Dokument

NACH

Highlight (nicht löschen) wiederholen Sie die Sätze oder Ausdrücke in einem word-Dokument

Nette Antwort, aber mein Verständnis ist, dass der OP sucht nach Phrasen, die vielleicht nicht einen ganzen Satz.
In diesem Fall OP haben, definieren Sie die minimale Anzahl der Wörter in einem Satz, sonst dadurch wird eine Verwirrung. This is a green apple und This is a green Ball. This is a green gemeinsam in Ihnen 🙂
Die OP konnte (...looking for any 3-4 words that come in the same sequence...) in der ursprünglichen Frage. Mein Beispiel erlaubt eine individuelle Anpassung derselben sowie (mit dem übergebenen argument ChainLength).
Ok. Ich will hinzufügen, dass ein Teil als gut 🙂

InformationsquelleAutor Siddharth Rout

4

Habe ich nicht meine eigenen DAWG Vorschlag, und ich bin immer noch daran interessiert, zu sehen, wenn jemand anderes hat einen Weg, dies zu tun, aber ich war in der Lage zu kommen mit diesem:
```
Option Explicit

Sub test()
Dim ABC As Scripting.Dictionary
Dim v As Range
Dim n As Integer
    n = 5
    Set ABC = FindRepeatingWordChains(n, ActiveDocument)
    ' This is a dictionary of word ranges (not the same as an Excel range) that contains the listing of each word chain/phrase of length n (5 from the above example).
    ' Loop through this collection to make your selections/highlights/whatever you want to do.
    If Not ABC Is Nothing Then
        For Each v In ABC
            v.Font.Color = wdColorRed
        Next v
    End If
End Sub

' This is where the real code begins.
Function FindRepeatingWordChains(ChainLenth As Integer, DocToCheck As Document) As Scripting.Dictionary
Dim DictWords As New Scripting.Dictionary, DictMatches As New Scripting.Dictionary
Dim sChain As String
Dim CurWord As Range
Dim MatchCount As Integer
Dim i As Integer

    MatchCount = 0

    For Each CurWord In DocToCheck.Words
        ' Make sure there are enough remaining words in our document to handle a chain of the length specified.
        If Not CurWord.Next(wdWord, ChainLenth - 1) Is Nothing Then
            ' Check for non-printing characters in the first/last word of the chain.
            ' This code will read a vbCr, etc. as a word, which is probably not desired.
            ' However, this check does not exclude these 'words' inside the chain, but it can be modified.
            If CurWord <> vbCr And CurWord <> vbNewLine And CurWord <> vbCrLf And CurWord <> vbLf And CurWord <> vbTab And _
                CurWord.Next(wdWord, ChainLenth - 1) <> vbCr And CurWord.Next(wdWord, ChainLenth - 1) <> vbNewLine And _
                CurWord.Next(wdWord, ChainLenth - 1) <> vbCrLf And CurWord.Next(wdWord, ChainLenth - 1) <> vbLf And _
                CurWord.Next(wdWord, ChainLenth - 1) <> vbTab Then
                sChain = CurWord
                For i = 1 To ChainLenth - 1
                    ' Add each word from the current word through the next ChainLength # of words to a temporary string.
                    sChain = sChain & " " & CurWord.Next(wdWord, i)
                Next i

                ' If we already have our temporary string stored in the dictionary, then we have a match, assign the word range to the returned dictionary.
                ' If not, then add it to the dictionary and increment our index.
                If DictWords.Exists(sChain) Then
                    MatchCount = MatchCount + 1
                    DictMatches.Add DocToCheck.Range(CurWord.Start, CurWord.Next(wdWord, ChainLenth - 1).End), MatchCount
                Else
                    DictWords.Add sChain, sChain
                End If
            End If
        End If
    Next CurWord

    ' If we found any matching results, then return that list, otherwise return nothing (to be caught by the calling function).
    If DictMatches.Count > 0 Then
        Set FindRepeatingWordChains = DictMatches
    Else
        Set FindRepeatingWordChains = Nothing
    End If

End Function
```
Habe ich getestet, die auf eine 258 Seiten-Dokument (TheStory.txt) von diese Quelle, und es lief in nur wenigen Minuten.

Sehen die test() sub für die Nutzung.

Müssen Sie einen Verweis auf die Microsoft Scripting Runtime mit der Scripting.Dictionary Objekte. Wenn das unerwünscht ist, kleine änderungen können gemacht werden, zu verwenden Collections anstelle, aber ich bevorzuge die Dictionary wie hat es die nützliche .Exists() Methode.
- Ich bin gespannt, ob Ihr code wurde weniger als eine minute für ein 625 mb Dokument dann, warum bieten die bounty und unsere Zeit verschwenden 🙂 Oder erwartest du einen code, der erreicht, dass in 15-20 Sekunden??
- Ich hatte nicht die Absicht, Verschwendung jedermanns Zeit; ich wollte wirklich zu sehen, einige verschiedene Möglichkeiten, dies zu tun. Ich habe nicht testen Sie die Geschwindigkeit von meinem eigenen, bis gerade jetzt. Ich war in der Planung die Vergabe der bounty auf dich sowieso! 😉
- Ich habe es nicht für das bounty 🙂 Sie vergeben kann es zu Kim oder zu sich selbst . Das ist ok mit mir. Ich war gerade auf der Suche nach einer herausfordernden Frage 😉 I did not test the speed of my own until just now. Wenn das ist eine Tatsache dann, nehme ich meine Worte zurück. Ich war einfach nur neugierig, wenn Ihr code wird wie du sagst (was ich immer noch unglaublich), dann haben Sie wirklich brauchen nicht jemand anderen code 😉 Aber im ernst Ihr code gelingt, finden alle doppelten Sätze UND Phrasen in den 258 Seiten-Dokument in weniger als einer minute? Leider kann ich nicht testen, da ich nicht herunterladen, die 625 MB schwere Dokument.
- Wenn jemand anderes will antesten, ich bin sehr offen! Ich lief mir zweimal aus dem gleichen Grund, aber endete mit einem ähnlichen Ergebnis. Ich will nicht ausschließen, einen Fehler vorzeitig beenden, aber ich habe keinerlei On Error Schritte, so hätte ich erwartet, dass eine Warnung/dialog. Ich habe auch gescannt, der doc und gefunden Höhepunkte während, all der Weg zur letzten Seite. Wenn jemand beweisen mich nicht falsch, dann würde ich gerne wissen was ich falsch gemacht habe mit meinem test (laufen mit Phrasen, die aus 5 Wörtern, die wahrscheinlich von Bedeutung ist) also ich nicht es wieder tun!
- Ich denke, ich werde erstellen Sie eine test-Dokument später und testen Sie es selbst. Die Sache, die mich stört, ist, dass 1) Sie die Schleife durch jedes Wort und ich bin die Schleife durch jeden Satz zu 2) ich bin nicht sogar ein Satz überprüfen, während Sie dabei sind, einen Satz überprüfen, also wie kann es sein, dass mein code ist immer noch langsam... Das ist das, was ist beunruhigend Sie mir... Wie ich schon sagte, ich werde es testen, später.
- Wenn Sie das tun, bitte schicken/verlinken auf mich, so kann ich versuchen zu reproduzieren mir!
- Ich erstellte eine word-Datei mit 800 Seiten (119996 Worte) Mein makro nahm 1 hr 11 mins. Ich bin jetzt läuft das makro. Ich hatte erwartet, dass Ihr makro fertig in 10-15 Minuten max basierend auf Ihrer Studie, dass es lief in weniger als einer minute für 258 Seiten. Es ist ja schon nach 20 Minuten... das makro noch läuft. Halten Sie auf dem Laufenden, wenn es endet. Die einzige änderung, die ich gemacht, um Ihren code wurde Dim MatchCount As Integer zu Dim MatchCount As Long wie ich immer war, ein überlauf-Fehler (was ja auch verständlich ist)
- Dein makro einfach beendet. 1 Hr 18 Mins
- Beispiel für eine Datei zum testen. Dies ist 41.8 kb - 800 Seiten (119996 Worte) Die Datei hat auch meine und Ihre Makros, die ich verwendet. wikisend.com/download/356770/Sample.docm
- lassen Sie uns weiter, diese Diskussion im chat
- Getestet dieses Skript und bekam ein paar false-positives und Phrasen, die waren unter der ChainLength. Leider kann ich nicht hochladen, meine Datei, sondern nur etwas bewusst zu sein. Dank
InformationsquelleAutor Gaffi

Wählte ich eine eher lahme Theorie, aber es scheint zu funktionieren (zumindest, wenn ich die Frage richtig cuz manchmal bin ich ein langsam understander).
Ich lade den gesamten text in einen string laden Sie die einzelnen Wörter in ein array, eine Schleife durch das array und verketten von string, mit jedes mal, wenn drei aufeinander folgende Wörter.

Denn die Ergebnisse sind bereits in 3-Wort-Gruppen, 4 Wort-Gruppen oder mehr wird automatisch erkannt.

Option Explicit

Sub Find_Duplicates()

On Error GoTo errHandler

Dim pSingleLine                     As Paragraph
Dim sLine                           As String
Dim sFull_Text                      As String
Dim vArray_Full_Text                As Variant

Dim sSearch_3                       As String
Dim lSize_Array                     As Long
Dim lCnt                            As Long
Dim lCnt_Occurence                  As Long


'Create a string from the entire text
For Each pSingleLine In ActiveDocument.Paragraphs
    sLine = pSingleLine.Range.Text
    sFull_Text = sFull_Text & sLine
Next pSingleLine

'Load the text into an array
vArray_Full_Text = sFull_Text
vArray_Full_Text = Split(sFull_Text, " ")
lSize_Array = UBound(vArray_Full_Text)


For lCnt = 1 To lSize_Array - 1
    lCnt_Occurence = 0
    sSearch_3 = Trim(fRemove_Punctuation(vArray_Full_Text(lCnt - 1) & _
                    " " & vArray_Full_Text(lCnt) & _
                    " " & vArray_Full_Text(lCnt + 1)))

    With Selection.Find
        .Text = sSearch_3
        .Forward = True
        .Replacement.Text = ""
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False

        Do While .Execute

            lCnt_Occurence = lCnt_Occurence + 1
            If lCnt_Occurence > 1 Then
                Selection.Range.Font.Color = vbRed
            End If
            Selection.MoveRight
        Loop
    End With

    Application.StatusBar = lCnt & "/" & lSize_Array
Next lCnt

errHandler:
Stop

End Sub

Public Function fRemove_Punctuation(sString As String) As String

Dim vArray(0 To 8)      As String
Dim lCnt                As Long


vArray(0) = "."
vArray(1) = ","
vArray(2) = ","
vArray(3) = "?"
vArray(4) = "!"
vArray(5) = ";"
vArray(6) = ":"
vArray(7) = "("
vArray(8) = ")"

For lCnt = 0 To UBound(vArray)
    If Left(sString, 1) = vArray(lCnt) Then
        sString = Right(sString, Len(sString) - 1)
    ElseIf Right(sString, 1) = vArray(lCnt) Then
        sString = Left(sString, Len(sString) - 1)
    End If
Next lCnt

fRemove_Punctuation = sString

End Function

Den code übernimmt ein fortlaufender text ohne Aufzählungszeichen.

Als ich das Las (nicht der test selber), da Sie die Teilung auf " ", nicht Worte, die das Ende eines Satzes (oder durch ein Komma getrennt werden/andere Satzzeichen) nicht immer übereinstimmen? Beispiel: "I like to do this." vs. "I like to do this sometimes." (auch, würde ich +1 für heute noch eine gute Antwort, aber ich bin aus der Stimmen für den Tag...)
Mach dir keine sorgen über die Abstimmung und du hast Recht. Ich habe keinen Zugriff auf meinen PC mehr, da ich Links arbeiten, aber ich Schreibe eine kleine Funktion morgen zu entfernen, die Interpunktion von der such-string.
Die Funktion wurde Hinzugefügt.
Ich habe nicht den test durchzuführen (weil es so lange gedauert hat), aber das braucht erheblich mehr Zeit als entweder von mir oder Sid ist für eine sehr große Datei (siehe die Anmerkung zu meiner Antwort). Obwohl, es funktioniert immer noch gerade in Ordnung für kleinere Dateien.
Das ist sehr gut möglich. Wenn Sie denken, es vorbei ist, ich wahrscheinlich auch, hätte Wörterbüchern; be-ein array von 3-Text-strings in ein Wörterbuch, falls vorhanden -> kopieren in ein neues dictionary und die Grenze meiner "suchen -> - Farbe", um nur die strings anwendbar. Ich denke, dass die "exists" - Methode von dictionaries kann drastisch erhöhen die Leistung (mit den Tasten) und vielleicht das wiederholte und explizite "finden" ist, was macht es langsam.

InformationsquelleAutor Trace

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.