Parse XML-Datei mit dem windows-batch

Wie kann ich extrahieren einen STRING wie "US_NY" zwischen den tags <LOCATION></LOCATION> aus einer XML-Datei? Ich versuchte es mit FINDSTR, aber die Zeilenumbrüche sind problematisch.

<?xml version="1.0" encoding="utf-16"?>
<DEVICE>
    <AGENT>
        <VERSION>
            2.0.0.2
        </VERSION>
        <CONNECTION>
            <LOCATION>
                US_NY
            </LOCATION>
            <SERVERIP>
                127.0.0.1
            </SERVERIP>
            <TCPPORT>
                5656
            </TCPPORT>
            <POLLINTERVAL>
                5
            </POLLINTERVAL>
        </CONNECTION>
    </AGENT>
</DEVICE>
  • Was ist die Logik zum bestimmen, was muss extrahiert werden?
  • Ich möchte die Standorte von somde Geräte. Diese Informationen werden in verschiedenen XML-Dateien. Somit Brauch ich zu extrahieren, den STRING oder die Linie zwischen den xml-Tags <location> und </location>. Dies sollte mit windows-batch-Skript.
  • möglich, Duplikat der Eine batch-Datei zu extrahieren Sie den Wert eines bestimmten XML-tag
InformationsquelleAutor eichhorn | 2013-11-01
  1. 7

    Einer mehr

    @echo off
    setlocal enableextensions enabledelayedexpansion
    set "xmlFile=%~1"
    for /f "tokens=1,2 delims=:" %%n in ('findstr /n /i /c:"<LOCATION>" "%xmlFile%"') do (
        for /f "tokens=*" %%l in ('type "%xmlFile%" ^| more +%%n') do set "location=%%l" & goto endLoop
    )
:endLoop
    echo %location%
    • Hier xmlFLie wird ersetzt durch den Namen der Datei?? für zB Data.xml???
    • Blick auf die Dritte Zeile. xmlFile zugeordnet ist, den Namen der Datei als argument übergeben wird, um die batch-Datei. Also, ja, es ist der name der Datei.
    • mit findstr hat ein großes problem, denn es wird der Befehl verlassen Sie sich auf die xml-Datei zu formatieren. Wenn Sie mehrere tags auf der gleichen Linie es nicht mit dem Muster!!
    • ich bin damit einverstanden, xml-handling von batch-Skripten getan werden sollte, mit so etwas wie xmlstartlet, aber a) es ist eine non-native Lösung (ein problem für einige Umgebungen) b) das problem in der OP-Frage ist die Zeilenumbrüche.
    InformationsquelleAutor MC ND
  2. 15

    Sollten Sie verwenden XML.EXE innerhalb des batch-zum Lesen einer XML-Datei. Für weitere Informationen gehen Sie zu http://xmlstar.sourceforge.net/

    Batch-Datei:

    @echo off
for /f %%i in ('XML.EXE sel -t -v "//LOCATION" CP.xml') do set var=%%i
echo LOCATION is %var%

    Ausgabe:

    LOCATION is US_NY
    InformationsquelleAutor Navin Rawat
  3. 4

    Wenn Sie möchten, verwenden Sie einen Helfer batch-Datei (von aacini) dann funktioniert das:

    @echo off
for /f "tokens=*" %%a in ('findrepl /i "<location>" /e:"</location>" /o:+1:-1 ^< "file.xml" ') do echo "%%a"

    Diese wird eine helper-batch-Datei namens findrepl.bat aus - https://www.dropbox.com/s/rfdldmcb6vwi9xc/findrepl.bat

    Ort findrepl.bat im gleichen Ordner wie die batch-Datei.

    • Clevere dual-Verwendung-Skript, beide CMD-und JScript-mit built-in CScript. Es auch wieder selbst zu geben, die helfen, wenn es sein muss.
    InformationsquelleAutor foxidrive
  4. 4

    Hier ist die xpath.bat -kleines Skript, das dir erlaubt, einen xml-Knoten/Attribut Wert durch xpath-Ausdruck ohne Verwendung von externen binaries.

    Für Ihren Fall es kann z.B. so verwendet werden:

    call xpath.bat  "location.xml" "//LOCATION"

    oder weisen Sie den Wert einer Variablen:

    for /f "tokens=* delims=" %%a  in  ('xpath.bat  "location.xml" "//LOCATION"') do (
   set "location=%%a"
)

    Reinen batch-Lösung

     @echo off
        for /f "tokens=1 delims=:" %%L in ('findstr /n "<LOCATION>" some.xml') do ( 
         set begin_line=%%L
        )

        for /f "tokens=1 delims=:" %%L in ('findstr /n "</LOCATION>" some.xml') do ( 
         set /a end_line=%%L+1
        )

        echo showing lines between %end_line% and %begin_line%
        break>"%temp%\empty"
        for /f "delims=" %%l in ('fc "%temp%\empty" "some.xml" /lb  %end_line% /t ^|more +4 ^| findstr /B /E /V "*****" ^| more +%begin_line%') do (
         set "location=%%l"
         goto :break_for
        )
        :break_for
        echo %location%
        del /Q /F "%temp%\empty"

    Ersetzen some.xml mit dem Namen Ihrer xml.

    InformationsquelleAutor npocmaka
  5. 2

    Reinen batch -

    @ECHO OFF
SETLOCAL
SET "location="&SET "grab="
FOR /f "tokens=*" %%a IN (q19722041.xml) DO (
 IF DEFINED grab SET location=%%a&SET "grab="
  IF /i "%%a"=="<LOCATION>" SET grab=Y
)
ECHO found location=%location%
GOTO :EOF

    wo q19722041.xml ist Ihre Quelle .xml Datei.

    InformationsquelleAutor Magoo
  6. 1

    Versuchen Sie dies:

    @echo off
setlocal EnableDelayedExpansion
set lastLine=0
< input.xml (for /F "delims=:" %%a in (
              'findstr /N /C:"<LOCATION>" input.xml') do (
   set /A skip=%%a-lastLine+1, lastLine=%%a+2
   for /L %%i in (1,1,!skip!) do set /P line=
   set /P "line=!line!" & echo:
))

    Hinweis: die Antwort ist eine Anpassung der Antwort (wahrscheinlich von @Aacini) in diesem forum posten: Windows-batch-FindStr nach einer Zeichenfolge suchen und die entsprechende Zeile.

    InformationsquelleAutor Alex Filipovici
  7. 0

    sed für Windows 

    sed -n "/<LOCATION>/{n;p}" file.xml

    in einer batch-Datei:

    for /f %%a in ('sed -n "/<LOCATION>/{n;p}" file.xml') do set "location=%%a"
echo(%location%
    InformationsquelleAutor Endoro
Schreibe einen Kommentar