ich möchte hinzufügen "xmlns" - Attribut in der xml-Datei mit xslt

Möchte ich folgende xml-Datei ausgegeben:

<?xml version="1.0" encoding="ISO-8859-1" ?> 
- <T0020 xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://www.safersys.org/namespaces/T0020V1">
- <INTERFACE>
  <NAME>SAFER</NAME> 
  <VERSION>04.02</VERSION> 
  </INTERFACE>

dafür habe ich folgende xslt-Datei: 

<xsl:template match="T0020" >
    <xsl:copy>
    <xsl:attribute name="xsi:schemaLocation" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd </xsl:attribute>

  //some code here...............//

 <xsl:copy>

also ich add xmlns="http://www.safersys.org/namespaces/T0020V1" - Attribut unter <T0020> tag??

  • Gute Frage (+1). Siehe meine Antwort für eine kurze und einfache Lösung. 🙂
InformationsquelleAutor Saumil Bhatt | 2010-07-27
  1. 2

    Diese transformation:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vDefaultNS"
  select="'http://www.safersys.org/namespaces/T0020V1'"/>

 <xsl:template match="*">
  <xsl:element name="{name()}" namespace="{$vDefaultNS}">
   <xsl:copy-of select="namespace::* | @*"/>
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

    , wenn angewandt auf das XML-Dokument:

    <T0020 xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
 xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd"
>
 <INTERFACE>
  <NAME>SAFER</NAME>
  <VERSION>04.02</VERSION>
 </INTERFACE>
</T0020>

    produziert das erwartete Ergebnis:

    <T0020 xmlns="http://www.safersys.org/namespaces/T0020V1" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd">
   <INTERFACE>
      <NAME>SAFER</NAME>
      <VERSION>04.02</VERSION>
   </INTERFACE>
</T0020>

    Tun, beachten Sie, dass xmlns ist kein Attribut, sondern bezeichnet eine namespace-Deklaration.

    • +1 für die kurze Lösung. Aber wie Es aussieht ist die mitgelieferte stylesheet-fragment ist das hinzufügen einer schema-Instanz-Deklaration, denn vielleicht gab es vorher kein schema. Das könnte auch die Ursache sein für das ändern von Elementen namespace.
    • Ich will nicht zu erraten, hier. Die Frage war "How to add xmlns"... so bin ich nur mit diesem.
    InformationsquelleAutor Dimitre Novatchev
  2. 1

    Diesem stylesheet:

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*">
        <xsl:element name="{name()}" namespace="http://www.safersys.org/namespaces/T0020V1">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="T0020">
        <xsl:element name="{name()}" namespace="http://www.safersys.org/namespaces/T0020V1">
            <xsl:attribute name="xsi:schemaLocation">http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd</xsl:attribute>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

    Mit diesem input:

    <T0020>
    <INTERFACE>
        <NAME>SAFER</NAME>
        <VERSION>04.02</VERSION>
    </INTERFACE>
</T0020>

    Ausgabe:

    <T0020 xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://www.safersys.org/namespaces/T0020V1">
    <INTERFACE>
        <NAME>SAFER</NAME>
        <VERSION>04.02</VERSION>
    </INTERFACE>
</T0020>

    Hinweis: Namespace-Knoten sind nicht die Attribute-Knoten. Wenn Sie möchten, dass Elemente, die in keinem namespace bekommt die Ausgabe unter bestimmten namespace müssen Sie die xsl:element/@namespace.

    • +1 für eine sehr gute Lösung behebt nur das problem mit kein Exkurs.
    InformationsquelleAutor
Schreibe einen Kommentar