Immer der kleinste Wert einer Liste

Ich bin auf der Suche nach den Minimalwert einer Liste (als Lernerfahrung, also ohne min).

Mein Ansatz ist der folgende:

minimo([X], X).
minimo([X,Y|Tail], N):-
    (X > Y, minimo([Y,Tail], Y));
    (X <= Y, minimo([X,Tail], X)).

Dies gibt mir die folgende Fehlermeldung:

Syntax Fehler: Operator erwartet

Also meine Fragen sind:

  • Was die Ursache der syntax-Fehler?
  • Ich werde versuchen, es selbst einmal zu, dass ist fest, wenn es tatsächlich gibt den richtigen Wert zurück, aber wäre das tatsächlich der richtige Ansatz?

Vielen Dank im Voraus.

InformationsquelleAutor Trufa | 2011-11-08
  1. 4

    Es gibt mehrere bugs in Ihrem Programm:

    1. wie bereits von Joe Lehmann, es gibt keine '<='/2. Es muss '=<'/2.

    2. beim Aufruf minimo/2 rekursiv erstellen Sie die Listen falsch. Statt [Y,Tail] verwenden [Y|Tail]. Andernfalls erhalten Sie eine Liste, die eine Liste als zweites element.

    3. binden Sie das zweite argument des rekursiven Aufrufs von minimo/2 zu Y oder X. Stattdessen muss es gebunden werden, um N. Ansonsten, Ihr N wird nie instanziiert werden.

    Können Sie verbessern Ihr Programm weiter, indem Schnitte oder mit if-then-else ('->' + ;):

    minimo([X], X) :- !.
minimo([X,Y|Tail], N):-
    ( X > Y ->
        minimo([Y|Tail], N)
    ;
        minimo([X|Tail], N)
    ).
    InformationsquelleAutor twinterer
  2. 4

    Zusätzlich zu den anderen Versionen schon gepostet, sollten auch eine version ohne wenn-dann-sonst, und mit einem mehr beschreibenden Namen für die relation (die sich eine Liste auf minimum):

    list_min([L|Ls], Min) :- list_min(Ls, L, Min).

list_min([], Min, Min).
list_min([L|Ls], Min0, Min) :-
    Min1 is min(L, Min0),
    list_min(Ls, Min1, Min).

    Solch ein Muster aufgerufen wird, eine Falten (von Links), und wir können schreiben es gleichbedeutend mit `foldl/4:

    list_min([L|Ls], Min) :- foldl(min_, Ls, L, Min).

min_(A, B, Min) :- Min is min(A, B).

    Beispiel-query:

    ?- list_min([1,0,2], Min).
Min = 0.

    Beachten Sie aber, dass dies nicht eine echte Beziehung und kann nicht verwendet werden, die in alle Richtungen durch die Verwendung von low-level-Arithmetik. Zum Beispiel, wenn wir versuchen, es in der anderen Richtung erhalten wir:

    ?- list_min([X,Y], 3). 
ERROR: is/2: Argumente sind nicht ausreichend instanziiert

    Machen es zu einem wahren Lösung, verwenden Sie Einschränkungen wie clpfd und clpq. Zum Beispiel, für eine Lösung über Ganzzahlen:

    :- use_module(library(clpfd)).

list_min([L|Ls], Min) :- foldl(min_, Ls, L, Min).

min_(A, B, Min) :- Min #= min(A, B).

    Dieser funktioniert in alle Richtungen:

    ?- list_min([X,Y], 3).
X in 3..sup,
3#=min(Y, X),
Y in 3..sup.
    InformationsquelleAutor mat
  3. 3

    Den syntax-Fehler ist, weil weniger oder gleich im Prolog ist =<, nicht <=.

    Ich denke, dass der Ansatz funktionieren wird, aber man sollte wirklich vermeiden, in einer Klausel. Nur es aufgeteilt in zwei Klauseln.

    Ich denke auch, dass Sie etwas tun wollen gerne [X|Tail] in der Rekursion statt [X,Tail]

    • =< scheinen, um es zu beheben, danke. Aber jetzt habe ich diese Fehlermeldung: ERROR: >/2: Arithmetic: []/0' ist keine Funktion`und wenn ich es teilen in zwei, erhalte ich: - minimo([1,2,3],X). ERROR: >/2: Arithmetic: `[]/0' is not a function Exception: (8) minimo([[3], []], [3]) ? Danke! +1
    InformationsquelleAutor Joe Lehmann
  4. 2
    min([H|T], Min) :- min(T, H, Min).

min([], Min, Min).
min([H|T], Min, Min1) :-
  (   H < Min
  ->  min(T, H, Min1)
  ;   min(T, Min, Min1) ).
    InformationsquelleAutor salva
Schreibe einen Kommentar