mit der Länge null-Spalten sind nicht erlaubt - das Erstellen einer Tabelle aus der Ansicht

Als Sie sagte, Sie rufen eine Prozedur auf eine Tabelle erstellen aus der Ansicht. Also gehe ich davon aus, dass Sie bereits mit dynamic SQL (Native Dynamic SQL aka EXECUTE IMMEDIATE Anweisung oder DBMS_SQL - Paket) zum ausführen von DDL-Anweisungen. Dann könnte man generieren komplizierter CREATE TABLE AS - Anweisung, mit mit dem Oracle-dictionary-Ansichten wie USER_VIEWS und USER_TAB_COLUMNS, um Informationen über die Spalten " Arten, Länge, Maßstab und was du sonst noch brauchst um zu schreiben, eine richtige BESETZUNG nennen.

Einem schmutzigen Beispiel ist unten:

create or replace view v 
as 
  select decode(dummy, 'Y', '123') s 
       , 1 n
       , 2.2 f
       , cast (1.1 as number(5,3)) fs
    from dual
/

set serveroutput on
declare
  l_query varchar2(32767) := 'create table t as select <column list> from v';
  l_type varchar2(100);
begin
  for tc in (
    select * from user_tab_columns 
     where table_name = 'V'
     order by column_id
  ) loop
    l_type := tc.data_type;
    l_type := l_type || 
      case tc.data_type 
        when 'NUMBER' then 
          case when tc.data_precision is not null then '(' || tc.data_precision || case when tc.data_scale is not null then ','||tc.data_scale end || ')' end
        when 'VARCHAR2' then 
          '(' || tc.char_length || ' ' || case tc.char_used when 'C' then 'char' else 'byte' end || ')' 
       end;
    l_query := replace(l_query, '<column list>', 'cast("'||tc.column_name||'" as '|| l_type ||') "'||tc.column_name||'" ,<column list>');
  end loop;
  l_query := replace(l_query, ',<column list>');

  dbms_output.put_line(l_query);
end;
/

Ergebnisse:

view V created.
anonymous block completed
create table t as select cast("S" as VARCHAR2(3 char)),cast("N" as NUMBER),cast("F" as NUMBER),cast("FS" as NUMBER(5,3)) from v

Glück.

InformationsquelleAutor suPPLer