MS Access: programmgesteuert Spalten umbenennen

Schrieb ich code für eine app erst Letzte Woche:

  Public Sub RenameFields(ByRef tdf As DAO.TableDef)
    Dim fld As DAO.Field
    Dim strFieldName As String
    Dim strNewName As String

    Debug.Print "==============================================" & vbCrLf & UCase(tdf.Name)
    For Each fld In tdf.Fields
      strFieldName = fld.Name
      strNewName = Mid(strFieldName, 4)
      Select Case Left(strFieldName, 3)
        Case "boo", "byt", "cur", "dat", "hyp", "int", "mem", "obj", "txt"
          fld.Name = strNewName
          Debug.Print tdf.Name & "." & strFieldName & "=>" & strNewName
      End Select
    Next fld
    Set fld = Nothing
  End Sub

In diesem Fall, einen früheren Entwickler hatte dummerweise verwendet VBA-Variablen-Benennungs-Konventionen für Feldnamen (txtLastName für das, was sollte sein Nachname zum Beispiel) und ich brauchte, um alle zu entfernen. Der code wird so aufgerufen:

  Dim tdf As DAO.TableDef

  For Each tdf in CurrentDB.TableDefs
    If Left(tdf.Name,3) = "tbl" Then ' <= this line may differ for you
       Call RenameFields(tdf)
    End If
  Next tdf
  Set tdf = Nothing

Könnten Sie leicht anpassen, RenameFields() sub Replace() verwenden Sie für den neuen Namen, so etwas wie dieses:

  Public Sub RenameFields(ByRef tdf As DAO.TableDef)
    Dim fld As DAO.Field
    Dim strFieldName As String
    Dim strNewName As String

    Debug.Print "==============================================" & vbCrLf & UCase(tdf.Name)
    For Each fld In tdf.Fields
      strFieldName = fld.Name
      strNewName = Replace(strFieldName, "_"," ")
      If strFieldName <> strNewName Then
         fld.Name = strNewName
         Debug.Print tdf.Name & "." & strFieldName & "=>" & strNewName
      End If
    Next fld
    Set fld = Nothing
  End Sub

Alles, was gesagt, ich würde wirklich, wirklich stark darauf hin, dass Sie nicht ersetzen Sie die Unterstriche mit Leerzeichen, da dies macht es viel, viel schwieriger zu arbeiten mit den Feldnamen in SQL und im code. Ich würde die Verwendung der CAMEL case mit keine Unterstriche oder Leerzeichen oder Bindestriche enthalten, so dass die Replace () - Zeile im code oben werden würde:

  strNewName = Replace(StrConv(Replace(strFieldName, "_"," "), vbProper)," ", vbNullString)

Würden konvertieren "Nachname" oder "Nachname" zu "Nachname". Camel-case für die Lesbarkeit von Feldnamen, wurde standard für Access-Entwickler, wie lange habe ich programmiert in Access (seit 1996), und vermeidet die Probleme, die durch Besondere Zeichen oder Leerzeichen (D. H., dass surround-der name des Feldes mit eckigen Klammern).