ORA-00932: inkonsistente Datentypen: erwartet - got -

Ich habe mit Oracle(10g.2) als PHP-Programmierer seit fast 3 Jahren, aber wenn ich gab eine Zuweisung, ich habe versucht, verwenden Sie den ref Cursor-und collection-Typen für die erste Zeit. Und Ich
've durchsucht das web, wenn ich mit Problemen konfrontiert, und dies ora-00932 Fehler wirklich überwältigt mich. Ich brauche Hilfe von einem alten hand.

Hier ist, was ich die Bekämpfung,
Ich möchten wählen Sie Zeilen aus einer Tabelle, und setzen Sie Sie in einen ref-cursor, und dann mit record-Typ, sammeln Sie in einem assoziativen array. Und wieder von diesem assoziativen array, machen einen ref-cursor. Frag mich nicht warum, ich bin das schreiben eines so komplizierten code, weil ich es brauche weitere komplexe Aufgabe. Ich könnte verwirrend klingen, um Sie, so lassen Sie mich Ihnen zeigen, meine codes.

Habe ich 2 Typen definiert in der Registerkarte Dateitypen in Kröte. Einer von Ihnen ist ein Objekt-Typ:

CREATE OR REPLACE
TYPE R_TYPE AS OBJECT(sqn number,firstname VARCHAR2(30), lastname VARCHAR2(30));

Andere ist eine Sammlung geben, die mit den Objekt-Typ erstellt oben:

CREATE OR REPLACE
TYPE tr_type AS TABLE OF r_type;

Dann habe ich ein Paket erstellen:

CREATE OR REPLACE PACKAGE MYPACK_PKG IS
TYPE MY_REF_CURSOR IS REF CURSOR;
PROCEDURE MY_PROC(r_cursor OUT MY_REF_CURSOR);
END MYPACK_PKG;

Paket, Karosserie:

CREATE OR REPLACE PACKAGE BODY MYPACK_PKG AS
 PROCEDURE MY_PROC(r_cursor OUT MY_REF_CURSOR) AS
  rcur MYPACK_PKG.MY_REF_CURSOR;
  sql_stmt VARCHAR2(1000);
  l_rarray   tr_type := tr_type();
                l_rec r_type;

 BEGIN
     sql_stmt :=  'SELECT 1,e.first_name,e.last_name  FROM hr.employees e ';
     OPEN rcur FOR sql_stmt;
     LOOP
       fetch rcur into l_rec;
                  exit when rcur%notfound;
     l_rarray := tr_type( l_rec );
     END LOOP;
   CLOSE rcur;
    --OPEN r_cursor FOR SELECT * FROM TABLE(cast(l_rarray as tr_type) );


END MY_PROC;
END MYPACK_PKG;

Kommentierte ich aus der letzten Zeile, wo ich offen ref cursor. Weil es verursacht einen Fehler, wenn ich die Prozedur ausführen, die im Toad SQL-Editor, und es ist die zweite Frage, die ich Ihnen stellen werde.
Und schließlich habe ich den code auszuführen, der in Toad:

variable r refcursor
declare
r_out MYPACK_PKG.MY_REF_CURSOR;
begin
MYPACK_PKG.MY_PROC(r_out);
:r := r_out;
end;
print :r

Dort bekomme ich die ora-00932 Fehler.

InformationsquelleAutor Duygu Akyol | 2011-01-04
  1. 6

    Die Art, wie du mit der REF-CURSOR ist ungewöhnlich. Dies wäre der normale Weg, Sie zu verwenden:

    SQL> CREATE OR REPLACE PACKAGE BODY MYPACK_PKG AS
  2     PROCEDURE MY_PROC(r_cursor OUT MY_REF_CURSOR) AS
  3     BEGIN
  4        OPEN r_cursor FOR SELECT e.empno,e.ENAME,null  FROM scott.emp e;
  5     END MY_PROC;
  6  END MYPACK_PKG;
  7  /

Corps de package crÚÚ.

SQL> VARIABLE r REFCURSOR
SQL> BEGIN
  2     MYPACK_PKG.MY_PROC(:r);
  3  END;
  4  /

ProcÚdure PL/SQL terminÚe avec succÞs.

SQL> PRINT :r

     EMPNO ENAME      N
---------- ---------- -
      7369 SMITH
      7499 ALLEN
      7521 WARD
      7566 JONES
      7654 MARTIN
      [...]

14 ligne(s) sÚlectionnÚe(s).

    Ich bin mir nicht sicher, was Sie hier versuchen zu erreichen, Sie sind Holen Sie den ref cursor innerhalb der Prozedur und dann wieder eine andere ref-cursor, die die gleichen Daten. Ich glaube nicht, dass es notwendig ist, Holen Sie den cursor an alle in der Prozedur. Lassen Sie die aufrufende app das abrufen (hier das abrufen erfolgt durch die print).

    Update: warum werden die Leute, die nicht gerade hilfreichen Fehlermeldung?

    Bist du mit einem cursor geöffnet dynamisch und ich denke, das ist Teil der Grund, dass Sie immer die sinnlose Fehlermeldungen. Wenn wir mit festen SQL die Fehlermeldung ist anders:

    SQL> CREATE OR REPLACE PACKAGE BODY MYPACK_PKG AS
  2     PROCEDURE MY_PROC(r_cursor OUT MY_REF_CURSOR) AS
  3        TYPE type_rec IS RECORD (qn number,
  4                                 firstname VARCHAR2(30),
  5                                 lastname VARCHAR2(30));
  6        lt_record type_rec; /* Record type */
  7        lt_object r_type; /* SQL Object type */
  8     BEGIN
  9        OPEN r_cursor FOR SELECT e.empno,e.ENAME,null  FROM scott.emp e;
 10        FETCH r_cursor INTO lt_record; /* This will work */
 11        FETCH r_cursor INTO lt_object; /* This won't work in 10.2 */
 12     END MY_PROC;
 13  END MYPACK_PKG;
 14  /

Package body created

SQL> VARIABLE r REFCURSOR
SQL> BEGIN
  2     MYPACK_PKG.MY_PROC(:r);
  3  END;
  4  /
BEGIN
*
ERREUR Ó la ligne 1 :
ORA-06504: PL/SQL: Return types of Result Set variables or query do not match
ORA-06512: at "APPS.MYPACK_PKG", line 11
ORA-06512: at line 2

    Habe ich dargestellt, dass derzeit in 10.2 können Sie Holen einen cursor in eine PLSQL-Datensatz, aber die nicht in ein SQL-Objekt.

    Update: bezüglich der PLS-00306: falsche Anzahl oder Typen von Argumenten

    l_rarray ist eine GESCHACHTELTE TABELLE, muss es initialisiert werden und dann erweitert werden können, zum speichern von Elementen. Zum Beispiel:

    SQL> CREATE OR REPLACE PACKAGE BODY MYPACK_PKG AS
  2     PROCEDURE MY_PROC(r_cursor OUT MY_REF_CURSOR) AS
  3        lr_array tr_type := tr_type(); /* SQL Array */
  4     BEGIN
  5        FOR cc IN (SELECT e.empno, e.ENAME, NULL lastname
  6                     FROM scott.emp e) LOOP
  7           lr_array.extend;
  8           lr_array(lr_array.count) := r_type(cc.empno,
  9                                              cc.ename,
 10                                              cc.lastname);
 11           /* Here you can do additional procedural work on lr_array */
 12        END LOOP;
 13        /* then return the result set */
 14        OPEN r_cursor FOR SELECT * FROM TABLE (lr_array);
 15     END MY_PROC;
 16  END MYPACK_PKG;
 17  /

Corps de package crÚÚ.

SQL> print r

       SQN FIRSTNAME                      LASTNAME
---------- ------------------------------ -----------
      7369 SMITH                          
      7499 ALLEN                          
      7521 WARD                           
      [...]

14 ligne(s) sÚlectionnÚe(s).

    Für weitere Informationen können Sie der Dokumentation für PL/SQL-collections und Datensätze.

    • Danke für deine Antwort, aber wie ich bereits erwähnt, dies ist nur ein einfaches Beispiel, das eigentliche problem ist komplexer und refcursor, der identifiziert ist in der Prozedur-Deklaration Teil-und out-parameter, der für die Rückgabe der Ergebnisse, die ein weiterer ref cursor werden nicht mit den gleichen Daten im konkreten Fall.
    • Ich aktualisiert meine Antwort, HTH
    • Vielen Dank für die Antwort. Mit Hilfe des Codes, habe ich erklärt, meine record-Typ innerhalb der Prozedur, und es ist die einzige änderung, die ich gemacht habe in dem code, und der Fehler ging Weg. Obwohl, es hat mir geholfen, den Fehler zu verbessern, ich 've begonnen zu erhalten, ein weiterer Fehler. Es ist auf der Zeile, wo identifiziere ich meinen assoziatives array mit dem Typ record (l_rarray := tr_type( l_rec );), und der Fehler ist "PLS-00306: falsche Anzahl oder Typen der Argumente in Aufruf von "TR_TYPE'". Haben Sie eine Idee, warum der Fehler aufgetreten ist?
    • Ich danke Ihnen so sehr. Ich erkannte jetzt, dass es keine Notwendigkeit zu Holen, die ref cursor in ein record-Typ, und ich löste den Fehler, indem Sie die Art und Weise Sie dargestellt in deinem letzten post. Danke nochmal, und nochmal.
    • Ich möchte Sie bitten, eine Frage noch, ich hoffe, dass dies die letzten sein werden.In deinem letzten post, wenn Sie dynamisches sql verwenden, wie 'sql_stmt := SELECT e.empno, e.ENAME NULL-lastname FROM scott.emp e', und dann FÜR cc IN (select sql_stmt VON dual), und dann versuchen, den cursor mit den Elementen durch das schreiben von cc.empno zum Beispiel, Sie bekommen eine PLS-00302 Fehler.Wie kann man es behandeln? Gibt es eine Möglichkeit, da habe ich auf die Verwendung einer dynamischen sql.
    • Wenn Sie dynamisches SQL verwenden, müssen Sie einen expliziten cursor, zum Beispiel: DECLARE lc SYS_REFCURSOR; ldummy VARCHAR2(1); BEGIN OPEN lc FOR 'SELECT * FROM DUAL'; FETCH lc INTO ldummy; CLOSE lc;END;

    InformationsquelleAutor Vincent Malgrat
Schreibe einen Kommentar