QMake - So kopieren Sie eine Datei in die Ausgabe

Hier ist ein Beispiel aus einem unserer Projekte. Es zeigt, wie das kopieren von Dateien auf die DESTDIR für Windows und Linux.

linux-g++{
    #...
    EXTRA_BINFILES += \
        $${THIRDPARTY_PATH}/gstreamer-0.10/linux/plugins/libgstrtp.so \
        $${THIRDPARTY_PATH}/gstreamer-0.10/linux/plugins/libgstvideo4linux2.so
    for(FILE,EXTRA_BINFILES){
        QMAKE_POST_LINK += $$quote(cp $${FILE} $${DESTDIR}$$escape_expand(\n\t))
    }
}

win32 {
    #...
    EXTRA_BINFILES += \
        $${THIRDPARTY_PATH}/glib-2.0/win32/bin/libglib-2.0.dll \
        $${THIRDPARTY_PATH}/glib-2.0/win32/bin/libgmodule-2.0.dll
    EXTRA_BINFILES_WIN = $${EXTRA_BINFILES}
    EXTRA_BINFILES_WIN ~= s,/,\\,g
        DESTDIR_WIN = $${DESTDIR}
    DESTDIR_WIN ~= s,/,\\,g
    for(FILE,EXTRA_BINFILES_WIN){
                QMAKE_POST_LINK +=$$quote(cmd /c copy /y $${FILE} $${DESTDIR_WIN}$$escape_expand(\n\t))
    }
}

InformationsquelleAutor der Antwort sje397

Wenn du make installieren, können Sie die INSTALLIERT variable qmake. Hier ist ein Beispiel:

images.path    = $${DESTDIR}/images
images.files   += images/splashscreen.png
images.files   += images/logo.png
INSTALLS       += images

dann mittels 'make install'

InformationsquelleAutor der Antwort Caleb Huitt - cjhuitt

Erstellen Sie eine Datei copy_files.prf in einem der Pfade, die qmake verwendet für config features. Die Datei sollte wie folgt Aussehen:

QMAKE_EXTRA_COMPILERS += copy_files
copy_files.name = COPY
copy_files.input = COPY_FILES
copy_files.CONFIG = no_link

copy_files.output_function = fileCopyDestination
defineReplace(fileCopyDestination) {
    return($$shadowed($$1))
}

win32:isEmpty(MINGW_IN_SHELL) {
    # Windows shell
    copy_files.commands = copy /y ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
    TOUCH = copy /y nul
}
else {
    # Unix shell
    copy_files.commands = mkdir -p `dirname ${QMAKE_FILE_OUT}` && cp ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
    TOUCH = touch
}

QMAKE_EXTRA_TARGETS += copy_files_cookie
copy_files_cookie.target = copy_files.cookie
copy_files_cookie.depends = compiler_copy_files_make_all

win32:!mingw {
    # NMake/MSBuild
    copy_files_cookie.commands = $$TOUCH $** && $$TOUCH $@
}
else {
    # GNU Make
    copy_files_cookie.commands = $$TOUCH $<  && $$TOUCH $@
}

PRE_TARGETDEPS += $${copy_files_cookie.target}

Wie es funktioniert

Den ersten Teil definiert eine extra compiler die lese-Eingabe-Dateinamen aus der COPY_FILES variable. Der nächste Teil beschreibt die Funktion, die Sie verwenden werden, zu synthetisieren, eine Ausgabedatei für jeden entsprechenden Eingang. Dann definieren wir die Befehle zum aufrufen dieser "compiler", je nachdem, welche Art von shell, die wir sind.

Dann definieren wir eine extra makefile-target copy_files.cookiedie abhängig von der Ziel -compiler_copy_files_make_all. Dies ist der name, der das Ziel, das qmake erzeugt für die extra-compiler definierten wir im ersten Schritt. Dies bedeutet, dass, wenn die copy_files.cookie Ziel ist gebaut, es wird aufgerufen, die extra compiler die Dateien kopieren.

Wir geben Sie einen Befehl, der durch dieses Ziel, die touch die Dateien copy_files.cookie und compiler_copy_files_make_all. Durch die Berührung mit diesen Dateien stellen wir sicher, dass make wird nicht versuchen Sie, kopieren Sie die Dateien erneut, es sei denn, deren Zeitstempel Aktueller ist als der berührt-Dateien. Schließlich, fügen wir copy_files.cookie der Liste der Abhängigkeiten der make all Ziel.

Wie es zu benutzen

In Ihrem .pro - Datei, fügen Sie copy_files zu den CONFIG variable:

CONFIG += copy_files

Dann die Dateien hinzufügen, um die COPY_FILES variable:

COPY_FILES += docs/*.txt

InformationsquelleAutor der Antwort Oktalist

Definieren Sie zunächst die folgenden zwei Funktionen für die Unterstützung von Windows/Unix.

defineReplace(nativePath) {
    OUT_NATIVE_PATH = $$1
    # Replace slashes in paths with backslashes for Windows
    win32:OUT_NATIVE_PATH ~= s,/,\\,g
    return($$OUT_NATIVE_PATH)
}

# Copies the given files to the destination directory
defineReplace(copyToDestDirCommands) {
    variable_files = $$1
    files = $$eval($$variable_files)
    DDIR = $$nativePath($$2)
    win32:DDIR ~= s,/,\\,g
    POST_LINK = echo "Copying files to $$DDIR" $$escape_expand(\\n\\t)

    win32 {
        POST_LINK += $$QMAKE_MKDIR $$quote($$DDIR) 2>&1 & set errorlevel=0 $$escape_expand(\\n\\t)
    }
    !win32 {
        POST_LINK += $$QMAKE_MKDIR -p $$quote($$DDIR) $$escape_expand(\\n\\t)
    }

    for(ORIGINAL_FILE, files) {
        FILE = $$nativePath($$ORIGINAL_FILE)
        POST_LINK += $$QMAKE_COPY $$quote($$FILE) $$quote($$DDIR) $$escape_expand(\\n\\t)
    }

    return ($$POST_LINK)
}

Dann können Sie den folgenden code, um die funcitons, die definiert werden, bevor Sie zum kopieren von Dateien in bestimmte Ordner, und auch das erstellen des Verzeichnisses, wenn nötig. Dies ist getestet unter Win32, Linux-tests sind willkommen.

BATOS_FILES = \
    $$BATOS_BIN_ROOT/batos-core.dll \
    $$BATOS_BIN_ROOT/batos-pfw.dll \
    $$BATOS_BIN_ROOT/dre.dll \
    $$BATOS_BIN_ROOT/log4qt.dll

QMAKE_POST_LINK += $$copyToDestDirCommands(BATOS_FILES, $$DESTDIR)

BATOS_PLUGINS_FILES = \
    $$BATOS_BIN_ROOT/plugins/com.xaf.plugin-manager.dll \
    $$BATOS_BIN_ROOT/plugins/org.commontk.eventadmin.dll

QMAKE_POST_LINK += $$copyToDestDirCommands(BATOS_PLUGINS_FILES, $$DESTDIR/plugins)

InformationsquelleAutor der Antwort lygstate