Konvertieren von ActionScript 2.0-code auf ActionScript 3.0

Ich derzeit Folgen einer flash-online-tutorial zum erstellen einer interaktiven Skizzenblock. Der link zum tutorial ist http://flashexplained.com/actionscript/making-an-interactive-drawing-sketchpad/.

Das einzige problem mit diesem tutorial ist, dass der code für actionscript 2.0 statt 3.0. Ich weiß, wie definieren Sie die Variablen, aber außer, dass ich bin ratlos, so war ich der Hoffnung, jemand kann mir helfen, konvertieren Sie den code zu ActionScript 3.0.

Hier ist das ActionScript 2.0-code:

lineThickness = 0;
selectedColor = "0x000000";

_root.onMouseDown = startDrawing;
_root.onMouseUp = stopDrawing;

function startDrawing()
{
    if(_xmouse < 455)
    {
        _root.lineStyle(lineThickness, selectedColor);
        _root.moveTo(_root._xmouse, _root._ymouse);
        _root.onMouseMove = drawLine;
    }
}

function drawLine()
{
    _root.lineTo(this._xmouse, this._ymouse);
}


function stopDrawing()
{
    delete this.onMouseMove;
}

line0.onPress = function()
{
    lineThickness = 0;
}

line3.onPress = function()
{
    lineThickness = 3;
}

line6.onPress = function()
{
    lineThickness = 6;
}

colorRed.onPress = function()
{
    selectedColor = "0xFF0000";
}

colorGreen.onPress = function()
{
    selectedColor = "0x00FF00";
}
InformationsquelleAutor Learn123 | 2012-07-24
  1. 3

    AS2:

    lineThickness = 0;
selectedColor = "0x000000";

    AS3:

    var lineThickness:int = 0;
var selectColor:uint = 0x000000;

    AS2:

    _root.onMouseDown = startDrawing;
_root.onMouseUp = stopDrawing;

function startDrawing()
{
    if(_xmouse < 455)
    {
        _root.lineStyle(lineThickness, selectedColor);
        _root.moveTo(_root._xmouse, _root._ymouse);
        _root.onMouseMove = drawLine;
    }
}

function stopDrawing()
{
    delete this.onMouseMove;
}

function drawLine()
{
    _root.lineTo(this._xmouse, this._ymouse);
}

    AS3:

    stage.addEventListener(MouseEvent.MOUSE_DOWN, startDrawing);
stage.addEventListener(MouseEvent.MOUSE_UP, stopDrawing);

function startDrawing(e:MouseEvent):void
{
    if(mouseX < 455)
    {
        this.graphics.lineStyle(lineThickness, selectedColor);
        this.graphics.moveTo(mouseX, mouseY);

        stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMove);
    }
}

function stopDrawing(e:MouseEvent):void
{
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMove);
}

function mouseMove(e:MouseEvent):void
{
    this.graphics.lineTo(mouseX, mouseY);
}

    AS2:

    line0.onPress = function()
{
    lineThickness = 0;
}

line3.onPress = function()
{
    lineThickness = 3;
}

line6.onPress = function()
{
    lineThickness = 6;
}

colorRed.onPress = function()
{
    selectedColor = "0xFF0000";
}

colorGreen.onPress = function()
{
    selectedColor = "0x00FF00";
}

    AS3:

    line0.addEventListener(MouseEvent.CLICK, changeLine);
line3.addEventListener(MouseEvent.CLICK, changeLine);
line6.addEventListener(MouseEvent.CLICK, changeLine);
colorRed.addEventListener(MouseEvent.CLICK, changeColor);
colorGreen.addEventListener(MouseEvent.CLICK, changeColor);

function changeLine(e:MouseEvent):void
{
    switch(e.currentTarget)
    {
        default: lineThickness = 1; break;

        case line0: lineThickness = 0; break;
        case line3: lineThickness = 0; break;
        case line6: lineThickness = 0; break;
    }
}

function changeColor(e:MouseEvent):void
{
    switch(e.currentTarget)
    {
        default: selectedColor = 0x000000;

        case colorRed: selectedColor = 0xFF0000; break;
        case colorGreen: selectedColor = 0x00FF00; break;
    }
}

    Zusätzliche (klar die Grafik):

    eraser_btn.addEventListener(MouseEvent.CLICK, erase);
function erase(e:MouseEvent):void
{
    this.graphics.clear();
}
    • Ich kopierte den code und getestet, die flash, und ich erhielt eine Fehlermeldung, die sagt, "1120: Access of Undefined property selectedColor." Muss ich definieren, die es irgendwie?
    • Korrigiert habe ich die 1120 Fehler. Wenn Sie deklariert die variable an der Spitze, die Sie eingegeben haben selectColor statt selectedColor. Allerdings bekomme ich jetzt eine Fehlermeldung, die sagt: Error #1063: Argument count mismatch auf paintcanvas_fla::MainTimeline/stopDrawing(). Erwartet 0, bekam 1. Was bedeutet es?
    • Hoppla, fügen Sie e:MouseEvent in stopDrawing().
    • Vielen, vielen Dank!!! Es funktioniert jetzt.
    • Ich bin so Leid, aber ich habe noch eine Letzte Frage. Wie kann konvertieren eraser_btn.onPress = function() { _root.clear(); }; Actionscript 3.0?
    • Folgen Sie den Schritten nach oben für das hinzufügen einer Ereignis-listener, um die eraser_btn Objekt. Die Funktion für das listener enthalten this.graphics.clear().
    • Es funktioniert jetzt, aber wie ändere ich den Maus-Zeiger, wenn er sich über den button?
    • true;
    • Vielen, vielen Dank!
    • Keine Sorge. Darf ich vorschlagen, Annahme, dass diese Antwort?
    • Ja, tut mir Leid, ich wollte nicht sehen, Ihren Kommentar bis jetzt.
    • sorry, ich bin ziemlich neu auf dieser website. Ich habe gerade akzeptiert Ihre Antwort. Ich danke Ihnen so sehr für Ihre Hilfe!
    • Kein problem, danke für die guten sport.

    InformationsquelleAutor Marty
  2. 0

    Empfehle ich Ihnen die Lektüre dieses http://www.actionscriptcheatsheet.com/downloads/as3cs_migration.pdf

    Aber, hier einige Tipps.

    Ereignisse, die Sie code wie diesen

    object.addEventListener(Event.EVENT_TYPE,myFunctionToHandleTheEvent);

    im Fall von 

    _root.lineStyle(lineThickness, selectedColor);
_root.moveTo(_root._xmouse, _root._ymouse);

    verwenden Sie diese

    this.graphics.lineStyle(lineThickness, selectedColor);
this.graphics.moveTo(stage.mouseX, stage.mouseY);

    entfernen Sie einen Ereignis-listener verwenden

    object.removeEventListener(Event.EVENT_TYPE,myFunction);
    • Danke, ich werde bei dem link, den Sie zuerst.
    • FYI - link ist kaputt.
    InformationsquelleAutor João Mosmann
Schreibe einen Kommentar