Skript dynamisch fix ophaned Benutzer nach dem db-restore

Nach dem ausführen einer Datenbank wiederherstellen, ich will laufen ein dynamisches script zu beheben ophaned Benutzer. Mein Skript durchläuft alle Benutzer angezeigt werden, nach der Ausführung von sp_change_users_login 'report' und gilt als "alter user [username] with login = [Benutzername]" - Anweisung zu beheben SID Konflikte. Ich bin immer eine "falsche syntax error on line 15" und kann nicht herausfinden, warum...Hilfe..

DECLARE @Username varchar(100), @cmd varchar(100)
DECLARE userLogin_cursor CURSOR FAST_FORWARD
FOR
SELECT UserName = name FROM sysusers
WHERE issqluser = 1 and (sid IS NOT NULL AND sid <> 0×0)
    AND suser_sname(sid) IS NULL
ORDER BY name
FOR READ ONLY
OPEN userLogin_cursor

FETCH NEXT FROM userLogin_cursor INTO @Username
WHILE @@fetch_status = 0
  BEGIN
    SET @cmd = ‘ALTER USER ‘+@username+‘ WITH LOGIN ‘+@username
    EXECUTE(@cmd)
    FETCH NEXT FROM userLogin_cursor INTO @Username
  END
CLOSE userLogin_cursor
DEALLOCATE userLogin_cursor
InformationsquelleAutor gates | 2010-05-20
  1. 1
    DECLARE @Username VARCHAR(100),
        @cmd      VARCHAR(100)

DECLARE userlogin_cursor CURSOR FAST_FORWARD FOR
  SELECT username = name
  FROM   sysusers
  WHERE  issqluser = 1
     AND (sid IS NOT NULL
          AND sid <> 0x01)
     AND Suser_sname(sid) IS NULL
  ORDER  BY name
  FOR READ ONLY

OPEN userlogin_cursor
FETCH NEXT FROM userlogin_cursor INTO @Username

WHILE @@FETCH_STATUS = 0
  BEGIN
      SET @cmd = 'ALTER USER [' + @username + '] WITH LOGIN = [' + @username + ']'
      EXECUTE(@cmd)
      FETCH NEXT FROM userlogin_cursor INTO @Username
  END

CLOSE userlogin_cursor
DEALLOCATE userlogin_cursor
    • Ich vergesse immer über die eckigen Klammern []. Danke!
    • Haben Sie sichergestellt, dass die Nutzer nicht in der Tat existieren?
    InformationsquelleAutor Kenneth
  2. 3

    Verwaisten Benutzern behoben werden kann mit der [dbo].[sp_change_users_login] gespeicherte Prozedur.

    Schleife über alle Benutzer und führen Sie die Prozedur

    Glück

    DECLARE @UserCount INT
DECLARE @UserCurr INT
DECLARE @userName VARCHAR(100)
DECLARE @vsql NVARCHAR(4000)
DECLARE @Users TABLE(
id INT IDENTITY(1,1) PRIMARY KEY NOT NULL,
userName VARCHAR(100))
INSERT INTO @Users(UserName) 
SELECT [name] FROM 
--
master.[dbo].sysUsers -- SQL 2008 & SQL 2005
--master.dbo.sysxlogins -- SQL 2000


SELECT @UserCount = max([id]) FROM @Users
SET @UserCurr = 1

WHILE (@UserCurr <= @UserCount)
BEGIN
 SELECT @userName=userName FROM @Users WHERE [id] =@UserCurr
 SET @vsql = '[dbo].[sp_change_users_login] ''AUTO_FIX'',''' + @userName + ''''
 -- EXEC(@vsql)
 PRINT @vsql
 SET @UserCurr = @UserCurr + 1
END
    InformationsquelleAutor John DaCosta
  3. 1

    Habe ich verwendet einen ähnlichen Ansatz, wickeln Sie den code in eine gespeicherte Prozedur:

    USE [master]
GO

CREATE PROCEDURE [sp_AutoFixAllUsers]
AS
BEGIN

    DECLARE @AutoFixCommand NVARCHAR(MAX)
    SET @AutoFixCommand = ''

    SELECT --dp.[name], dp.[sid] AS [DatabaseSID], sp.[sid] AS [ServerSID],
        @AutoFixCommand = @AutoFixCommand + ' '
         + 'EXEC sp_change_users_login ''Auto_Fix'', ''' + dp.[name] + ''';'-- AS [AutoFixCommand]
    FROM sys.database_principals dp
    INNER JOIN sys.server_principals sp
        ON dp.[name] = sp.[name] COLLATE DATABASE_DEFAULT
    WHERE dp.[type_desc] IN ('SQL_USER', 'WINDOWS_USER', 'WINDOWS_GROUP')
    AND sp.[type_desc] IN ('SQL_LOGIN', 'WINDOWS_LOGIN', 'WINDOWS_GROUP')
    AND dp.[sid] <> sp.[sid]

    IF (@AutoFixCommand <> '')
    BEGIN
        PRINT 'Fixing users in database: ' + DB_NAME()
        PRINT @AutoFixCommand
        EXEC(@AutoFixCommand)
        PRINT ''
    END
END
GO

    Dann habe ich die sys.sp_MS_marksystemobject gespeicherte Prozedur, um meine gespeicherten Prozedur verfügbar in allen Benutzer-Datenbanken (so dass es für den Betrieb auf lokale Objekte)

    EXEC sys.sp_MS_marksystemobject 'sp_AutoFixAllUsers'

    Können Sie es wie folgt:

    EXEC [MyDB].[dbo].[sp_AutoFixAllUsers]

    Oder für jede Datenbank, die mithilfe sp_msforeachdb:

    EXEC sp_msforeachdb '[?].[dbo].[sp_AutoFixAllUsers]'
    InformationsquelleAutor Tom Hunter
Schreibe einen Kommentar