Importieren von Tab-Getrennte Text-Datei mit Mehrzeiligen Zellen (in Excel oder Access)

Hier ist, was ich kam mit. Wenn Sie garantieren können der letzten Spalte wird niemals eine Zeilenschaltung, dann sollte diese Arbeit ok.

Was dies bedeutet ist, Lesen Sie die text-Datei in VBA und bringt es in die Arbeitsmappe. Sie müssen angeben, wie viele Felder zu erwarten (in dem test-Szenario 4). Dies ist, so dass Sie nachverfolgen können, Wann es bereit ist für den start einer neuen Zeile.

Es ist ein wenig verwirrend, da der Schlitten zurück, aber Schritt für Schritt durch den code, und ich denke, Sie werden in der Lage sein, um es herauszufinden. Lassen Sie mich wissen, wenn Sie irgendwelche Fragen haben.

Option Explicit

Const fieldCount = 4

Sub import()
    Application.ScreenUpdating = False

    Dim fileNumber As Integer
    Dim data As String
    Dim curCol As Long, curRow As Long
    Dim dataCols As Long
    Dim i As Long
    Dim sh As Excel.Worksheet
    Dim arr() As String
    Dim hasCarriageReturn As Boolean

    fileNumber = FreeFile()
    Open "C:\test.txt" For Input As #fileNumber
    curCol = 1
    curRow = 1
    Set sh = ThisWorkbook.Worksheets("Sheet1")

    While Not EOF(fileNumber)
        ' if we reached the "correct" last column, then move to next row
        If (curCol > fieldCount) Then
            curCol = 1
            curRow = curRow + 1
            hasCarriageReturn = False
        End If

        Line Input #fileNumber, data
        arr = Split(data, vbTab)
        dataCols = UBound(arr)



        If (dataCols = fieldCount - 1) Then
            ' full row has no carriage returns
            hasCarriageReturn = False

            For i = 0 To dataCols
                sh.Cells(curRow, curCol).Value = arr(i)
                curCol = curCol + 1
            Next

        ElseIf (dataCols = 0 And hasCarriageReturn = True) Then
            ' if there is only 1 value in the row, append it to the current column
            sh.Cells(curRow, curCol - 1).Formula = sh.Cells(curRow, curCol - 1).Formula & Chr(10) & arr(0)

        ElseIf (dataCols = 0 And hasCarriageReturn = False) Then
            ' carriage return begins in the first field
            sh.Cells(curRow, curCol).Formula = sh.Cells(curRow, curCol).Formula & Chr(10) & arr(0)
            curCol = curCol + 1
            hasCarriageReturn = True

        ElseIf (hasCarriageReturn) Then
            ' append first item to field 3, then rest goes in other columns
            sh.Cells(curRow, curCol - 1).Formula = sh.Cells(curRow, curCol - 1).Formula & Chr(10) & arr(0)
            For i = 1 To dataCols
                sh.Cells(curRow, curCol).Value = arr(i)
                curCol = curCol + 1
            Next

            hasCarriageReturn = False

        Else
            ' process row and note that it has carriage returns
            For i = 0 To dataCols
                sh.Cells(curRow, curCol).Value = arr(i)
                curCol = curCol + 1
            Next

            hasCarriageReturn = True
        End If

    Wend

    Application.ScreenUpdating = True
End Sub

InformationsquelleAutor Joseph

Import in Libre Office Calc. Libre Office Calc nicht interpretieren Zeilenumbrüche zwischen zwei tabs als nächste Zeile Befehl. Der Inhalt nach dem Zeilenumbruch erscheint in der nächsten Zeile in der gleichen Zelle. Speichern Sie die Tabelle als ms-excel-xls/xlsx-format.
Ignorieren Sie die Warnung, die erscheint, bevor es gespeichert wird, auf Ihr eigenes Risiko und/oder proof-Lesen Sie die gleichen Tabellenblatt nach dem import. Während der Nachweis Lesen stellen Sie sicher, dass Sie mit Excel.

InformationsquelleAutor anotherperson1