So drucken Sie datagridview-Tabelle mit der Kopfzeile vb.net?

Den original code ist ein netter Anfang, aber hat ein paar bugs und inefficiecies:

• Es nutzt die newpage Flagge zum drucken der Kopfzeile oder der ersten Reihe, wenn es eine neue Seite. Natürlich können Sie wirklich wollen, es zu tun, sowohl
• Druck der Spaltenüberschriften erfolgt einmal pro Seite, so dass Sie nicht brauchen, um in der Daten-print-Schleife an alle
• Es ist nicht erlaubt für unsichtbare Spalten oder Spalten mit anderen als Standard-Ausrichtung, Es könnten auch andere derartige Einstellungen, die Sie möchten, zu berücksichtigen.
• Weil es nicht tatsächlich drucken die richtige Anzahl von Zeilen, sobald Sie zu beheben, die Sie finden, dass es Nachdrucke der letzten Zeile der vorherigen Seite als erste Zeile einer neuen Seite.
• Es gibt einen internen Dachrinne oder margin, damit der text nicht drucken zu nahe an Rasterlinien - dieser benutzt nur einen Versatz von 1 oder 2
• Ist es auch unnötig mit single und RectangleF
• Es ist auch nicht bereit, für das Dokument wieder angezeigt werden oder Gedruckt werden. Sie wollen auch auf die reset - mRow und newpage entweder die-Taste oder klicken Sie auf BeginPrint Veranstaltung.

Habe ich ein paar Kommentare sowie färben der Kopfzeile, die zeigen, wie zu implementieren, Dinge wie ein RowPrePaint Regel.

Private mRow As Integer = 0
Private newpage As Boolean = True

Private Sub PrintDocument1_PrintPage(sender As System.Object,
                    e As PrintPageEventArgs) Handles PrintDocument1.PrintPage

    ' sets it to show '...' for long text
    Dim fmt As StringFormat = New StringFormat(StringFormatFlags.LineLimit)
    fmt.LineAlignment = StringAlignment.Center
    fmt.Trimming = StringTrimming.EllipsisCharacter
    Dim y As Int32 = e.MarginBounds.Top
    Dim rc As Rectangle
    Dim x As Int32
    Dim h As Int32 = 0
    Dim row As DataGridViewRow

    ' print the header text for a new page
    '   use a grey bg just like the control
    If newpage Then
        row = dgvZZ.Rows(mRow)
        x = e.MarginBounds.Left
        For Each cell As DataGridViewCell In row.Cells
            ' since we are printing the control's view,
            ' skip invidible columns
            If cell.Visible Then
                rc = New Rectangle(x, y, cell.Size.Width, cell.Size.Height)

                e.Graphics.FillRectangle(Brushes.LightGray, rc)
                e.Graphics.DrawRectangle(Pens.Black, rc)

                ' reused in the data pront - should be a function
                Select Case dgvZZ.Columns(cell.ColumnIndex).DefaultCellStyle.Alignment
                    Case DataGridViewContentAlignment.BottomRight,
                         DataGridViewContentAlignment.MiddleRight
                        fmt.Alignment = StringAlignment.Far
                        rc.Offset(-1, 0)
                    Case DataGridViewContentAlignment.BottomCenter,
                        DataGridViewContentAlignment.MiddleCenter
                        fmt.Alignment = StringAlignment.Center
                    Case Else
                        fmt.Alignment = StringAlignment.Near
                        rc.Offset(2, 0)
                End Select

                e.Graphics.DrawString(dgvZZ.Columns(cell.ColumnIndex).HeaderText,
                                            dgvZZ.Font, Brushes.Black, rc, fmt)
                x += rc.Width
                h = Math.Max(h, rc.Height)
            End If
        Next
        y += h

    End If
    newpage = False

    ' now print the data for each row
    Dim thisNDX As Int32
    For thisNDX = mRow To dgvZZ.RowCount - 1
        ' no need to try to print the new row
        If dgvZZ.Rows(thisNDX).IsNewRow Then Exit For

        row = dgvZZ.Rows(thisNDX)
        x = e.MarginBounds.Left
        h = 0

        ' reset X for data
        x = e.MarginBounds.Left

        ' print the data
        For Each cell As DataGridViewCell In row.Cells
            If cell.Visible Then
                rc = New Rectangle(x, y, cell.Size.Width, cell.Size.Height)

                ' SAMPLE CODE: How To 
                ' up a RowPrePaint rule
                'If Convert.ToDecimal(row.Cells(5).Value) < 9.99 Then
                '    Using br As New SolidBrush(Color.MistyRose)
                '        e.Graphics.FillRectangle(br, rc)
                '    End Using
                'End If

                e.Graphics.DrawRectangle(Pens.Black, rc)

                Select Case dgvZZ.Columns(cell.ColumnIndex).DefaultCellStyle.Alignment
                    Case DataGridViewContentAlignment.BottomRight,
                         DataGridViewContentAlignment.MiddleRight
                        fmt.Alignment = StringAlignment.Far
                        rc.Offset(-1, 0)
                    Case DataGridViewContentAlignment.BottomCenter,
                        DataGridViewContentAlignment.MiddleCenter
                        fmt.Alignment = StringAlignment.Center
                    Case Else
                        fmt.Alignment = StringAlignment.Near
                        rc.Offset(2, 0)
                End Select

                e.Graphics.DrawString(cell.FormattedValue.ToString(),
                                      dgvZZ.Font, Brushes.Black, rc, fmt)

                x += rc.Width
                h = Math.Max(h, rc.Height)
            End If

        Next
        y += h
        ' next row to print
        mRow = thisNDX + 1

        If y + h > e.MarginBounds.Bottom Then
            e.HasMorePages = True
            ' mRow -= 1   causes last row to rePrint on next page
            newpage = True
            Return
        End If
    Next


End Sub

Beachten, dass es eine Id Spalte unsichtbar in der DGV, die Color Spalte ist zentriert und Price ist Linksbündig ausgerichtet - das sind alle Einstellungen abgeholt von der Steuerung. Beachten Sie auch, dass der text verschoben wird, Weg von den Rasterlinien nur ein bisschen.

Den letzten Punkt oben, Sie auch zurücksetzen möchten mRow und newpage entweder die-Taste oder klicken Sie auf BeginPrint Veranstaltung. bedeutet dies:

Private Sub PrintDocument1_BeginPrint(sender As Object, 
          e As PrintEventArgs) Handles PrintDocument1.BeginPrint
    mRow = 0
    newpage = True
    PrintPreviewDialog1.PrintPreviewControl.StartPage = 0
    PrintPreviewDialog1.PrintPreviewControl.Zoom = 1.0
End Sub

Nachdem Sie eine Vorschau der mRow variable wird zeigen, dass alle Zeilen gedruckt wurden. Wenn der Benutzer auf Drucken klickt oder geht wieder für ein weiteres Album, wird nichts gedruckt. Dieser code setzt auch die erste Seite zu zeigen, und das erste Zoom.

InformationsquelleAutor Nat Pongjardenlarp