Klassische ASP-amazon s3 rest-Zulassung

Ich verwirrt bin, was mache ich hier falsch...

<script language="javascript" runat="server">
  function GMTNow(){return new Date().toGMTString()}
</script>
<%

Const AWS_BUCKETNAME = "uk-bucketname"
Const AWS_ACCESSKEY = "GOES HERE"
Const AWS_SECRETKEY = "SECRET"
LocalFile = Server.Mappath("/test.jpg")

Dim sRemoteFilePath
    sRemoteFilePath = "/files/test.jpg" 'Remote Path, note that AWS paths (in fact they aren't real paths) are strictly case sensitive

Dim strNow
    strNow = GMTNow() ' GMT Date String

Dim StringToSign
    StringToSign = Replace("PUT\n\nimage/jpeg\n\nx-amz-date:" & strNow & "\n/"& AWS_BUCKETNAME & sRemoteFilePath, "\n", vbLf)

Dim Signature
    Signature = BytesToBase64(HMACSHA1(AWS_SECRETKEY, StringToSign))

Dim Authorization
    Authorization = "AWS " & AWS_ACCESSKEY & ":" & Signature

Dim AWSBucketUrl
    AWSBucketUrl = "http://s3.amazonaws.com/" & AWS_BUCKETNAME

With Server.CreateObject("Microsoft.XMLHTTP")
    .open "PUT", AWSBucketUrl & sRemoteFilePath, False
    .setRequestHeader "Authorization", Authorization
    .setRequestHeader "Content-Type", "image/jpeg"
    .setRequestHeader "Host", AWS_BUCKETNAME & ".s3.amazonaws.com"  
    .setRequestHeader "x-amz-date", strNow
    .send GetBytes(LocalFile) 'Get bytes of local file and send
    If .status = 200 Then ' successful
        Response.Write "<a href="& AWSBucketUrl & sRemoteFilePath &" target=_blank>Uploaded File</a>"
    Else ' an error ocurred, consider xml string of error details
        Response.ContentType = "text/xml"
        Response.Write .responseText
    End If
End With

Function GetBytes(sPath)
    dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.GetFile(sPath)
GetBytes = f.Size
set f=nothing
set fs=nothing
End Function

Function BytesToBase64(varBytes)
    With Server.CreateObject("MSXML2.DomDocument").CreateElement("b64")
        .dataType = "bin.base64"
        .nodeTypedValue = varBytes
        BytesToBase64 = .Text
    End With
End Function

Function HMACSHA1(varKey, varValue)
    With Server.CreateObject("System.Security.Cryptography.HMACSHA1")
        .Key = UTF8Bytes(varKey)
        HMACSHA1 = .ComputeHash_2(UTF8Bytes(varValue))
    End With
End Function

Function UTF8Bytes(varStr)
    With Server.CreateObject("System.Text.UTF8Encoding")
        UTF8Bytes = .GetBytes_4(varStr)
    End With
End Function
%>

Jetzt immer der Fehler.

msxml3.dll error '800c0008'

The download of the specified resource has failed.

/s3.asp, line 39

Hast du es geschafft, zu finden, Ihr problem, Chris?
Nein noch nicht 🙁
Hallo Chris, bist du angemeldet für den Amazon S3 service als auch ein AWS-Konto? das ist der thread forums.aws.amazon.com/thread.jspa?threadID=45582
Ja, ich habe einen Eimer set-up und bereit zu gehen 🙂
+1 für den Mut, kombiniert innovatives cloud-tech mit stone age ASP-tech. Hoffe, du findest eine gute Lösung.
Definieren Sie die vollständige relative Pfad in sRemoteFilePath als /files/test.jpg. GetBytes geändert wurde, falsch. Es muss wieder bytes der Datei, nicht Größe Byte. Ich werde aktualisieren, meine Antwort mit diesen Verbesserungen, wie Sie benötigen Strom. Als Ausgangspunkt, kopieren Sie einfach und verwenden Sie nach dem ändern der S3-Anmeldeinformationen.
Ich habe aktualisiert mein code, das problem ist dass Sie mir. "The requested header was not found" Problem code ist .send GetBytes(LocalFile)
Das ist mit MSXML2.ServerXMLHTTP.3.0 wenn ich 6.0 bekomme ich The HTTP redirect request failed gleichen Zeile code.

InformationsquelleAutor Chris Dowdeswell | 2012-06-13

9

Möchte ich erklären, wie der S3 Rest-Api funktioniert soweit ich weiß.
Zuerst, Sie müssen lernen, was sollte der string auf Zeichen von Amazon akzeptiert.

Format :
```
StringToSign = HTTP-Verb + "\n" +
    Content-MD5 + "\n" +
    Content-Type + "\n" +
    Date + "\n" +
    CanonicalizedAmzHeaders +
    CanonicalizedResource;
```
Generieren unterzeichnet string :
```
Signature = Base64( HMAC-SHA1( YourSecretAccessKeyID, UTF-8-Encoding-Of( StringToSign ) ) );
```
Vorbei authorization-header:
```
Authorization = "AWS" + " " + AWSAccessKeyId + ":" + Signature;
```
Leider spielen Sie byte für byte, da gibt es kein SDK veröffentlicht, für das klassische asp. So, sollten verstehen, indem ich die gesamte Seite http://docs.amazonwebservices.com/AmazonS3/latest/dev/RESTAuthentication.html

String zu unterzeichnen, wie Sie oben sehen können in format, es gibt drei native Header reserviert sind, die von der API. Content-Type, Content-MD5 und Datum. Diese Header werden muss, existiert in der string-Zeichen auch Ihre Anfrage nicht Ihnen als, leer, ohne header-Namen, nur seinen Wert. Es ist eine Ausnahme, die Date Kopf muss leer sein string der Zeichen, wenn x-amz-date header ist bereits in der Anfrage. Dann, Wenn die Anfrage hat canonical die amazon-Header, fügen Sie Sie als Schlüssel-Wert-Paare wie x-amz-headername:value. Aber, es gibt eine weitere Ausnahme, die berücksichtigt werden müssen für mehrere Kopfzeilen. Mehrere Header sollte zu kombinieren, um eine Kopf-mit Werten, die durch Komma getrennt sind.

Richtige

x-amz-headername:Wert1,Wert2

Falsch

x-amz-headername:Wert1\n

x-amz-headername:Wert2

Allem, Kopfzeilen müssen aufsteigen, um von dessen Gruppe in der Zeichenfolge in Zeichen. Ersten, reservierten Header mit aufsteigender Reihenfolge, dann canonical Header mit aufsteigender Reihenfolge.

Ich würde empfehlen, mit DomDocument Funktionalität zu generieren, die Base64-kodierte strings.
Zusätzlich anstelle eines Windows-Scripting-Komponente (.wsc-Dateien), die Sie nutzen könnten .Net interops wie System.Security.Cryptography zu generieren keyed hashes mehr effektiv mit der Kraft der System.Text. Alle diese interoperabilities sind in der heutigen IIS-web-Server.

So, als Beispiel schrieb ich den untenstehenden script nur sendet eine Datei zum Eimer, die Sie angegeben. Betrachten und testen Sie es.

Angenommen name der lokalen Datei ist myimage.jpg - und hochgeladen wird, mit demselben Namen zum Stamm der Gruppe.
```
<script language="javascript" runat="server">
function GMTNow(){return new Date().toGMTString()}
</script>
```
```
<%
Const AWS_BUCKETNAME = "uk-bucketname"
Const AWS_ACCESSKEY = "GOES HERE"
Const AWS_SECRETKEY = "SECRET"

LocalFile = Server.Mappath("/test.jpg")

Dim sRemoteFilePath
    sRemoteFilePath = "/files/test.jpg" 'Remote Path, note that AWS paths (in fact they aren't real paths) are strictly case sensitive

Dim strNow
    strNow = GMTNow() ' GMT Date String

Dim StringToSign
    StringToSign = Replace("PUT\n\nimage/jpeg\n\nx-amz-date:" & strNow & "\n/"& AWS_BUCKETNAME & sRemoteFilePath, "\n", vbLf)

Dim Signature
    Signature = BytesToBase64(HMACSHA1(AWS_SECRETKEY, StringToSign))

Dim Authorization
    Authorization = "AWS " & AWS_ACCESSKEY & ":" & Signature

Dim AWSBucketUrl
    AWSBucketUrl = "https://" & AWS_BUCKETNAME & ".s3.amazonaws.com"

With Server.CreateObject("MSXML2.ServerXMLHTTP.6.0")
    .open "PUT", AWSBucketUrl & sRemoteFilePath, False
    .setRequestHeader "Authorization", Authorization
    .setRequestHeader "Content-Type", "image/jpeg"
    .setRequestHeader "Host", AWS_BUCKETNAME & ".s3.amazonaws.com"  
    .setRequestHeader "x-amz-date", strNow
    .send GetBytes(LocalFile) 'Get bytes of local file and send
    If .status = 200 Then ' successful
        Response.Write "<a href="& AWSBucketUrl & sRemoteFilePath &" target=_blank>Uploaded File</a>"
    Else ' an error ocurred, consider xml string of error details
        Response.ContentType = "text/xml"
        Response.Write .responseText
    End If
End With

Function GetBytes(sPath)
    With Server.CreateObject("Adodb.Stream")
        .Type = 1 ' adTypeBinary
        .Open
        .LoadFromFile sPath
        .Position = 0
        GetBytes = .Read
        .Close
    End With
End Function

Function BytesToBase64(varBytes)
    With Server.CreateObject("MSXML2.DomDocument").CreateElement("b64")
        .dataType = "bin.base64"
        .nodeTypedValue = varBytes
        BytesToBase64 = .Text
    End With
End Function

Function HMACSHA1(varKey, varValue)
    With Server.CreateObject("System.Security.Cryptography.HMACSHA1")
        .Key = UTF8Bytes(varKey)
        HMACSHA1 = .ComputeHash_2(UTF8Bytes(varValue))
    End With
End Function

Function UTF8Bytes(varStr)
    With Server.CreateObject("System.Text.UTF8Encoding")
        UTF8Bytes = .GetBytes_4(varStr)
    End With
End Function
%>
```
- Ich bin immer der Fehler "msxml6.dll Fehler '80072f7c' Der HTTP-redirect-Anforderung fehlgeschlagen" irgendwelche Ideen, was kann es?
- Welche Veränderungen haben Sie in den code, außer für bucket-name access-key und secret-key?
- Nichts, außer den Variablen, die Sie setzen... 🙁
- Ich weiß wirklich nicht, was ist die Ursache HIERFÜR. Auf meinem computer, es funktioniert wie ein Charme, und auch mit vielen online-Seiten derzeit. So, Wenn Sie in der Lage zu schnuppern http-Anfragen mit einem Dienstprogramm wie HttpSniffer, kann es herausfinden. Zusätzlich, sollten Sie vielleicht versuchen, ältere Versionen von MSXML z.B. MSXML2.ServerXMLHTTP.3.0
- Ok ich habe die version 3.0 und habe "Der angeforderte header wurde nicht gefunden"
- Leider helfen durch Kommentare ist so schwer. Wäre besser, wenn Sie aktualisieren die Frage mit den neuesten Zustand und ich würde gerne sehen, vollständigen code, den Sie versuchen, auch wenn Sie geändert haben, einen Brief.
- Ich habe aktualisiert die Frage, die ich wirklich zu schätzen Ihre Hilfe! Danke.
- so hilfreich, danke! Dies funktionierte perfekt für das hinzufügen von Objekten. Weiter, ich versuche, dies zu ändern führen Sie eine Kopie-Vorgang, kann aber nicht die Genehmigung der Arbeit, speziell der Zeichenfolge in Zeichen. Könnten Sie vielleicht geben Sie mir ein Beispiel für das kopieren eines Objekts von einem Eimer zum anderen. Total mein Haar ziehen mit classic ASP. Seufz.
- Ändern Sie die Bucket-URL, um die folgenden, sonst funktioniert es nur in us-east-1 AWSBucketUrl = "https://" & AWS_BUCKETNAME & ".s3.amazonaws.com" - das löst die redirect-Fehler.
- In der Tat, ich erinnere mich nicht, wie ich getestet habe den code. Wenn Sie sicher sind, bitte fühlen Sie sich frei zu Bearbeiten. Danke.
InformationsquelleAutor Kul-Tigin

Amazon Signature url-codiert werden muss in einer etwas anderen Weise zu dem, was VBSCript codiert. Die folgende Funktion codieren, ist das Ergebnis korrekt:

JScript-Version:

function amazonEncode(s)
{
    return Server.UrlEncode(s).replace(/\+/g,"%20").replace(/\%2E/g,".").replace(/\%2D/g,"-").replace(/\%7E/g,"~").replace(/\%5F/g,"_");
}

VBScript, Version:

function amazonEncode(s)
    dim retval
    retval = Server.UrlEncode(s)
    retval = replace(retval,"+","%20")
    retval = replace(retval,"%2E",".")
    retval = replace(retval,"%2D","-")
    retval = replace(retval,"%7E","~")
    retval = replace(retval,"%5F","_")
    amazonEncode = retval
end function

Als base64, die ich verwendet habe .NETTO ist bereits integrierten Funktionalität für Sie. Ich hatte um eine DLL zu erstellen, um wickeln Sie es, so dass ich es verwenden von JScript (oder VBScript).

Hier ist, wie zu schaffen, dass dll:

Download the free C# 2010 Express and install it.
You also need to use two other tools that you won’t have a path to, so you will need to add the path to your PATH environment variable, so at a cmd prompt search for regasm.exe, guidgen.exe and sn.exe (you might find several versions – select the one with the latest date).
•   cd\
•   dir/s regasm.exe
•   dir/s sn.exe
•   dir/s guidgen.exe


So as an example, a COM object that has just one method which just returns “Hello”:
Our eventual aim is to use it like this:
<%@Language=JScript%>
<%
var x = Server.CreateObject("blah.whatever");
Response.Write(x.someMethod());
%>

or 

<%@Language=VBScript%>
<%
dim x
set x = Server.CreateObject("blah.whatever")
Response.Write x.someMethod()
%>

•   Start C# and create a new project
•   Select “Empty Project”
•   Give it a name – this becomes the namespace by default (the blah in the sample above)
•   Next save the project (so you know where to go for the next bit).  This will create a folder structure like so:
o   blah    this contains your solution files that the editor needs (blah.sln etc)
   blah    this contains your source code and project files
•   bin
o   Debug           the compiled output ends up here
•   Next, using the cmd console, navigate to the root blah folder and create a key pair file:
   sn –k key.snk
•   Next you need a unique guid (enter guidgen at the cmd prompt)
o   Select registry format
o   Click “New Guid”
o   Click “Copy”
•   Back to C# editor – from the menu, select Project – Add Class
•   Give it a name – this is the whatever in the sample above
•   After the opening brace just after the namespace line type:
   [GuidAttribute(“paste your guid here”)]
   remove the curly brackets from your pasted guid
•   You will need to add another “using” at the top
  using System.Runtime.InteropServices;
•   Finally you need to create someMethod

The final C# code looks like this (the bits in red may be different in your version):
using System;
using System.Collections.Generic;
using System.Linq;
using System.Text;
using System.Runtime.InteropServices;

namespace blah
{
    [GuidAttribute("AEF4F27F-9E97-4189-9AD5-64386A1699A7")]
    public class whatever
    {
        public string someMethod()
        {
            return "Hello";
        }
    }
}

•   Next, from the menu, select Project – Properties
o   On the left, select Application and, for the Output type dropdown, select “Class Library”
o   On the left, select Signing and tick the “Sign the assembly” box, then browse to the key.snk file you made earlier
o   Save the properties (CTRL-S)
•   Next build the dll (Press F6) – This will create a dll in the Debug folder
•   Open a cmd window as administrator (right click cmd.exe and select “Run as Administrator”)
•   Navigate to the Debug folder and enter the following to register the assembly:
  regasm blah.dll /tlb:blah.tlb /codebase blah

That’s it – the above is a genuine COM component and will work in other applications, the example below allows for event handling and only really works in ASP due to the default property mechanism of ASP:

Den code für die base64-Zeug wäre:

    // returns a base 64 encoded string that has been encrypted with SHA256
    // parameters:
    //  s   string to encrypt
    //  k   key to use during encryption
    public string getBase64SHA256(string s, string k)
    {
        HMACSHA256 sha = new HMACSHA256();
        System.Text.UTF8Encoding encoding = new System.Text.UTF8Encoding();
        sha.Key = encoding.GetBytes(k);
        byte[] hashBytes = sha.ComputeHash(encoding.GetBytes(s));
        return System.Convert.ToBase64String(hashBytes);
    }

    // returns a base 64 encoded string that has been encrypted with SHA1
    // parameters:
    //  s   string to encrypt
    //  k   key to use during encryption
    public string getBase64SHA1(string s, string k)
    {
        HMACSHA1 sha = new HMACSHA1();
        System.Text.UTF8Encoding encoding = new System.Text.UTF8Encoding();
        sha.Key = encoding.GetBytes(k);
        byte[] hashBytes = sha.ComputeHash(encoding.GetBytes(s));
        return System.Convert.ToBase64String(hashBytes);
    }

Müssen Sie die relevanten aufzuhalten der Benutzung:

using System.Security.Cryptography;

Unterschrift zu voll werden, müssen alle query-string name-Wert-Paare in alphabetischer Reihenfolge vor, die Berechnung des SHA " und "base64". Hier ist meine version des Signatur-creator-Funktion:

function buildAmazonSignature(host,req,qstring)
{
    var str="", i, arr = String(qstring).split("&");

    for (i=0; i<arr.length; i++)
        arr[i] = arr[i].split("=");
    arr.sort(amazonSortFunc);

    for (i=0; i<arr.length; i++)
    {
        if (str != "")
            str += "&";

        str += arr[i][0] + "=" + arr[i][1];
    }

    str = "GET\n"+host+"\n"+req+"\n"+str;

    var utils = Server.CreateObject("FMAG.Utils");
    var b64 = utils.getBase64SHA256(str, "xxxxxxxxxx");
    utils = null;

    return amazonEncode(b64);
}

function amazonSortFunc(a,b)
{
    return (a[0]<b[0])?-1:((a[0]>b[0])?1:0);
}

VBScript nicht über eine sehr gute array-sort-Anlage, so dass Sie arbeiten müssen, dass man aus sich selbst - sorry

Auch ich habe die Zeitstempel in diesem format:

YYYY-MM-DDTHH:MM:SSZ

Auch die Sachen, die in der Abfragezeichenfolge enthalten die folgenden:

AWSAccessKeyId
SignatureMethod
SignatureVersion
Version
Expires
Action

Hoffe, das hilft

InformationsquelleAutor Graham

Danke dir so sehr für diese Frage, es war wie ein große Hilfe um zu starten meine WSH/VBScript für mein S3-backup-service 😉

Ich habe nicht viel Zeit, also werde ich nicht durch die Einzelheiten der Dinge, die ich geändert von Chris' code, aber bitte finden Sie nachstehend meine kleine Prototyp Skript funktioniert perfekt 😉

Dies ist nur ein WSH/VBScript, so dass Sie nicht brauchen, IIS, um es auszuführen, müssen Sie nur fügen Sie den Inhalt in eine Datei mit der ".vbs" - Erweiterung, und Sie können dann direkt ausführen 😉

Option Explicit
'-- Amazon Web Services > My Account > Access Credentials > Access Keys --'
Dim strAccessKeyID: strAccessKeyID = "..."
Dim strSecretAccessKey: strSecretAccessKey = "..."
'-- Parameters: --'
Dim strLocalFile: strLocalFile = "..."
Dim strRemoteFile: strRemoteFile = "..."
Dim strBucket: strBucket = "..."
'-- Authentication: --'
Dim strNowInGMT: strNowInGMT = NowInGMT()
Dim strStringToSign: strStringToSign = _
  "PUT" & vbLf & _
  "" & vbLf & _
  "text/xml" & vbLf & _
  strNowInGMT & vbLf & _
  "/" & strBucket + "/" & strRemoteFile
Dim strSignature: strSignature = ConvertBytesToBase64(HMACSHA1(strSecretAccessKey, strStringToSign))
Dim strAuthorization: strAuthorization = "AWS " & strAccessKeyID & ":" & strSignature
'-- Upload: --'
Dim xhttp: Set xhttp = CreateObject("MSXML2.ServerXMLHTTP")
xhttp.open "PUT", "http://" & strBucket & ".s3.amazonaws.com/" & strRemoteFile, False
xhttp.setRequestHeader "Content-Type", "text/xml"
xhttp.setRequestHeader "Date", strNowInGMT 'Yes, this line is mandatory ;-) --'
xhttp.setRequestHeader "Authorization", strAuthorization
xhttp.send GetBytesFromFile(strLocalFile)
If xhttp.status = "200" Then
  WScript.Echo "The file has been successfully uploaded ;-)"
Else
  WScript.Echo "There was an error :-(" & vbCrLf & vbCrLf & _
  xhttp.responseText
End If
Set xhttp = Nothing
'-- NowInGMT ------------------------------------------------------------------'
Function NowInGMT()
  'This is probably not the best implementation, but it works ;-) --'
  Dim sh: Set sh = WScript.CreateObject("WScript.Shell")
  Dim iOffset: iOffset = sh.RegRead("HKLM\System\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")
  Dim dtNowGMT: dtNowGMT = DateAdd("n", iOffset, Now())
  Dim strDay: strDay = "NA"
  Select Case Weekday(dtNowGMT)
    Case 1 strDay = "Sun"
    Case 2 strDay = "Mon"
    Case 3 strDay = "Tue"
    Case 4 strDay = "Wed"
    Case 5 strDay = "Thu"
    Case 6 strDay = "Fri"
    Case 7 strDay = "Sat"
    Case Else strDay = "Error"
  End Select
  Dim strMonth: strMonth = "NA"
  Select Case Month(dtNowGMT)
    Case 1 strMonth = "Jan"
    Case 2 strMonth = "Feb"
    Case 3 strMonth = "Mar"
    Case 4 strMonth = "Apr"
    Case 5 strMonth = "May"
    Case 6 strMonth = "Jun"
    Case 7 strMonth = "Jul"
    Case 8 strMonth = "Aug"
    Case 9 strMonth = "Sep"
    Case 10 strMonth = "Oct"
    Case 11 strMonth = "Nov"
    Case 12 strMonth = "Dec"
    Case Else strMonth = "Error"
  End Select
  Dim strHour: strHour = CStr(Hour(dtNowGMT))
  If Len(strHour) = 1 Then strHour = "0" & strHour End If
  Dim strMinute: strMinute = CStr(Minute(dtNowGMT))
  If Len(strMinute) = 1 Then strMinute = "0" & strMinute End If
  Dim strSecond: strSecond = CStr(Second(dtNowGMT))
  If Len(strSecond) = 1 Then strSecond = "0" & strSecond End If
  Dim strNowInGMT: strNowInGMT = _
    strDay & _
    ", " & _
    Day(dtNowGMT) & _
    " " & _
    strMonth & _
    " " & _
    Year(dtNowGMT) & _
    " " & _
    strHour & _
    ":" & _
    strMinute & _
    ":" & _
    strSecond & _
    " +0000"
  NowInGMT = strNowInGMT
End Function
'-- GetBytesFromString --------------------------------------------------------'
Function GetBytesFromString(strValue)
  Dim stm: Set stm = CreateObject("ADODB.Stream")
  stm.Open
  stm.Type = 2
  stm.Charset = "ascii"
  stm.WriteText strValue
  stm.Position = 0
  stm.Type = 1
  GetBytesFromString = stm.Read
  Set stm = Nothing
End Function
'-- HMACSHA1 ------------------------------------------------------------------'
Function HMACSHA1(strKey, strValue)
  Dim sha1: Set sha1 = CreateObject("System.Security.Cryptography.HMACSHA1")
  sha1.key = GetBytesFromString(strKey)
  HMACSHA1 = sha1.ComputeHash_2(GetBytesFromString(strValue))
  Set sha1 = Nothing
End Function
'-- ConvertBytesToBase64 ------------------------------------------------------'
Function ConvertBytesToBase64(byteValue)
  Dim dom: Set dom = CreateObject("MSXML2.DomDocument")
  Dim elm: Set elm = dom.CreateElement("b64")
  elm.dataType = "bin.base64"
  elm.nodeTypedValue = byteValue
  ConvertBytesToBase64 = elm.Text
  Set elm = Nothing
  Set dom = Nothing
End Function
'-- GetBytesFromFile ----------------------------------------------------------'
Function GetBytesFromFile(strFileName)
  Dim stm: Set stm = CreateObject("ADODB.Stream")
  stm.Type = 1 'adTypeBinary --'
  stm.Open
  stm.LoadFromFile strFileName
  stm.Position = 0
  GetBytesFromFile = stm.Read
  stm.Close
  Set stm = Nothing
End Function

Liebe Stein-edge-Technologie-VBScript-Verknüpfungen (*), lassen Sie mich wissen,, wenn es für Sie arbeitet, wie auch 😉

(*) Dies ist ein Verweis auf den Kommentar von Spudley, siehe oben 😉

InformationsquelleAutor Babelabout

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.