Parsen von text-Datei mit XSLT

Ich habe eine plain-text-Datei wie folgt aufgebaut:

!ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
...

Ist es möglich, sich mit XSLT-Datei ähnlich:

<?xml version="1.0" encoding="UTF-8" ?>
<document>
  <ITEM_NAME>Item value</ITEM_NAME>
  <ANOTHER_ITEM>Its value</ANOTHER_ITEM>
  ...
</document>

BEARBEITEN

Tut mir Leid, ich habe nicht klar gesagt. Ich bin versucht zu erreichen, diese transformation mit der Visual Studio 2005-XSLT-engine. Ich habe versucht, sowohl die der Lösungen, und ich bin sicher, dass die korrekt sind. Aber Visual Studio 2005 kennt Sie nicht, die ungeparste-text-Funktion.

  • Dies ist aber nicht möglich, da nur gültige Eingaben zu XSLT ist wohlgeformtes Xml.
  • nach dieser Frage, ist es möglich, link
  • Interessant. Der heutige Eintrag in der "Eine Glühbirne kann auch verwendet werden zum braten ein steak." - Liste ... danke für den link 🙂
  • Oder "mit Kanone auf eine fliege". Jeder andere Vorschlag, um die Eingabe von text-Datei mehr "beherrschbar"? Vielleicht mit .NET framework? 😉
  • Auch können Sie eine XSLT-2.0-Prozessor wie Saxon 9 oder AltovaXML oder XmlPrime?
  • Lieber @O. R. Mapper, FYI, XSLT 2.0 wurde erfolgreich und effizient in der Implementierung einer generischen LR-1-parser und auf dieser Grundlage für das Parsen von Sprachen wie JSON und XPath 2.0. Der Einsatz moderner Analyse-Methoden, oder von regulären Ausdrücken, wo Sie am besten geeignet sind, ist genau das Gegenteil von "Eine Glühbirne kann auch verwendet werden, zum braten, ein steak".
  • Ich bin nicht convined der EIGNUNG, wenn reguläre Ausdrücke mit der Erfassung von Gruppen verwendet werden, die bereits für eine einfache Aufgabe wie das Lesen aus einer Datei Zeile für klug und erkennen der ersten Buchstaben der Zeilen, aber es ist gut zu wissen, XSLT kann verwendet werden, die über den ursprünglich beabsichtigten Umfang bei Bedarf 🙂
  • Gut, Ihre Daten, ist 6-7 Jahre alt. XPath 3.0-standard-Funktionen, um die Zeilen einer text-Datei -- unparsed-text-lines(): w3.org/TR/xpath-functions-30/#func-unparsed-text-lines . Die F & O 3.0 ist bereits eine Candidate Recommendation des W3C. Wie für den ersten Buchstaben einer Zeile, kann man noch die XPath-1.0-Funktion substring. In XPath 3.0-Funktion head() (w3.org/TR/xpath-functions-30/#func-head) bietet einen generischen Zugriff auf die Haupt-Sequenz.
  • Ich basiert meine Antwort auf deine Antwort von 11 Stunden vor, die ich vermutet hätte berücksichtigen den aktuellen Stand der Entwicklung.
  • Meine Antwort ist für jemanden, der wahrscheinlich wenig oder keine Ahnung von XSLT 2.0-oder beschränkt ist, durch Ihre management-verwenden Sie nur XSLT 1.0. Sehr wenige Menschen wissen, XSLT 3.0/XPath 3.0 vorhanden ist. Im Fall, Sie sind einer von diesen, können Sie sehen, was leicht möglich ist) in der reinen XPath 3.0 nur hier: xfront.com/Pearls-of-XSLT-and-XPath-3-0-Design.pdf
  • Danke für den link, das sieht interessant aus 🙂

InformationsquelleAutor sblandin | 2013-04-12
  1. 8

    Wenn Sie verwenden können, XSLT 2.0, die Sie nutzen könnten unparsed-text()...

    Text-Datei (verwenden Sie nicht die text-Datei als direkte Eingabe der XSLT.)

    !ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
!TEST_BANG
Here's a value with !bangs!!!

    XSLT 2.0 (diese Anwenden von XSLT selbst (verwenden Sie das stylesheet als XML-input). Sie müssen auch den Pfad ändern, um Ihren text-Datei. Haben Sie vielleicht, um die Codierung ändern zu.)

    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="text-encoding" as="xs:string" select="'iso-8859-1'"/>
    <xsl:param name="text-uri" as="xs:string" select="'file:///C:/Users/dhaley/Desktop/test.txt'"/>

    <xsl:template name="text2xml">
        <xsl:variable name="text" select="unparsed-text($text-uri, $text-encoding)"/>
        <xsl:analyze-string select="$text" regex="!(.*)\n(.*)">
            <xsl:matching-substring>
                <xsl:element name="{normalize-space(regex-group(1))}">
                    <xsl:value-of select="normalize-space(regex-group(2))"/>
                </xsl:element>
            </xsl:matching-substring>
        </xsl:analyze-string>
    </xsl:template>

    <xsl:template match="/">
        <document>
            <xsl:choose>
                <xsl:when test="unparsed-text-available($text-uri, $text-encoding)">
                    <xsl:call-template name="text2xml"/>                                
                </xsl:when>
                <xsl:otherwise>
                    <xsl:variable name="error">
                        <xsl:text>Error reading "</xsl:text>
                        <xsl:value-of select="$text-uri"/>
                        <xsl:text>" (encoding "</xsl:text>
                        <xsl:value-of select="$text-encoding"/>
                        <xsl:text>").</xsl:text>
                    </xsl:variable>
                    <xsl:message><xsl:value-of select="$error"/></xsl:message>
                    <xsl:value-of select="$error"/>
                </xsl:otherwise>
            </xsl:choose>
        </document>
    </xsl:template>
</xsl:stylesheet>

    XML-Ausgabe

    <document>
   <ITEM_NAME>Item value</ITEM_NAME>
   <ANOTHER_ITEM>Its value</ANOTHER_ITEM>
   <TEST_BANG>Here's a value with !bangs!!!</TEST_BANG>
</document>
    • Ist der verschachtelte analyze-string nötig? Kannst du nicht einfach verwenden regex="!(.*)\n(.*) im äußeren analyze-string extrahieren und dann den Namen und den Wert?
    • Ja und sowas hatte ursprünglich. Nicht sicher, warum ich fügte hinzu, dass wieder ein. Ich werde zu aktualisieren. Danke!!
    • Auch aktualisiert die text-input - /xml-Ausgabe zeigen Werte mit !.
    InformationsquelleAutor Daniel Haley
  2. 5

    Dieses XSLT 2.0-transformation:

    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vText" select=
 "replace(unparsed-text('file:///c:/temp/delete/text.txt'),'\r','')"/>

 <xsl:template match="/">
  <document>
      <xsl:analyze-string select="$vText" regex="(!(.+?)\n([^\n]+))+">
       <xsl:matching-substring>
         <xsl:element name="{regex-group(2)}">
                <xsl:sequence select="regex-group(3)"/>
         </xsl:element>
       </xsl:matching-substring>
       <xsl:non-matching-substring><xsl:sequence select="."/></xsl:non-matching-substring>
      </xsl:analyze-string>
  </document>
 </xsl:template>
</xsl:stylesheet>

    wenn appliedon einem XML-Dokument (nicht verwendet) und mit den bereitgestellten text mit Wohnsitz in der lokalen Datei C:\temp\delete\Text.txt:

    !ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
...

    erzeugt die gewünschte, richtige Ergebnis:

    <document>
   <ITEM_NAME>Item value</ITEM_NAME>
   <ANOTHER_ITEM>Its value</ANOTHER_ITEM>
...
</document>

    Zu testen, mehr vollständig sind, setzen wir diesen text in die Datei:

    As is text
!ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
As is text2
!TEST_BANG
Here's a value with !bangs!!!
!TEST2_BANG
 !!!Here's a value with !more~ !bangs!!!
As is text3

    Die transformation produziert wieder den wollte, richtige Ergebnis:

    <document>As is text
<ITEM_NAME>Item value</ITEM_NAME>
<ANOTHER_ITEM>Its value</ANOTHER_ITEM>
As is text2
<TEST_BANG>Here's a value with !bangs!!!</TEST_BANG>
<TEST2_BANG> !!!Here's a value with !more~ !bangs!!!</TEST2_BANG>
As is text3
</document>
    • Vielen Dank für alle Antworten... ich habe gerade entdeckt, dass Visual Studio 2005 (IDE, so bin ich gezwungen, Sie zu nutzen) XSLT parser kennt Sie nicht, die ungeparste-text-Funktion. Sorry für die nicht genügend Kontext.
    InformationsquelleAutor Dimitre Novatchev
Schreibe einen Kommentar