Korrupte Form - Rettung oder Remake?

Andere geliefert haben, Sie mit verschiedenen Ansätzen, um möglicherweise wiederherstellen Ihrer beschädigten form. Manchmal ist ein code-Lager-Access-Objekt wird unwiederbringlich beschädigt und keine dieser Methoden funktioniert. In diesem Fall müssen Sie look= at-sicherungen finden Sie eine nicht beschädigte version als Ausgangspunkt und import, und dann überarbeiten Sie es zurück auf den aktuellen Zustand des Objekts.

Bin ich Entsendung eine Antwort vorschlagen, dass Sie wahrscheinlich brauchen, um Ihre Codierung Praktiken, wenn Sie die Begegnung mit der Korruption in den code-tragenden Objekten.

1. Erste, Sie brauchen, um sicherzustellen, dass Sie regelmäßige backups und nicht überschreiben. Rollback zu einer früheren version ist immer der Letzte Ausweg.

2. Schalten Sie immer KOMPILIERUNG AUF NACHFRAGE in den VBE-Optionen. Lesen Sie Michael Kaplans Artikel über Der Real Deal auf dem Decompile-Schalter für die Erklärung, warum.

3. In der VBE, fügen Sie den compile-button (und den call-stack-Taste), um Ihre regelmäßige VBE-Symbolleiste, und drücken Sie die Schaltfläche kompilieren nach allen paar Zeilen code, und speichern Sie Ihre code.

4. Entscheiden, auf einem angemessenen Intervall zu sichern und zu dekompilieren der app. Wenn Sie heavy-duty-code stampfen, möchten Sie vielleicht, dies zu tun jeden Tag. Wenn Sie erlebt haben eine Access-Absturz während der Codierung, die Sie wahrscheinlich wollen, um Ihre backup-und dekompilieren/kompilieren. Sicherlich vor dem verteilen an Benutzer, Sie sollten zu dekompilieren und kompilieren der app.

Wenn Sie diese Praktiken, die Ursachen der Korruption in code-Lager-Access-Objekte minimiert werden, so viel wie möglich, während Sie haben auch viel von backups (mehrere Ebenen von redundanten backups sind ein muss, denn wenn die backup-Fehler passieren, sind Sie fast immer Kaskade über mehrere Ebenen-haben mehrere Arten von backup-und verlassen Sie sich nicht auf eine automatische Sicherung (backup).

Aber der wichtigste Punkt:

Kompilieren oft, zu dekompilieren einigermaßen oft und eklig Zeug niemals eine chance haben, sich in die p-code Ihrer Anwendung.

Dekompilieren ist eine gute Sache, zu versuchen, einmal, Sie haben eine Kopie der Datenbank. Haben Sie versucht, speichern das Formular unter einem anderen Namen mit Datei >> Speichern unter? Auch versuchen Sie, kopieren und einfügen das Formular mit einem anderen Namen aus der Datenbank-Fenster.

Außerdem ist es meine Erfahrung gewesen, dass eine korrupte form/Bericht nicht zu verbreiten, um dem rest der Datenbank. Das heißt, es tut nicht weh, Dinge zu bereinigen. Komprimieren und reparieren behebt nur Tabellen und damit verbundene Daten, wie Indizes und Beziehungen. Zu reinigen beschädigt, die anderen Objekte wie Formulare und Berichte müssen Sie importieren in eine neue MDB/ACCDB. Tipp: Schließen Sie die Datenbank-container-Fenster, wenn Sie eine Menge von Objekten. Zugang verschwendet viel Zeit beim import aktualisieren der Datenbank-container Fenster.

Habe ich, dass mir das passieren viele Male. Hier sind ein paar der Dinge, die gespeichert mein Speck. Ich gehe davon aus, dass Sie mit Access 2003 oder höher. Probieren Sie konvertieren die Datenbank in Access 2002 oder 2000-format. Dann konvertieren Sie die Datenbank zurück, um Ihre aktuelle version.

Hier ist etwas code, den ich erstellt zur Bekämpfung von Paketen in früheren Versionen. Es löste auch dieses Problem für mich 95% der Zeit.

Option Compare Database
Option Explicit

Private Sub cmdCreateDuplicate_Click()
'********************************************************
' Author        Daniel Tweddell
' Revision Date 10/27/05
'
' To Combat bloat, we are recreating the a new database
'********************************************************
On Error GoTo Err_Function
    Dim strNewdb As String
    Dim AppNewDb As New Access.Application 'the new database we're creating to manage the updates
    strNewdb = CurrentProject.Path & "\db1.mdb"
    SysCmd acSysCmdSetStatus, "Creating Database. . ."
    With AppNewDb
        DeleteFile strNewdb 'make sure it's not already there
        .Visible = False 'hear no database see no database
        .NewCurrentDatabase strNewdb 'open it
        ChangeRemoteProperty "StartupShowDbWindow", AppNewDb, , dbBoolean, False
        ChangeRemoteProperty "Auto compact", AppNewDb, , dbBoolean, True
        ImportReferences AppNewDb, Application
        .CloseCurrentDatabase
    End With
    Set AppNewDb = Nothing
    Dim ao As AccessObject
    For Each ao In CurrentData.AllTables
        If Left(ao.Name, 4) <> "msys" Then
            DoCmd.TransferDatabase acExport, "Microsoft Access", strNewdb, acTable, ao.Name, ao.Name
            SysCmd acSysCmdSetStatus, "Exporting " & ao.Name & ". . ."
        End If
    Next
    For Each ao In CurrentData.AllQueries
        DoCmd.TransferDatabase acExport, "Microsoft Access", strNewdb, acQuery, ao.Name, ao.Name
        SysCmd acSysCmdSetStatus, "Exporting " & ao.Name & ". . ."
    Next
    For Each ao In CurrentProject.AllForms
        DoCmd.TransferDatabase acExport, "Microsoft Access", strNewdb, acForm, ao.Name, ao.Name
        SysCmd acSysCmdSetStatus, "Exporting " & ao.Name & ". . ."
    Next
    For Each ao In CurrentProject.AllReports
        DoCmd.TransferDatabase acExport, "Microsoft Access", strNewdb, acReport, ao.Name, ao.Name
        SysCmd acSysCmdSetStatus, "Exporting " & ao.Name & ". . ."
    Next
    For Each ao In CurrentProject.AllMacros
        DoCmd.TransferDatabase acExport, "Microsoft Access", strNewdb, acMacro, ao.Name, ao.Name
        SysCmd acSysCmdSetStatus, "Exporting " & ao.Name & ". . ."
    Next
    For Each ao In CurrentProject.AllModules
        DoCmd.TransferDatabase acExport, "Microsoft Access", strNewdb, acModule, ao.Name, ao.Name
        SysCmd acSysCmdSetStatus, "Exporting " & ao.Name & ". . ."
    Next
    MsgBox "Creation Complete!" & vbCrLf & "Reset Password", vbExclamation, "New Database"
Exit Sub
Err_Function:
    ErrHandler Err.Number, Err.Description, Me.Name & " cmdCreateDuplicate_Click()"
End Sub


Function DeleteFile(ByVal strPathAndFile As String) As Boolean
'***********************************************************************************
' Author        Daniel Tweddell
' Revision Date 04/14/03
'
' Deletes a file
'***********************************************************************************
On Error GoTo Err_Function
    DeleteFile = True                   'default to true
    If UncDir(strPathAndFile) <> "" Then   'make sure the file is there
        Kill strPathAndFile             'delete a file
    End If
Exit Function
Err_Function:
    ErrHandler Err.Number, Err.Description, "DeleteFile()", bSilent
    DeleteFile = False                  'if there is a problem, false
End Function

Public Sub ChangeRemoteProperty(strPropName As String, _
                                appToDB As Access.Application, Optional appFromDB As Access.Application, _
                                Optional vPropType As Variant, Optional vPropValue As Variant)
'********************************************************************************
' Author        Daniel Tweddell
' Revision Date 01/13/04
'
' Changes/adds a database property in one db to match another
'********************************************************************************
On Error GoTo Err_Function
    Dim ToDB As DAO.Database
    Dim FromDB As DAO.Database
    Dim prpTest As DAO.Property
    Dim bPropertyExists As Boolean
    Set ToDB = appToDB.CurrentDb
    If Not appFromDB Is Nothing Then Set FromDB = appFromDB.CurrentDb
    bPropertyExists = False 'flag to see if we found the property
    For Each prpTest In ToDB.Properties 'first see if the property exists so we don't error
        If prpTest.Name = strPropName Then
            If IsMissing(vPropValue) Then vPropValue = FromDB.Properties(strPropName) 'in case we want to assign it a specific value
            ToDB.Properties(strPropName) = vPropValue 'if it does set it and get out or the loop
            bPropertyExists = True
            Exit For
        End If
    Next
    If Not bPropertyExists Then ' Property not found.
        Dim prpChange As DAO.Property
        If IsMissing(vPropValue) Then
            With FromDB.Properties(strPropName)
                vPropValue = .Value 'in case we want to assign it a specific value
                vPropType = .Type
            End With
        End If
        Set prpChange = ToDB.CreateProperty(strPropName, vPropType, vPropValue) 'add it
        ToDB.Properties.Append prpChange
    End If
Exit Sub
Err_Function:
    ErrHandler Err.Number, Err.Description, "ChangeRemoteProperty()", bSilent
End Sub

Public Sub ImportReferences(AppNewDb As Access.Application, appUpdateDB As Access.Application, Optional iStatus As Integer)
'********************************************************************************
' Author        Daniel Tweddell
' Revision Date 01/13/04
'
' Copies the current references from the one database to another we're building
'********************************************************************************
On Error GoTo Err_Function
    Dim rNewRef As Reference
    Dim rUpdateRef As Reference
    Dim bReferenceExists As Boolean
    Dim rToAdd As Reference
    Dim sReference As String
    If iStatus <> 0 Then ProgressBarUpdate iStatus, "Referencing Visual Basic Libraries. . ."
    For Each rUpdateRef In appUpdateDB.References
        bReferenceExists = False
        For Each rNewRef In AppNewDb.References
            sReference = rNewRef.Name
            If rUpdateRef.Name = sReference Then
                bReferenceExists = True
                Exit For
            End If
        Next
        If Not bReferenceExists Then
            With rUpdateRef
                Set rToAdd = AppNewDb.References.AddFromGuid(.Guid, .Major, .Minor)
            End With
        End If
    Next
Exit Sub
Err_Function:
    ErrHandler Err.Number, Err.Description, "ImportReferences(" & sReference & ")", bSilent
    Resume Next
End Sub