So exportieren Sie clob-Feld Daten in einem oracle sql-developer

Exportieren clob-Feld Daten in oracle sql developer. Derzeit clob-Feld-Daten können nicht exportiert in oracle sql developer.

  • Mögliche Duplikate?, Welche Art von export-wollen Sie tun?
  • Ich möchte zu exportieren clob-Daten in sql-format. Also ich kann wieder einfügen gleichen Daten, wenn ich will.
  • Du meinst, wie eine Liste von insert Aussagen? Als die verlinkten Antwort fragt, was würde erwarten, dass die insert-Anweisung zu schauen, wie in diesem Fall, vor allem, wenn der CLOB-Werte überschreitet 4k? Was ist falsch mit data pump export?
InformationsquelleAutor Prashobh Chandran | 2017-02-15
  1. 11

    Wenn Sie wollen nicht (oder können nicht) export und import Ihre Daten, und wirklich wollen, es als eine Reihe von insert-Anweisungen Sie können SQL-Developer ' s built-in-Formatierung-tools zur automatischen Trennung von Ihrem CLOBs in mehrere Stücke, die klein genug sind, um gültig zu sein, da string-Literale, und dann Spule das Ergebnis in einer Datei:

    spool clob_export.sql
select /*insert*/* from your_table;
spool off

    Mit neueren Versionen, die Sie verwenden können,die sqlformat - Befehl, um Kontrolle über die Ausgabe-format, ohne die Abfrage zu modifizieren; dies ist äquivalent:

    set sqlformat insert
spool clob_export.sql
select * from your_table;
spool off

    Den generierten insert-statements wird etwa so Aussehen:

    REM INSERTING into YOUR_TABLE
SET DEFINE OFF;
Insert into YOUR_TABLE (ID,CLOB_COLUMN) values (1,TO_CLOB('... up to 4k of characters with quotes escaped ...')
|| TO_CLOB('... up to 4k of characters with quotes escaped ...')
|| TO_CLOB('... up to 4k of characters with quotes escaped ...')
...
|| TO_CLOB('... up to 4k of characters with quotes escaped ...'));
    • Wichtige Informationen für Benutzer von SQL Developer: um für diese zu arbeiten, die Sie nicht ausführen kann, die Linien getrennt. Sie brauchen, um Sie auszuführen, als ein Skript.
    InformationsquelleAutor Alex Poole
  2. 2

    Den folgenden EXP_IMP_LOB Paket können exportieren und importieren von CLOB, NCLOB BLOB-Spalte Typ die Daten über einfache SQL - (text -) Dateien.

    Wie zu verwenden:

    zunächst installieren Sie das Paket auf Quell-und Ziel-schemas.
    Zu exportieren, führen Sie diese Option wählen,

    select * from table( EXP_IMP_LOB.EXPORT('table_name','lob_column_name','condition') );

    wo die Table_Name und LOB_Column_Name definieren der Spalte Daten und die optionale Bedingung definiert die Zeile oder Zeilen.
    Wenn es keine Bedingung, dann jede Zeile, die Daten exportiert werden sollen Zeile für Zeile.

    Beispiel:

    select * from table( EXP_IMP_LOB.EXPORT('person','image','id=103' ) );

    Ergebnis:

    /******************************************************
    TABLE  :PERSON
    COLUMN :IMAGE
    ROW    :103
******************************************************/
BEGIN
    EXP_IMP_LOB.IMPORT_NEW;
    EXP_IMP_LOB.IMPORT_APPEND ( 'FFD8FFE000104A464....23232323232');
    EXP_IMP_LOB.IMPORT_APPEND ( '32323232323232323....798999AA2A3');
    .........
    EXP_IMP_LOB.IMPORT_APPEND ( 'B2316524267279AA9....51401FFFD9');
    EXP_IMP_LOB.IMPORT_UPDATE ( 'PERSON','IMAGE','103' ); 
    COMMIT;
END;
/

    So, der export wandelt die binären Daten zu 400 char Länge hexa-strings und erstellt ein Skript von ihm.
    Ich benutzt ..... symbolisieren viele chars, denn das ist nur ein Beispiel oben.

    NICHT DAS RESULTAT SORTIEREN!

    Importieren, müssen Sie nur installieren Sie das Paket auf das Ziel-schema zu, und führen Sie das obige Skript in das Zielschema.
    Das ist alles.

    ...mehr:

    • Die Quell-und Ziel-table-name, column-name muss der gleiche sein!
    • Der Tabelle (Quelle und Ziel) müssen Primär-Schlüssel müssen identisch sein.
    • Die EXPORT-Funktion erkennen kann, primary key automatisch. Theoretisch verwalten können zusammengesetzt Tasten zu...
    • Die Größe eines hexa-Zeichenfolge definiert wird, in G_LENGTH Globale variable. 200 chars bedeutet 400 hexa chars.
    • Das weitere Verfahren:
    • IMPORT_NEW : setzt der Paket-Variablen vorzubereiten, es zu akzeptieren, eine neue LOB -
    • IMPORT_APPEND : konvertiert die hexa-Zeichenfolge, um eine Binär-Daten und fügen Sie es dem Paket variable
    • IMPORT_UPDATE : aktualisiert die Tabelle, Zeile, Spalte mit dem Paket-variable
    • DIRECT_SQL : führt das angegebene SQL-global-LOB-variable als parameter. eg: EXP_IMP_LOB.DIRECT_SQL( 'insert into ANY_TABLE ( ID, BILD ) values ( 123, :1 )' );
    /*============================================================================================*/
create or replace package EXP_IMP_LOB is
/*============================================================================================*/

  type T_STRING_LIST is table of varchar2( 32000 );

    ---------------------------------------------------------------------------
    function  EXPORT ( I_TABLE_NAME  in varchar2
                     , I_COLUMN_NAME in varchar2
                     , I_WHERE       in varchar2 default null
                     ) return T_STRING_LIST pipelined;
    ---------------------------------------------------------------------------

    ---------------------------------------------------------------------------
    procedure IMPORT_NEW;
    ---------------------------------------------------------------------------

    ---------------------------------------------------------------------------
    procedure IMPORT_APPEND ( I_RAW         in varchar2);
    ---------------------------------------------------------------------------

    ---------------------------------------------------------------------------
    procedure DIRECT_SQL ( I_SQL  in varchar2 );
    ---------------------------------------------------------------------------

    ---------------------------------------------------------------------------
    procedure IMPORT_UPDATE ( I_TABLE_NAME  in varchar2
                            , I_COLUMN_NAME in varchar2
                            , I_PK          in varchar2
                            );
    ---------------------------------------------------------------------------

end;
/



/*============================================================================================*/
create or replace package body EXP_IMP_LOB is
/*============================================================================================*/


    G_TABLE_NAME    varchar(   40 );
    G_COLUMN_NAME   varchar(   40 );
    G_COLUMN_TYPE   varchar(   40 );
    G_PK_KEY        varchar( 4000 );
    G_PK_LST        varchar( 4000 );
    G_LENGTH        number := 200;
    G_BLOB          blob;
    G_CLOB          clob;

---------------------------------------------------------------------------
procedure GET_PK ( I_TABLE_NAME in varchar ) is
---------------------------------------------------------------------------
    L_SEP           varchar ( 40 ) := ',';
    L_DATA_TYPE     varchar2( 30 );
begin
    G_PK_KEY := '';
    G_PK_LST := '';
    for L_A_PK in ( select COLUMN_NAME
                      from USER_CONSTRAINTS UC
                         , USER_CONS_COLUMNS DBC
                     where UC.CONSTRAINT_TYPE  = 'P'
                       and DBC.CONSTRAINT_NAME = UC.CONSTRAINT_NAME
                       and DBC.TABLE_NAME      = I_TABLE_NAME 
                     order by position 
                  ) 
    loop
        if nvl( length( G_PK_KEY ), 0 ) + length( L_A_PK.COLUMN_NAME ) < 4000 then
            select DATA_TYPE into L_DATA_TYPE from user_tab_columns where table_name = G_TABLE_NAME and column_name = L_A_PK.COLUMN_NAME;
            if instr( L_DATA_TYPE, 'CHAR') > 0 then
                G_PK_KEY := G_PK_KEY||'''''''''||'||L_A_PK.COLUMN_NAME||'||''''''''||'''||L_SEP||'''||';
            elsif instr( L_DATA_TYPE, 'DATE') > 0 then
                G_PK_KEY := G_PK_KEY||'''TO_DATE(''''''||TO_CHAR('||L_A_PK.COLUMN_NAME||',''YYYY.MM.DD HH24:MI:SS'')||'''''',''''YYYY.MM.DD HH24:MI:SS'''')''||'''||L_SEP||'''||';
            else
                G_PK_KEY := G_PK_KEY||L_A_PK.COLUMN_NAME||'||'''||L_SEP||'''||';
            end if;
            G_PK_LST := G_PK_LST||L_A_PK.COLUMN_NAME||L_SEP;
        end if;
    end loop;
    G_PK_KEY := substr( G_PK_KEY, 1, length( G_PK_KEY ) - ( 6 + length( L_SEP ) ) );
    G_PK_LST := substr( G_PK_LST, 1, length( G_PK_LST ) - length(L_SEP));
end;

---------------------------------------------------------------------------
function EXPORT ( I_TABLE_NAME  in varchar2
                , I_COLUMN_NAME in varchar2
                , I_WHERE       in varchar2 default null
                ) return T_STRING_LIST pipelined is
---------------------------------------------------------------------------
    V_BLOB          blob;
    V_CLOB          clob;
    V_CUR_SQL       varchar( 32000 );
    V_LOB_SQL       varchar( 32000 );
    V_RAW           varchar( 32000 );
    V_START         number;
    V_PK            varchar(  4000 );
    V_REC_SET       sys_refcursor; 

begin
    G_TABLE_NAME  := upper( trim( I_TABLE_NAME  ) );
    G_COLUMN_NAME := upper( trim( I_COLUMN_NAME ) );
    GET_PK( G_TABLE_NAME );
    select DATA_TYPE into G_COLUMN_TYPE from user_tab_columns where table_name = G_TABLE_NAME and column_name = G_COLUMN_NAME;
    if G_COLUMN_TYPE not in ('CLOB','NCLOB','BLOB') then
        raise_application_error ( -20001, 'The type of column '||I_COLUMN_NAME||' is not CLOB, NCLOB or BLOB' );    
    end if;

    V_CUR_SQL := 'select '||G_PK_KEY||' from '||G_TABLE_NAME||' where '||nvl( I_WHERE, ' 1 = 1 ');
    open V_REC_SET for V_CUR_SQL;
    loop
        fetch V_REC_SET into V_PK;
        exit when V_REC_SET%notfound; 
        PIPE ROW( '/******************************************************' );
        PIPE ROW( '   TABLE  :'||G_TABLE_NAME                               );
        PIPE ROW( '   COLUMN :'||G_COLUMN_NAME                              );
        PIPE ROW( '   ROW    :'||V_PK                                       );
        PIPE ROW( '******************************************************/' );
        PIPE ROW( 'BEGIN'                                                   );
        PIPE ROW( '   EXP_IMP_LOB.IMPORT_NEW;'                              );
        V_LOB_SQL := 'select '||G_COLUMN_NAME||' from '||G_TABLE_NAME||' where ('||G_PK_LST||') in ( select '||V_PK||' from dual )';

        if G_COLUMN_TYPE = 'BLOB' then
            execute immediate V_LOB_SQL into V_BLOB;
            if nvl( dbms_lob.getlength( V_BLOB ), 0 ) > 0 then
                V_START := 1;
                for L_I IN 1..ceil( dbms_lob.getlength( V_BLOB ) /G_LENGTH )
                loop
                    V_RAW   := dbms_lob.substr( V_BLOB, G_LENGTH, V_START );
                    PIPE ROW( '   EXP_IMP_LOB.IMPORT_APPEND ( '''||V_RAW||''');'         );
                    V_START := V_START + G_LENGTH;
                end loop;
                PIPE ROW( '   EXP_IMP_LOB.IMPORT_UPDATE ( '''||G_TABLE_NAME||''','''||G_COLUMN_NAME||''','''||replace(V_PK,'''','''''')||''' ); ');
                PIPE ROW( '   COMMIT;'                                              );
            end if;
        else
            execute immediate V_LOB_SQL into V_CLOB;
            if nvl( dbms_lob.getlength( V_CLOB ), 0 ) > 0 then
                V_START := 1;
                for L_I IN 1..ceil( dbms_lob.getlength( V_CLOB ) /G_LENGTH )
                loop
                    V_RAW   := UTL_RAW.CAST_TO_RAW( dbms_lob.substr( V_CLOB, G_LENGTH, V_START ) );
                    PIPE ROW( '   EXP_IMP_LOB.IMPORT_APPEND ( '''||V_RAW||''');'         );
                    V_START := V_START + G_LENGTH;
                end loop;
                PIPE ROW( '   EXP_IMP_LOB.IMPORT_UPDATE ( '''||G_TABLE_NAME||''','''||G_COLUMN_NAME||''','''||replace(V_PK,'''','''''')||''' ); ');
                PIPE ROW( '   COMMIT;'                                              );
            end if;
        end if;
        PIPE ROW( 'END;'                                                    );   
        PIPE ROW( '/'                                                       );
        PIPE ROW( ' '                                                       );
    end loop;
    close V_REC_SET;

    return;

end;

---------------------------------------------------------------------------
procedure IMPORT_NEW is
---------------------------------------------------------------------------
begin
    G_BLOB := null;
    G_CLOB := null;
end;

---------------------------------------------------------------------------
procedure IMPORT_APPEND ( I_RAW         in varchar2 ) is
---------------------------------------------------------------------------
    V_BLOB          blob;
begin
    V_BLOB := hextoraw( I_RAW );
    if nvl( dbms_lob.getlength( V_BLOB ), 0 ) > 0 then
        if nvl( dbms_lob.getlength( G_BLOB ), 0 ) = 0 then 
            G_BLOB := V_BLOB;
        else
            DBMS_LOB.APPEND( G_BLOB, V_BLOB );
        end if;
    end if;       
end;

---------------------------------------------------------------------------
procedure DIRECT_SQL ( I_SQL  in varchar2 ) is
---------------------------------------------------------------------------
begin
    if nvl( dbms_lob.getlength( G_BLOB ), 0 ) > 0 then
        execute immediate I_SQL using G_BLOB;
    else
        execute immediate I_SQL using G_CLOB;
    end if;
    commit;
end;

-- I downloaded this from the Net:
function clobfromblob( p_blob blob ) return clob is
    l_clob         clob;
    l_dest_offsset integer := 1;
    l_src_offsset  integer := 1;
    l_lang_context integer := dbms_lob.default_lang_ctx;
    l_warning      integer;
begin
    if p_blob is null then
        return null;
    end if;
    dbms_lob.createTemporary(lob_loc => l_clob
                            ,cache   => false);
    dbms_lob.converttoclob(dest_lob     => l_clob
                          ,src_blob     => p_blob
                          ,amount       => dbms_lob.lobmaxsize
                          ,dest_offset  => l_dest_offsset
                          ,src_offset   => l_src_offsset
                          ,blob_csid    => dbms_lob.default_csid
                          ,lang_context => l_lang_context
                          ,warning      => l_warning);
    return l_clob;
end;


---------------------------------------------------------------------------
procedure IMPORT_UPDATE ( I_TABLE_NAME  in varchar2
                        , I_COLUMN_NAME in varchar2
                        , I_PK          in varchar2
                        ) is
---------------------------------------------------------------------------
    V_SQL           varchar( 32000 );
begin
    G_TABLE_NAME  := upper( trim( I_TABLE_NAME  ) );
    G_COLUMN_NAME := upper( trim( I_COLUMN_NAME ) );
    GET_PK( G_TABLE_NAME );
    select DATA_TYPE into G_COLUMN_TYPE from user_tab_columns where table_name = G_TABLE_NAME and column_name = G_COLUMN_NAME;
    V_SQL := 'update '||I_TABLE_NAME||' set '||I_COLUMN_NAME||' = :1 where ('||G_PK_LST||') in ( select '||I_PK||' from dual )';
    if G_COLUMN_TYPE in ( 'CLOB', 'NCLOB' ) then
        G_CLOB := clobfromblob ( G_BLOB );
        G_BLOB := null;
        DIRECT_SQL( V_SQL );
    elsif G_COLUMN_TYPE in ( 'BLOB' ) then
        DIRECT_SQL( V_SQL );
    end if;
end;


end;
/
    InformationsquelleAutor Ferenc Tóth
  3. 0

    War ich konfrontiert mit diesem Problem, wenn Sie versucht, zu kopieren eine Tabelle, die CLOB-Spalte aus einer Datenbank-server zu einem anderen. Oracle SQL Developer ist "Tools - > Datenbank Kopieren" - tool war nicht eine gute Wahl für mich, weil ich brauchte einen anderen Namen für die Zieltabelle, also musste ich verwende "Tools - > Datenbank Exportieren", erzeugt der insert-Anweisungen für Sie .sql-Datei, wenn Sie so wählen.

    Schritte, die ich gemacht habe:

    1. Führen Sie diese in der Quell-DB:

      SELECT 
someColumA,
someColumB,
SubStr(myClobColumn, 1, 4000)    myClobColumn_part1, 
SubStr(myClobColumn, 4001, 8000) myClobColumn_part2, 
. . .
SubStr(Clob_field, .., ..) Clob_field_partN, 
OtherColumns
FROM YourTable ;

    2. Rechts und klicken Sie auf exportieren in eine Datei, alle insert-statements geschrieben werden, um eine temporäre Tabelle: EXPORT_TABLE.

    3. Führen, dass die Datei in die Ziel-DB-server zu erstellen EXPORT_TABLE

    4. Nun führen Sie das importieren der ersten 4000 chars:

      Insert Into YourDestinationTable(.., myClobColumn, ..)
SELECT .., myClobColumn_part1, ..
FROM EXPORT_TABLE ;

    5. Führen diese zum Anhängen der rest der Clob-Teile:

      Update YourDestinationTable A
   set myClobColumn = myClobColumn 
        || (Select myClobColumn_part2 
            From EXPORT_TABLE B
            Where B.tableKey = A.tableKey 
              and myClobColumn_part2 is not null)
;


Update YourDestinationTable A
   set myClobColumn = myClobColumn 
        || (Select myClobColumn_part3 
            From EXPORT_TABLE B
            Where B.tableKey = A.tableKey 
              and myClobColumn_part3 is not null)
;
...

    bis Teil N.

    Fertig.

    InformationsquelleAutor W. Elbashier
  4. 0

    Ich habe das gleiche problem, wenn ich versuche zu exportieren, einfügen, Felder, clob oder blob, dann ist es nicht enthalten, die in insert-Abfrage.

    Dies ist das Problem wegen der insert-Grenze nicht in Anspruch nehmen, um clob-Datentyp Größe.

    Lösung:

    Ich exportieren von Daten im XML-oder PDF-oder loader-oder Json. Dann habe ich Daten, clob oder blob.

    Tools - > Datenbank Exportieren > wählen Sie den Verbindungs - > deaktivieren Sie die Option export-DDl-wenn Sie möchten, dass nur die Daten > überprüfen Sie Daten exportieren > wählen Sie format: XML - > next > weiter > weiter > weiter >fertig stellen.

    Datei öffnen, in dem Sie speichern, die XML-Datei und überprüfen.

    genießen...

    InformationsquelleAutor ankit
Schreibe einen Kommentar