Perl-Skript zum Zusammenführen mehrerer Dateien Zeile für Zeile

Kann jemand bitte helfen Sie mir mit dem schreiben ein Perl-Skript, die als input 5 text-Dateien, und erstellen Sie eine neue text-Datei mit der Zusammenführung jede Zeile alle 5 Dateien.
Sollte dies durch die Eröffnung von 5 Lesen-streams gleichzeitig oder wie bei java einige zufällige Datei-reader ist erhältlich in Perl ?

Danke!

  • Ja, können Sie 5 Dateien auf einmal (und weit mehr als das) in Perl. Haben Sie versucht, an alle zu lösen, das problem selbst?
  • Meinst du gerade1 von Datei1, gerade1 von Datei2,..., gerade2 von Datei1, "line2" von Datei2... ?
  • ja Guru, genau das meine ich. Ja dan1111, ich habe versucht, aber ich mache etwas falsch. Kopieren, fügen Sie den code, nachdem du es ein wenig. Vielen Dank für die Beantwortung. Und ich entschuldige mich für nicht Entsendung meinen code mit der Frage.
InformationsquelleAutor Andy897 | 2012-10-25
  1. 5

    Dieses Programm erwartet eine Liste von Dateien auf der Kommandozeile (oder auf Unix-Systemen, ein wildcard-Datei-Spezifikation). Es erstellt ein array von filehandles @fh für diese Dateien und liest dann die von jeder von Ihnen wiederum, zum drucken des zusammengeführten Daten zu STDOUT

    use strict;
use warnings;

my @fh;
for (@ARGV) {
  open my $fh, '<', $_ or die "Unable to open '$_' for reading: $!";
  push @fh, $fh;
}

while (grep { not eof } @fh) {
  for my $fh (@fh) {
    if (defined(my $line = <$fh>)) {
      chomp $line;
      print "$line\n";
    }
  }
}
    • Wenn eine der Dateien endet nicht mit einem neue-Zeile-zwei Linien werden zu einer verschmolzen, die an diesem Punkt.
    • Behoben. Danke.
    • +1: grep { not eof } @fh ist eine deutliche Verbesserung im Vergleich zu dem, was ich hatte, mit zu kommen.
    InformationsquelleAutor Borodin
  2. 7

    Hier ist ein Perl-Skript, das die Arbeit auf einer beliebigen Anzahl von Dateien:

    use strict;
use warnings;

my @files = ('a.txt','b.txt');
my @fh;

#create an array of open filehandles.
@fh = map { open my $f, $_ or die "Cant open $_:$!"; $f } @files;

open my $out_file, ">merged.txt" or die "can't open out_file: $!";

my $output;
do
{
    $output = '';

    foreach (@fh)
    {
        my $line = <$_>;
        if (defined $line)
        {
            #Special case: might not be a newline at the end of the file
            #add a newline if none is found.
            $line .= "\n" if ($line !~ /\n$/);
            $output .= $line;
        }
    }

    print {$out_file} $output;
}
while ($output ne '');

    a.txt:

    foo1
foo2
foo3
foo4
foo5

    b.txt: 

    bar1
bar2
bar3

    merged.txt:

    foo1
bar1
foo2
bar2
foo3
bar3
foo4
foo5
    • Die $_= $f in Ihrem map Aufruf ersetzt alle Dateinamen in @files mit Ihrer Datei verarbeitet, wird es so und mit den gleichen Daten wie in @fh. Ich nehme an, Sie wollen das nicht, so sollten Sie nur verwenden $f anstelle von zuweisen zu $_
    • danke für den Fang, die. Korrigiert.
    InformationsquelleAutor dan1111
  3. 4

    Wenn ein nicht-perl-Lösung ist ok mit Ihnen, können Sie versuchen, diese:

    paste -d"\n\n\n\n\n" f1 f2 f3 f4 f5

    wo f1,f2,..sind Ihre text-Dateien.

    • Was ist das ? Ich habe es nicht bekommen
    • paste ist eine POSIX-standard-utility-Programm, das genau das tut, was Sie fordern
    • f1 f2 f3 f4 f5 ist ausreichend
    InformationsquelleAutor Guru
Schreibe einen Kommentar