Laden Sie die Bilder in separate movie-clips aus einer XML, Flash, Actionscript 3.0

Hier ist, wie würde ich es angehen. Das einzige, was ich nicht getan habe ist, ändern Sie die position des MovieClips, nachdem Sie geladen sind, mit den Bildern. Sie könnte leicht fügen Sie in diese Funktion in der imageLoaded () - Funktion.

Setzen Sie den folgenden code in das Bedienfeld "Aktionen" von den ersten frame eine AS3-FLA-Datei. Dies setzt Voraus, dass ein Verzeichnis namens "images" existiert im gleichen Verzeichnis wie die FLA/SWF.

//Create array of image filenames
var filenames:Array = new Array();
filenames[0] = 'some_image.jpg';
filenames[1] = 'some_other_image.jpg';
filenames[2] = 'and_another.jpg';

//Declare variables
const IMAGES_DIRECTORY:String = 'images/';
var loaders:Array = new Array();
var movieClips:Array = new Array();

//This function instantiates the exact number of Loader objects that are required
//and initiates the loading process for each image file. As each image is loaded,
//imageLoaded() is called
function createLoaders(filenamesAsArray:Array, directory:String):void
{
    for(var i:int = 0; i < filenamesAsArray.length; i++)
    {
        loaders[i] = new Loader();
        loaders[i].load(new URLRequest(directory + filenamesAsArray[i]));
        loaders[i].contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
    }
}

createLoaders(filenames, IMAGES_DIRECTORY);

//This function is called as each Loader object is completely loaded
//It creates each individual movieclip, adds the image to it, and then adds the MC to the stage
function imageLoaded(e:Event):void
{
    if(e.target.content.bitmapData)
    {
        var mc:MovieClip = new MovieClip();
        var bmp:Bitmap = new Bitmap(e.target.content.bitmapData);
        mc.addChild(bmp);
        movieClips.push(mc);
        addChild(movieClips[movieClips.length - 1]);
    }
}

Über den Import von XML-Daten

Blick in die XML-Objekt.

das Laden von XML-Beispiel

XML-Dokument zum Beispiel:

<images>
    <image>
        <title>Portrait of a Woman</title>
        <filename>portrait.jpg</filename>
    </image>
    <image>
        <title>Rural Landscape</title>
        <filename>landscape.jpg</filename>
    </image>
    <image>
        <title>My Cat</title>
        <filename>cat.jpg</filename>
    </image>
</images>

Den AS3-für das Laden der obigen XML-Dokument

//Instantiate some objects (URLoader and XML)
var xmlLoader:URLLoader = new URLLoader();
var xmlData:XML = new XML();

//Listen for the instance of URLLoader (xmlLoader) to trigger Event.COMPLETE,
//which will call the function named 'loadXML()'
xmlLoader.addEventListener(Event.COMPLETE, loadXML);

//Initiate the process of loading the XML document
//In this case, 'test.xml' is located in the same directory as the SWF/FLA
//that this code is located in
xmlLoader.load(new URLRequest('test.xml'));

//This is the function that will be called by the event listener above (when
//the xmlLoader signals Event.COMPLETE
function loadXML(e:Event):void
{
    //Retrieve the contents of the XML document
    xmlData = new XML(e.target.data);

    //Trace the entire document:
    trace(xmlData);

    //Trace the filename for the first <image> node
    trace(xmlData.image[0].filename);
}

Natürlich, Ihr XML-Dokument kann sehr unterschiedlich sein, in welchem Fall, Sie brauchen, um Praxis abrufen die genauen Informationen, die Sie wollen. Dies ist der schwierigste Teil, meiner Meinung nach. Auch würden Sie instanziieren ein array außerhalb des Bereichs der loadXML - Funktion oben. Dann, rekursiv füllen Sie das array mit den Dateinamen aus dem XML-Dokument.