Holen Sie sich einen datetime-von Jahr, Tag des Jahres und die Stunde, in SQL Server 2008 R2

Ich habe eine Tabelle in einer Microsoft SQL Server 2008 R2, die kamen aus einer externen Quelle. Die Spalten sind wie folgt: ID, Year, DAY, HOUR & Value, wo DAY enthält den Tag des Jahres (1 bis 366) und HOUR stellt die Stunde des Tages (0 bis 23).

Möchte ich zum erstellen eines neuen datetime-Spalte und füllen Sie es mit dem dateTime-erstellt aus den Daten in Year, DAY & HOUR Spalten.

Welche SQL-Funktion sollte ich verwenden, um erstellen Sie die DateTime von seinen teilen?

SQL Server 2012 hat DATETIMEFROMPARTS, aber es gibt keine äquivalente Funktion für SQL Server 2008 R2

InformationsquelleAutor Devdatta Tengshe | 2013-04-30
  1. 7
    declare @Year int = 2003
declare @Day int = 100
declare @Hour int = 13

select dateadd(hour, @Hour, dateadd(dayofyear, @Day - 1, dateadd(year, @Year - 1900, 0)))
    • Dank einer Tonne! Ich wusste nicht, dass die 0 steht 1900-01-01 00:00:00.000.
    InformationsquelleAutor Mikael Eriksson
  2. 4

    Könnten Sie den folgenden statt:

    DECLARE @day int, @month int, @year int
SELECT @day = 4, @month = 3, @year = 2011

SELECT dateadd(mm, (@year - 1900) * 12 + @month - 1 , @day - 1)

    Geben Sie Ihrem date (wenn es wahr ist, dass SQL 2012 bekommt es Recht, endlich!)

    Verwenden Sie es, wenn Sie Jahr, Tag des Jahres und der Stunde des Tages, verwenden Sie die folgende:

    declare @year int, @dayofyear int, @hourofday int
select @year = 2013, @dayofyear = 120, @hourofday = 12

select dateadd(hh, @hourofday, dateadd(yy, @year - 1900, dateadd(dd, @dayofyear - 1, 0)))
    • Ich habe nicht den Monat oder Tag des Monats. Ich habe nur das Jahr, Tag des Jahres, und die Stunde des Tages.
    • Ich habe aktualisiert, um Ihre verfügbaren Felder, die könnte wahrscheinlich gekürzt werden, aber es funktioniert trotzdem!
    InformationsquelleAutor KaraokeStu
  3. 3

    Erstellt, dass für mich und dachte, es wäre ein guter Ort, um zu teilen - es basiert auf dem Beispiel von Mikael Eriksson. 

    CREATE FUNCTION [dbo].[DATETIME2FROMPARTS](
    @year int,
    @month int,
    @day int,
    @hour int,
    @minute int,
    @second int,
    @fractions int,
    @precision int)
RETURNS datetime2(7)
AS
BEGIN
    RETURN
        DATEADD(NANOSECOND, POWER(10, 9-@precision)*@fractions, 
        DATEADD(SECOND, @second, 
        DATEADD(MINUTE, @minute, 
        DATEADD(HOUR, @hour, 
        DATEADD(DAY, @day-1, 
        DATEADD(MONTH, @month-1, 
        DATEADD(YEAR, @year-1900, 
        CAST(CAST(0 AS datetime) AS datetime2(7)))))))));
END
    InformationsquelleAutor Lucero
  4. 0

    Hier eine alternative Lösung:

    create table yourtable (yr int, dy int, hr int);
insert into yourtable values (2013,100,5);
insert into yourtable values (2013,1,1);

select dateadd(hour,hr,dateadd(month, (yr - 1900) * 12 , dy - 1))
from yourtable

    Konzept ist das hinzufügen von Stunden zu dem Datum, mit dem Jahr (Jahr - 1900) * 12 des Monats, beginnend mit der Zahl der Tage.

    InformationsquelleAutor sgeddes
Schreibe einen Kommentar