Long-Datentyp Überlauf

Ich versuche zu tun, einige prime factorisation mit meinem VBA-excel-und ich bin schlagen die Grenze des long Daten Typ -

Runtime Error 6 Overflow

Gibt es eine Möglichkeit, dies zu umgehen, und trotzdem bleiben Sie in VBA? Ich bin mir bewusst, dass das selbstverständlich wäre die Nutzung von anderen geeigneten Programmiersprache.

Lance Lösung funktioniert in so weit, dass ich in der Lage bin, um die großen zahlen in die Variablen jetzt. Jedoch, wenn ich versuche, gelten die MOD Funktion - bignumber MOD 2 zum Beispiel das immer noch fehlschlägt mit der Fehlermeldung

Runtime Error 6 Overflow

Ich nehme an, Sie wissen, dass Sie nur Blick für Faktoren von bis zu WURZEL(n)

InformationsquelleAutor Henrik K | 2008-11-17

1

MOD versucht zu konvertieren Sie Ihre DECIMAL-Typ zu LANGE vor dem Betrieb auf Sie. Möglicherweise müssen Sie schreiben Sie Ihre eigenen MOD-Funktion für den Typ "DECIMAL". Sie könnten versuchen, diese:
```
r = A - Int(A / B) * B
```
wo A & B sind in DEZIMAL-Untertyp von VARIANT-Variablen, und r könnte sein, dass die großen auch (je nach Bedarf), obwohl ich nur getestet, auf eine lange.

InformationsquelleAutor Lance Roberts
2

Können Sie die Decimal-Datentyp. Quick-Tipp von google: http://www.ozgrid.com/VBA/convert-to-decimal.htm

InformationsquelleAutor Arvo

Dies ist mein Dezimalstellen.cls (VB6):

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Decimals"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Attribute VB_Ext_KEY = "SavedWithClassBuilder6" ,"Yes"
Attribute VB_Ext_KEY = "Top_Level" ,"Yes"
Option Explicit

'local variable(s) to hold property value(s)
Private mvarDec As Variant 'local copy

Public Property Let Dec(ByVal vData As Variant)
'used when assigning a value to the property, on the left side of an assignment.
'Syntax: X.Dec = 5
    mvarDec = CDec(vData)
End Property

Public Property Get Dec() As Variant
Attribute Dec.VB_UserMemId = 0
'used when retrieving value of a property, on the right side of an assignment.
'Syntax: Debug.Print X.Dec
    Dec = CDec(mvarDec)
End Property

- und dies ist ein Test-Programm. Die Klasse wurde eingerichtet, so dass Sie nicht haben, um sich zu qualifizieren, mit .Dec() auf und lassen.

Dim dec1 As New Std.Decimals
Dim dec2 As New Std.Decimals
Dim dec3 As New Std.Decimals
Dim modulus As New Std.Decimals

Sub main()
    dec1 = "1000.000000001"
    dec2 = "1000.00000000000001"
    dec3 = dec1 + dec2
    Debug.Print dec1
    Debug.Print dec2
    Debug.Print dec3
    Debug.Print dec3 * dec3
    Debug.Print dec3 / 10
    Debug.Print dec3 / 100
    Debug.Print Sqr(dec3)
    modulus = dec1 - Int(dec1 / dec2) * dec2
    Debug.Print modulus
End Sub

und Probe Gefahren werden

 1000.000000001 
 1000.00000000000001 
 2000.00000000100001 
 4000000.000004000040000001 
 200.000000000100001 
 20.0000000000100001 
 44.721359550007 
 0.00000000099999 
 1000.000000001 
 1000.00000000000001 
 2000.00000000100001 
 4000000.000004000040000001 
 200.000000000100001 
 20.0000000000100001 
 44.721359550007 
 0.00000000099999

InformationsquelleAutor bugmagnet

Hier ist mein "großer " multiplizieren" - routine für die Multiplikation beliebig große zahlen (z.B. 100 Zeichen lang). Es funktioniert durch die Aufteilung der eingabezahlen, die strings sind, in Stücke von 7 stellen (denn dann kann er Kreuz multiplizieren Sie Sie, und speichern Sie die Ergebnisse im Doppel).

zB bigmultiply("1934567803945969696433","4483838382211678") = 8674289372323895422678848864807544574

Function BigMultiply(ByVal s1 As String, ByVal s2 As String) As String

Dim x As Long
x = 7

Dim n1 As Long, n2 As Long, n As Long
n1 = Int(Len(s1) / x + 0.999999)
n2 = Int(Len(s2) / x + 0.999999)
n = n1 + n2

Dim i As Long, j As Long
ReDim za1(n1) As Double
i = Len(s1) Mod x
If i = 0 Then i = x
za1(1) = Left(s1, i)
i = i + 1
For j = 2 To n1
 za1(j) = Mid(s1, i, x)
 i = i + x
Next j

ReDim za2(n2) As Double
i = Len(s2) Mod x
If i = 0 Then i = x
za2(1) = Left(s2, i)
i = i + 1
For j = 2 To n2
 za2(j) = Mid(s2, i, x)
 i = i + x
Next j

ReDim z(n) As Double
Dim u1 As Long, u2 As Long
Dim e As String
e = String(x, "0")

For u1 = 1 To n1
 i = u1
 For u2 = 1 To n2
   i = i + 1
   z(i) = z(i) + za1(u1) * za2(u2)
 Next u2
Next u1

Dim s As String, y As Double, w As Double, m As Long
m = n * x
s = String(m, "0")
y = 10 ^ x
For i = n To 1 Step -1
 w = Int(z(i) / y)
 Mid(s, i * x - x + 1, x) = Format(z(i) - w * y, e)
 z(i - 1) = z(i - 1) + w
Next i
'truncate leading zeros
For i = 1 To m
 If Mid$(s, i, 1) <> "0" Then Exit For
Next i
If i > m Then
 BigMultiply = ""
Else
 BigMultiply = Mid$(s, i)
End If

End Function

InformationsquelleAutor dbb

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.