Senden Tastendruck zu einer anderen Anwendung mithilfe der WinAPI

Habe ich zur Kontrolle eine andere Anwendung, indem Sie Tastenanschläge, um es wie STRGS oder STRGSHIFTC oder STRGF.

Ich habe versucht, eine Menge Dinge, aber ich nicht bekommen kann es arbeiten. Also ich versuche, dieses Recht auf einen einfacheren Fall.

Diese erfolgreich sendet Hey auf dem Merkzettel:

procedure TForm1.Button1Click(Sender: TObject);
  var notepad, edit: HWND;
begin
  notepad := FindWindow('notepad', nil);
  edit := FindWindowEx(notepad, FindWindow('Edit', nil), nil, nil);

  SendMessage(edit, WM_CHAR, dword('H'), 0);
  SendMessage(edit, WM_CHAR, dword('e'), 0);
  SendMessage(edit, WM_CHAR, dword('y'), 0);
end;

- Und dies erfolgreich, sendet die F5 - Taste, um den Editor, und funktioniert auch mit F3 poping bis Sie das Dialogfeld Suchen.

notepad := FindWindow('notepad', nil);
PostMessage(notepad, WM_KEYDOWN, VK_F5, 0);
PostMessage(notepad, WM_KEYUP, VK_F5, 0);

Aber ich weiß nicht, warum SendMessage funktioniert nicht auf dem Beispiel oben.

Das beste was ich tun konnte, war so etwas wie dieses, die tut nichts.

notepad := FindWindow('notepad', nil);
PostMessage(notepad, WM_KEYDOWN, VK_CONTROL, 0);
PostMessage(notepad, WM_KEYDOWN, VkKeyScan('F'), 0);
PostMessage(notepad, WM_KEYUP, VkKeyScan('F'), 0);
PostMessage(notepad, WM_KEYUP, VK_CONTROL, 0);

Ich gefunden habe hier irgendwo eine Bibliothek, die irgendwie emulieren das VBScript senden-Taste Funktionen, aber gerade auf der Suche den code, scheint es nur broadcast-Tasten, um die aktuelle Anwendung oder alle Anwendungen, da es keine Handle-parameter.

InformationsquelleAutor Vitim.us | 2013-04-06

  1. 5

    Warnung: Dieser Methode hängt von Einzelheiten der implementation und sollte nicht verwendet werden, wenn Sie garantieren müssen, die Richtigkeit des Programms. (Auf der anderen Seite, sind Sie bereits auf diesem Weg. Zum Beispiel, wenn ich mich Recht erinnere, in Windows 95 gibt es nicht einmal eine Go to dialog.)

    Öffnete ich notepad.exe in meiner Lieblings-Ressourcen-Editor, und untersucht die Menüleiste. Ich bemerkte, dass die ID des Save Menüpunkt ist 3. Also, der folgende code führt die Save Menü-Befehl im Editor:

    var
  notepad: HWND;
begin
  notepad := FindWindow('notepad', nil);

  SendMessage(notepad, WM_COMMAND, 3, 0);

    Ebenso Find ist 21 in meiner version von notepad.exe. Go to ist 24.

    Update, laut Kommentar:, Wenn Sie benötigen, senden Sie Strg+Taste verwenden, können Sie SendInput:

    var
  notepad: HWND;
  inputArray: array[0..3] of TInput;
begin
  notepad := FindWindow('notepad', nil);

  // TODO: Either exit if notepad isn't focused, or set focus to notepad

  FillChar(inputArray, length(inputArray) * sizeof(TInput), 0);

  inputArray[0].Itype := INPUT_KEYBOARD;
  inputArray[0].ki.wVk := VK_LCONTROL;
  inputArray[1].Itype := INPUT_KEYBOARD;
  inputArray[1].ki.wVk := VkKeyScan('S');
  inputArray[2].Itype := INPUT_KEYBOARD;
  inputArray[2].ki.wVk := VkKeyScan('S');
  inputArray[2].ki.dwFlags := KEYEVENTF_KEYUP;
  inputArray[3].Itype := INPUT_KEYBOARD;
  inputArray[3].ki.wVk := VK_LCONTROL;
  inputArray[3].ki.dwFlags := KEYEVENTF_KEYUP;

  SendInput(length(inputArray), inputArray[0], sizeof(TInput));
    Dies ist sehr nützlich, aber nicht für mich arbeiten, weil ich muss automatisiert eine Aufgabe in einem Spiel, das nicht über windows-standard-Komponenten, also AFAIK kann ich nicht finden, eine Befehls-ID, ich kann nur das senden von Nachrichten an den oberen Fenster-handle, und die einzige zuverlässige Weise, die ich finden kann, ist, dass die Tastenanschläge sind immer die gleichen.
    OK, ich sehe. Vielleicht SendInput arbeiten kann?
    Dort sind "alte" Versionen von Delphi nicht unterstützen absolute? Ich dachte, das war geerbt von Borland Pascal.
    Mein Verständnis ist, dass es eingeführt wurde Delphi 2009, aber anscheinend David widerspricht auf. Ich Schätze, ich war falsch.
    Ja, das war es, was ich suchte.

    InformationsquelleAutor Andreas Rejbrand

  2. 3

    Habe ich mit keybd_event für Alter. Es funktioniert immer, auch wenn alles andere fehlschlägt, weil es füttert den Eingang direkt in die Schnittstelle zwischen den Tastatur-Treiber und Windows. Es gibt wirklich keinen Unterschied zwischen manuell eingeben und generieren von Schlüsseln mit der Funktion unten. Einzige Nachteil ist, dass das Ziel-Fenster muss immer im Vordergrund bleiben.

    procedure SendKey(Wnd,VK : Cardinal; Ctrl,Alt,Shift : Boolean);
var
  MC,MA,MS : Boolean;
begin
  // Try to bring target window to foreground
  ShowWindow(Wnd,SW_SHOW);
  SetForegroundWindow(Wnd);

  // Get current state of modifier keys
  MC:=Hi(GetAsyncKeyState(VK_CONTROL))>127;
  MA:=Hi(GetAsyncKeyState(VK_MENU))>127;
  MS:=Hi(GetAsyncKeyState(VK_SHIFT))>127;

  // Press modifier keys if necessary (unless already pressed by real user)
  if Ctrl<>MC then keybd_event(VK_CONTROL,0,Byte(MC)*KEYEVENTF_KEYUP,0);
  if Alt<>MA then keybd_event(VK_MENU,0,Byte(MA)*KEYEVENTF_KEYUP,0);
  if Shift<>MS then keybd_event(VK_SHIFT,0,Byte(MS)*KEYEVENTF_KEYUP,0);

  // Press key
  keybd_event(VK,0,0,0);
  keybd_event(VK,0,KEYEVENTF_KEYUP,0);

  // Release modifier keys if necessary
  if Ctrl<>MC then keybd_event(VK_CONTROL,0,Byte(Ctrl)*KEYEVENTF_KEYUP,0);
  if Alt<>MA then keybd_event(VK_MENU,0,Byte(Alt)*KEYEVENTF_KEYUP,0);
  if Shift<>MS then keybd_event(VK_SHIFT,0,Byte(Shift)*KEYEVENTF_KEYUP,0);
end;
    Es kann scheitern. Es schlägt fehl, wenn ein anderer Prozess fügt Tastatur-Ereignisse, die interleave. Das ist, warum SendInput vorhanden ist. Ich weiß nicht, warum Sie denken, dass keybd_event ist besser als SendInput.
    Spiele sind vielleicht nicht immer reagieren zu SendMessage (), so dass eine untere-level-Funktion erforderlich ist. Ich nahm SendInput ist ein higher-level-Funktion SendMessage(). Ich stehe korrigiert.

    InformationsquelleAutor Martin

Schreibe einen Kommentar