Liste alle Dateien von einem Verzeichnis in ein string-grid mit delphi

Diese füllt eine TStrings Nachkomme (eg., TStringList, TMemo.Lihes, und so weiter), die mit allen Dateien in einem angegebenen Ordner:

function  GetFiles(const StartDir: String; const List: TStrings): Boolean;
var
  SRec: TSearchRec;
  Res: Integer;
begin
  if not Assigned(List) then
  begin
    Result := False;
    Exit;
  end;
  Res := FindFirst(StartDir + '*.*', faAnyfile, SRec );
  if Res = 0 then
  try
    while res = 0 do
    begin
      if (SRec.Attr and faDirectory <> faDirectory) then
        // If you want filename only, remove "StartDir +" 
        // from next line
        List.Add( StartDir + SRec.Name );
      Res := FindNext(SRec);
    end;
  finally
    FindClose(SRec)
  end;
  Result := (List.Count > 0);
end;

Verwenden Sie es wie diese füllen Sie Ihre TStringGrid (Grid in den folgenden code - ich code Hinzugefügt, um die automatische Größe der Spalte basierend auf der Länge des längsten Dateinamens):

var
  SL: TStringList;
  i: Integer;
  MaxWidth, CurrWidth: Integer;
const
  Padding = 10;
begin
  SL := TStringList.Create;
  try
    if GetFiles('C:\Temp\', SL) then
    begin
      MaxWidth := Grid.ColWidths[0];
      for i := 0 to SL.Count - 1 do
      begin
        CurrWidth := Grid.Canvas.TextWidth(SL[i]);
        if CurrWidth > MaxWidth then
          MaxWidth := CurrWidth;
        // Populates first column in stringgrid.
        Grid.RowCount := Grid.RowCount + 1;
        Grid.Cells[0, Grid.RowCount - 1] := SL[i];
      end;
      Grid.ColWidths[0] := MaxWidth + Padding;
    end;
  finally
    SL.Free;
  end;
end;

Beachten Sie, dass dieser code benötigt den Pfad einschließen, um den umgekehrten Schrägstrich nach dem Namen des Ordners; Sie können es ändern, einfach, um automatisch fügen Sie es, wenn nötig, oder zu akzeptieren sowohl den Namen eines Ordners und einer Datei-Maske, um nur bestimmte Dateien.

InformationsquelleAutor Ken White