Mit WMSYS.WM_CONCAT mit Oracle XE 10g

Wenn ich versuche, mit WMSYS.WM_CONCAT mit Oracle XE 10g, erhalte ich einen Kompilierungsfehler: ORA-00904: "WMSYS"."WM_CONCAT": invalid identifier. Kann jemand überprüfen, dass diese tatsächlich aufgrund XE fehlt dieser (undokumentierte) Funktion? Wenn dem so ist, ist es sowieso zu aktivieren, die es im XE?

InformationsquelleAutor Stephen Swensen | 2010-08-18

3

Fand ich ein paar Referenz-Seiten, aber hatte kein Glück ermöglicht. Landete ich Schreibe meine eigene Funktion zum behandeln der Verkettung.
```
CREATE or replace FUNCTION CONCAT_LIST( cur SYS_REFCURSOR, sep Varchar2 ) RETURN  VARCHAR2 IS
ret VARCHAR2(32000);
tmp VARCHAR2(4000);
BEGIN
loop
  fetch cur into tmp;
  exit when cur%NOTFOUND;
    if ret is null then
       ret := tmp;
    else
      ret := ret || sep || tmp;
    end if;

end loop;
RETURN ret; END;/
```
Dann kann man

SELECT distinct CONCAT_LIST(CURSOR(SELECT id FROM test_table1), ',') test_table1 FROM dual

Danke, ich bin wirklich gespannt, ob diese Funktion aktiviert werden kann. Die beste alternative, die ich fand, war das benutzerdefinierte Aggregat-Funktion hier: oracle-base.com/articles/misc/StringAggregationTechniques.php. Umbenannt habe ich die Funktion von string_agg zu wm_concat seit dann kann ich die Freigabe von gespeicherten Prozeduren mit meinem co-Arbeitskräfte, die vollständige oracle 10g (die Methode, die im Artikel angegeben kann die gleiche syntax, die Sie verwenden würden, mit der realen wm_concat -- solange Sie nicht mithilfe von Skripts, die voll qualifiziert wm_concat mit wm_sys)
Das ist ziemlich glatt. Ich habe ein paar große Abfragen, dass ich diese Funktion. Sobald ich wieder im Büro erstelle ich die neue ein und überprüfen Sie die Leistung. Das hat mich neugierig gemacht. Danke!
Cool, ich würde gerne hören, Ihre performance-Ergebnisse, wenn du fertig bist.
Ich habe einige Tests über beide Funktionen, CONCAT_LIST und STRING_AGG gefunden und ich musste, um eine änderung zu meiner Funktion. Ich habe vergessen zu schließen, den cursor und ich das Maximum der erlaubten Menge ziemlich schnell. Nach der änderung habe ich eine Abfrage erstellt, die gruppiert eine Reihe von 250 Geschäfte auf Ihren entsprechenden Typ. Die CONCAT_LIST abgeschlossen 2.68 Sekunden und die STRING_AGG von oracle-Basis abgeschlossen 0,38 Sekunden und sieht viel sauberer aus. Ich verändert habe einige Fragen, die ich hatte, um auf diese neue Funktion. Hier dachte ich, ich könnte Ihnen helfen und Sie endete mir zu helfen. DANKE!
Hehe, hört sich toll an, du bist willkommen!

InformationsquelleAutor RandyB

Quelle: link.

Erstellen Sie einfach diese Funktion mit sich:

CREATE OR REPLACE TYPE wm_concat_impl
   AUTHID CURRENT_USER
AS OBJECT (
   curr_str   VARCHAR2 (32767),
   STATIC FUNCTION odciaggregateinitialize (sctx IN OUT wm_concat_impl)
      RETURN NUMBER,
   MEMBER FUNCTION odciaggregateiterate (
      SELF   IN OUT   wm_concat_impl,
      p1     IN       VARCHAR2
   )
      RETURN NUMBER,
   MEMBER FUNCTION odciaggregateterminate (
      SELF          IN       wm_concat_impl,
      returnvalue   OUT      VARCHAR2,
      flags         IN       NUMBER
   )
      RETURN NUMBER,
   MEMBER FUNCTION odciaggregatemerge (
      SELF    IN OUT   wm_concat_impl,
      sctx2   IN       wm_concat_impl
   )
      RETURN NUMBER
);
/

CREATE OR REPLACE TYPE BODY wm_concat_impl
IS
   STATIC FUNCTION odciaggregateinitialize (sctx IN OUT wm_concat_impl)
      RETURN NUMBER
   IS
   BEGIN
      sctx := wm_concat_impl (NULL);
      RETURN odciconst.success;
   END;
   MEMBER FUNCTION odciaggregateiterate (
      SELF   IN OUT   wm_concat_impl,
      p1     IN       VARCHAR2
   )
      RETURN NUMBER
   IS
   BEGIN
      IF (curr_str IS NOT NULL)
      THEN
         curr_str := curr_str || ',' || p1;
      ELSE
         curr_str := p1;
      END IF;

      RETURN odciconst.success;
   END;
   MEMBER FUNCTION odciaggregateterminate (
      SELF          IN       wm_concat_impl,
      returnvalue   OUT      VARCHAR2,
      flags         IN       NUMBER
   )
      RETURN NUMBER
   IS
   BEGIN
      returnvalue := curr_str;
      RETURN odciconst.success;
   END;
   MEMBER FUNCTION odciaggregatemerge (
      SELF    IN OUT   wm_concat_impl,
      sctx2   IN       wm_concat_impl
   )
      RETURN NUMBER
   IS
   BEGIN
      IF (sctx2.curr_str IS NOT NULL)
      THEN
         SELF.curr_str := SELF.curr_str || ',' || sctx2.curr_str;
      END IF;

      RETURN odciconst.success;
   END;
END;
/

CREATE OR REPLACE FUNCTION wm_concat (p1 VARCHAR2)
   RETURN VARCHAR2
   AGGREGATE USING wm_concat_impl;
/

InformationsquelleAutor smnbbrv

Es wird empfohlen, nicht zu verwenden WM_CONCAT, da es ein nicht dokumentiertes feature, und es hat gewesen entfernt von 12c-version. Sehen Warum nicht WM_CONCAT-Funktion in Oracle?

Wenn Sie auf 11gR2 und Sie LISTAGG.

Version vor 11g wo LISTAGG wird nicht unterstützt, könnten Sie ROW_NUMBER() und SYS_CONNECT_BY_PATH Funktionen.

Beispielsweise

SELECT deptno,
       LTRIM(MAX(SYS_CONNECT_BY_PATH(ename,','))
       KEEP (DENSE_RANK LAST ORDER BY curr),',') AS employees
FROM   (SELECT deptno,
               ename,
               ROW_NUMBER() OVER (PARTITION BY deptno ORDER BY ename) AS curr,
               ROW_NUMBER() OVER (PARTITION BY deptno ORDER BY ename) -1 AS prev
        FROM   emp)
GROUP BY deptno
CONNECT BY prev = PRIOR curr AND deptno = PRIOR deptno
START WITH curr = 1;

    DEPTNO EMPLOYEES
---------- --------------------------------------------------
        10 CLARK,KING,MILLER
        20 ADAMS,FORD,JONES,SCOTT,SMITH
        30 ALLEN,BLAKE,JAMES,MARTIN,TURNER,WARD

3 rows selected.

InformationsquelleAutor Lalit Kumar B

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.