Qmake Projektabhängigkeiten (verknüpfte Bibliotheken)

Nach ziemlich viel Frust mit qmake, die ich gefunden habe, was ich denke, ist die Antwort auf Ihre Frage. Wenn nicht, dann habe ich gelernt, die Art und Weise, dass ich qmake verwenden, bis ich etwas besseres, denn das ist noch ein bisschen hässlich. Ich habe ein demo Projekt, das ist meine directory-Struktur (Dateien haben Erweiterungen, Ordner nicht):

MyProj
    MyProj.pro
    myproj-core
        myproj-core.pro
        globals.h
        MyProjCore.h
        MyProjCore.cpp
    myproj-app
        myproj-app.pro
        main.cpp

Beginnen wir mit MyProj.pro als subdirs Projekt, das ist der Schlüssel zu tun, was Sie Fragen. Im Grunde, statt abhängig von anderen Projekten, um anzugeben, debug/release und allen möglichen anderen Kram, den Sie gerade legen Sie es auf der einen qmake-Datei. Es nicht lassen, Sie machen nur das, was Sie brauchen, aber es ist die beste Lösung, die ich gefunden habe. Hier sind die Inhalte:

TEMPLATE = subdirs
# Needed to ensure that things are built right, which you have to do yourself :(
CONFIG += ordered

# All the projects in your application are sub-projects of your solution
SUBDIRS = myproj-core \
          myproj-app

# Use .depends to specify that a project depends on another.
myproj-app.depends = myproj-core

myproj-core.pro ist ein typisches shared-object-Bibliothek:

QT -= gui
TARGET = myproj-core
TEMPLATE = lib
DEFINES += MYPROJCORE_LIBRARY
SOURCES += MyProjCore.cpp
HEADERS += MyProjCore.h \
           globals.h

myproj-app.pro ist-consumer-Anwendung, wo die kleinen wieder aufzubauen-wenn-benötigt trick ist:

QT       -= gui

TARGET = myproj-app
CONFIG   += console
CONFIG   -= app_bundle

TEMPLATE = app

# Specify that we're lookin in myproj-core.  Realistically, this should be put
# in some configuration file
INCLUDEPATH += ../myproj-core
# Link to the library generated by the project.  Could use variables or
# something here to make it more bulletproof
LIBS += ../myproj-core/libmyproj-core.so
# Specify that we depend on the library (which, logically would be implicit from
# the fact that we are linking to it)
PRE_TARGETDEPS += ../myproj-core/libmyproj-core.so

SOURCES += main.cpp

Ich hoffe das löst dein problem, da ich weiß, dass es gelöst mine!

BEARBEITEN: ich habe eine Datei, die speziell für die Bau-Abhängigkeiten für mich, ich speichern Sie es in einem Geschwister-Ordner von jedem meiner Projekte (Kind des MyProj in die Verzeichnis-Struktur oben angegeben) genannt dependencies.pri:

# On windows, a shared object is a .dll
win32: SONAME=dll
else:  SONAME=so

# This function sets up the dependencies for libraries that are built with
# this project.  Specify the libraries you need to depend on in the variable
# DEPENDENCY_LIBRARIES and this will add
for(dep, DEPENDENCY_LIBRARIES) {
    #message($$TARGET depends on $$dep ($${DESTDIR}/$${dep}.$${SONAME}))
    LIBS += $${DESTDIR}/lib$${dep}.$${SONAME}
    PRE_TARGETDEPS += $${DESTDIR}/lib$${dep}.$${SONAME}
}

Also an der Unterseite aller verbrauchenden Anwendungen, ich kann fügen Sie die Zeilen:

DEPENDENCY_LIBRARIES = myproj-core

include(../config/dependencies.pri)

Diese geht davon aus, dass Sie kopieren Sie die Bibliotheken auf einen freigegebenen Speicherort und/oder zu bewegen, wie gebraucht, so dass meine Funktion funktioniert möglicherweise nicht für Sie, aber ich dachte, ich würde hinzufügen, um die Lösung.

InformationsquelleAutor der Antwort Travis Gockel

1. Überprüfen Sie heraus diese Frage: Gewalt verknüpfen, wenn die Gebäude in QT Creator

2. Versuchen Sie, etwas ähnliches zu diesem code, um Ihre pro-Datei:

   CONFIG(debug, debug|release) {   
       DESTDIR = ../../../bin/debug  
       OBJECTS_DIR = ./debug  
   }  
   else {   
       DESTDIR = ../../../bin/release  
       OBJECTS_DIR = ./release  
   }

Dann müssen Sie geben Sie die Abhängigkeiten für jede Konfiguration:

CONFIG(debug, debug|release) {   
    LIBS += -L../../../lib/debug \  
        -L../../../bin/debug \  
        -llib1 \  
        -llib2   
    PRE_TARGETDEPS += ../../../lib/debug/liblib1.a \  
        ../../../lib/debug/liblib2.a 
else { 
    LIBS += -L../../../lib/release \
        -L../../../bin/release \
        -llib1 \  
        -llib2   
    PRE_TARGETDEPS += ../../../lib/release/liblib1.a \
        ../../../lib/release/liblib2.a 
}

InformationsquelleAutor der Antwort rpg

Für diejenigen, die interessiert sind, in eine Vorlage für Ihre Qt/QML-Projekt, die ich veröffentlicht habe, ein template auf GitHub QmlAppTemplate.

InformationsquelleAutor der Antwort lucab0ni