Robot Framework-Datei Herunterladen

Ich verwende Robot Framework.

Auf meiner HTML-Seite habe ich einen einfachen button. Wenn Sie darauf klicken, es lädt eine pdf-Datei.

Wie kann ich überprüfen, mit Robot Framework, wenn die Datei heruntergeladen wurde ?

Tks

Ich habe eine Lösung gefunden, tks an @ombre42 :

${SERVER}                  ${SERVER_DEV}
${NAME}                 Robot
${FILE_NAME}                Robot.pdf
${CLASS_NAME}               in
${DOWNLOAD_DIRECTORY}       C:\\robot_download

Scenario: User can download
    Create Directory    ${DOWNLOAD_DIRECTORY}
    ${CHROME_OPTIONS}=  Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()   sys, selenium.webdriver
    ${disabled} Create List     Chrome PDF Viewer
    ${prefs}    Create Dictionary   download.default_directory=${DOWNLOAD_DIRECTORY}    plugins.plugins_disabled=${disabled}
    Call Method ${CHROME_OPTIONS}   add_experimental_option prefs   ${prefs}
    Create Webdriver    Chrome  chrome_options=${CHROME_OPTIONS}
    Goto    ${SERVER}
    Click Element ${NAME}
    Wait Until Element Is Visible   css=div.${CLASS_NAME}   8
    Page Should Contain ${NAME}
    Set Selenium Speed  10s
    Download PDF    ${NAME}
    File Should Exist   C:\\robot_download\\${FILE_NAME}
  • Welchen browser verwenden Sie?
  • Ich bin mit Chrome.
InformationsquelleAutor Raphael | 2016-02-09
  1. 15

    Die Lösung ist sehr browser-spezifisch. Für Chrome, können Sie erzählen, Chrom, wo das herunterladen von Dateien. Wählen Sie einen neuen Ordner überwachen Sie den status des downloads an. Auch, da Sie das herunterladen einer PDF-Datei, deaktivieren Sie das PDF-plugin ist notwendig, um zu verhindern, dass die PDF-Datei angezeigt werden, statt heruntergeladen. Hier ist ein test, funktionierte auf meinem Rechner mit einer einfachen Seite und die PDF-Datei.

    *** Settings ***
Test Teardown     Close All Browsers
Library           Selenium2Library
Library           OperatingSystem

*** Test Cases ***
Download PDF
    # create unique folder
    ${now}    Get Time    epoch
    ${download directory}    Join Path    ${OUTPUT DIR}    downloads_${now}
    Create Directory    ${download directory}
    ${chrome options}=    Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()    sys, selenium.webdriver
    # list of plugins to disable. disabling PDF Viewer is necessary so that PDFs are saved rather than displayed
    ${disabled}    Create List    Chrome PDF Viewer
    ${prefs}    Create Dictionary    download.default_directory=${download directory}    plugins.plugins_disabled=${disabled}
    Call Method    ${chrome options}    add_experimental_option    prefs    ${prefs}
    Create Webdriver    Chrome    chrome_options=${chrome options}
    Goto    http://localhost/download.html
    Click Link    link    # downloads a file
    # wait for download to finish
    ${file}    Wait Until Keyword Succeeds    1 min    2 sec    Download should be done    ${download directory}

*** Keywords ***
Download should be done
    [Arguments]    ${directory}
    [Documentation]    Verifies that the directory has only one folder and it is not a temp file.
    ...
    ...    Returns path to the file
    ${files}    List Files In Directory    ${directory}
    Length Should Be    ${files}    1    Should be only one file in the download folder
    Should Not Match Regexp    ${files[0]}    (?i).*\\.tmp    Chrome is still downloading a file
    ${file}    Join Path    ${directory}    ${files[0]}
    Log    File was successfully downloaded to ${file}
    [Return]    ${file}

    Inhalt download.html:

    <html><body><a href="file.pdf" id="link">Click Here</a></body></html>
    • IE ist das möglich?
    InformationsquelleAutor ombre42
  2. 2
    ${home_dir}         Get Environment Variable    HOME
${download_dir}     Join Path   ${home_dir}     Downloads
${result}    Run Keyword And Return Status  File Should Exist   
${download_dir}/filename.pdf

    Zu prüfen, weiter auf der Datei
    ${content} Holen der Datei ${download_dir}/Dateiname.pdf
    ${count_file} Get-Zeile Count ${content}

    Oben kann verwendet werden, für die grundlegende Behauptung
    Weitere keywords überprüfen Sie bitte den link http://robotframework.org/robotframework/latest/libraries/OperatingSystem.html

    InformationsquelleAutor Royalyn H
  3. 0

    Benötigen Sie das MD5 der Datei, vor dem download und nach download.
    Sowohl der MD5-sollten identisch sein.

    Vorausgesetzt, die Datei ist auf der Linux Maschine - vor und nach dem download :

    1. Einloggen, um linux-Rechner mit SSH-Bibliothek
    2. Führen Sie den Befehl ein : #md5sum DATEIPFAD
    3. Speichern Sie die Ausgabe in eine variable.
    4. Vergleichen Sie den Wert der Variablen

    So hoffe diese information war hilfreich.

    InformationsquelleAutor Bahubali Patil
Schreibe einen Kommentar