Positionierung ein Fenster mit AppleScript mit dual-Monitore

Ich habe zwei Monitore und ich bin versucht, positionieren Sie die Fenster einer Anwendung auf den zweiten monitor, aber nichts, was ich tun scheint zu funktionieren. So bin ich zum Beispiel mit meinem laptop und das terminal-Fenster ist maximiert auf dem Bildschirm. Dann habe ich einen externen monitor anschließen. Ich dann laufen will, applescript und terminal maximieren auf den größeren zweiten monitor.

Hier ist, was ich jetzt haben:

set monitorTwoPos to {1050, -600}
set monitorTwoSze to {1200, 1920}

tell application "Microsoft Outlook"
    set position of window 1 to monitorTwoPos
    set size of window 1 to monitorTwoSze
end tell

Hier ist die Fehlermeldung die ich bekomme:

/Users/vcutten/AppleScripts/SpacesWork.scpt:1291:1332: execution error: 
Microsoft Outlook bekam eine Fehlermeldung: Kann nicht die position von Fenster 1 in Typ Bezeichner. (-1700)

Ich bin mir ziemlich sicher, ich bin nur mit set position und Größe völlig falsch : (, Wenn ich Grenzen es irgendwie funktioniert...

Bonus-Frage:
Wie kann ich eine Schleife durch die offenen Fenster, und Ihre Größe? Danke!

InformationsquelleAutor gdoubleod | 2011-05-03

2

Was haben Sie versucht?

Ich denke, um dieses Problem zu lösen, müssen Sie berechnen die Display-Größe und die Koordinaten des zweiten Monitors. Zum Beispiel, Ihre Haupt-monitor beginnt an der position {0,0}. So die Ausgangsposition für den zweiten monitor hat, um etwas anderes zu sein, und Sie brauchen, um zu finden, dass. Zum Glück habe ich ein tool geschrieben, dass wird Ihnen sowohl die Start-Koordinaten und Größe Ihres Bildschirms überwacht. Sobald Sie die Größe und position, dann ist es einfach. System-Ereignisse können die Größe und position der Fenster, so dass Sie könnte so etwas wie dieses...
```
set monitorSize to {800, 600}
set monitorPosition to { -800, 0}

tell application "System Events"
    tell process "Terminal"
        set frontWindow to first window
        set position of frontWindow to monitorPosition
        set size of frontWindow to monitorSize
    end tell
end tell
```
Also aus dem oben genannten script müssen Sie nur die Größe und position Variablen. Sie können erhalten mein Werkzeug hier genannt hmscreens, die Ihnen jene. Möglicherweise müssen Sie einige Einstellung der Koordinaten, je nachdem, ob der Bildschirm ist gemessen von der unteren linken Ecke oder oben Links, aber das ist nur einfache Mathematik.

Ich hoffe, das hilft...
- Danke für die Antwort! Ich aktualisierte die Frage mit, was Sie gefragt haben... ich fühle mich wie ich bin nur nicht verwenden, legen Sie die position richtig 🙁
InformationsquelleAutor regulus6633

Hier ist ein Skript, das die Griffe zum speichern und wiederherstellen der Größe und Position für mehrere display-Konfigurationen. Es kann einige Probleme mit fullscreen-apps, aber es scheint zu funktionieren ok.

-- allSettings is a list of records containing {width:? height:? apps:{{name:? pos:? size:?},...} 
-- for each display setup store the apps and their associated position and size
property allSettings : {}

-- create a variable for the current settings
set currentSettings to {}

display dialog "Restore or save window settings?" buttons {"Restore", "Save"} default button "Restore"
set dialogResult to result

tell application "Finder"

    -- use the desktop bounds to determine display config
    set desktopBounds to bounds of window of desktop
    set desktopWidth to item 3 of desktopBounds
    set desktopHeight to item 4 of desktopBounds
    set desktopResolution to desktopWidth & "x" & desktopHeight

    -- find the saved settings for the display config
    repeat with i from 1 to (count of allSettings)
        if (w of item i of allSettings is desktopWidth) and (h of item i of allSettings is desktopHeight) then
            set currentSettings to item i of allSettings
        end if
    end repeat

    if (count of currentSettings) is 0 then
        -- add the current display settings to the stored settings
        set currentSettings to {w:desktopWidth, h:desktopHeight, apps:{}}
        set end of allSettings to currentSettings
        --say "creating new config for " & desktopResolution
    else
        --say "found config for " & desktopResolution
    end if

end tell

tell application "System Events"

    if (button returned of dialogResult is "Save") then
        say "saving"
        repeat with p in every process
            if background only of p is false then
                tell application "System Events" to tell application process (name of p as string)

                    set appName to name of p

                    if (count of windows) > 0 then
                        set appSize to size of window 1
                        set appPosition to position of window 1
                    else
                        set appSize to 0
                        set appPosition to 0
                    end if

                    set appSettings to {}

                    repeat with i from 1 to (count of apps of currentSettings)
                        if name of item i of apps of currentSettings is name of p then
                            set appSettings to item i of apps of currentSettings
                        end if
                    end repeat

                    if (count of appSettings) is 0 then
                        set appSettings to {name:appName, position:appPosition, size:appSize}
                        set end of apps of currentSettings to appSettings
                    else
                        set position of appSettings to appPosition
                        set size of appSettings to appSize
                    end if

                end tell
            end if
        end repeat
    end if

    if (button returned of dialogResult is "Restore") then
        if (count of apps of currentSettings) is 0 then
            say "no window settings were found"
        else
            say "restoring"
        repeat with i from 1 to (count of apps of currentSettings)
            set appSettings to item i of apps of currentSettings
            set appName to (name of appSettings as string)
            try
                tell application "System Events" to tell application process appName
                    if (count of windows) > 0 then
                        set position of window 1 to position of appSettings
                        set size of window 1 to size of appSettings
                    end if
                end tell
            end try
        end repeat
        end if
    end if
end tell

https://gist.github.com/cmackay/5863257

Kein Fenster Einstellungen gefunden wurden. Änderungen im Skript-Verhalten und Eigenschaften?
Ich habe nicht verwendet, die Skript in vielen Jahren. Ich bin nicht sicher, es würde immer noch funktionieren. Derzeit nutze ich eine app namens moom zu verwalten mein Fenster positioniert. manytricks.com/moom

InformationsquelleAutor craigm

0

Verwenden Schranken statt der position, es funktioniert. Sie bekommen Grenzen des Fenster wie dieses:
```
tell application "Microsoft Outlook"
    get bounds of first window
end tell
```
Antwort auf die bonus-Frage:
```
tell application "Microsoft Outlook"
    repeat with nextWindow in (get every window)
        get bounds of nextWindow
    end repeat
end tell
```
Wenn Sie offen Antworten Registerkarte im unteren Teil des Applescript-editor, sehen Sie alle Ergebnisse abrufen.

Hoffe, es hilft.

InformationsquelleAutor

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.