So löschen Sie Daten im ms-access-Tabellen auf einmal?

Gibt es eine Möglichkeit in MS-Access zu löschen die Daten in allen Tabellen gleichzeitig. Wir führen eine Datenbank in access speichern Sie die Daten jeden Monat und dann löschen Sie alle Daten im Zugriff. Aber es erfordert das löschen von Daten aus einer Menge von Tabellen. Gibt es nicht eine einfachere/leichtere Möglichkeit dies zu tun?

InformationsquelleAutor Varun Mahajan | 2009-03-26

ms-access sql

16

Warum gehst du nicht halten Sie eine leere Kopie der Datenbank auf der hand. Am Ende des Monats, speichern Sie die vorhandene Datenbank, dann kopieren Sie die leere Datenbank an seiner Stelle.
- Dies bedeutet auch, dass Sie nicht brauchen, zu komprimieren und reparieren.
- Tolle Antwort. Sehr pragmatisch.
- Und dann haben Sie replizieren alle fixes oder Verbesserungen, die über die leere Datenbank. Ich mache das schon seit einer Weile, aber es ist sehr fehleranfällig, um nicht zu sagen langweilig. Ich werde die anderen Lösungen zu probieren.
InformationsquelleAutor Craig T

Craig die Antwort ist einfach und sinnvoll. Wenn Sie wirklich wollen, eine programmatische Lösung, die folgende VBA-Skript löscht alle Daten aus jeder Tabelle mit Ausnahme der ausgeblendeten Tabellen. Es erfordert DAO aktiviert sein - im Visual Basic-Editor, gehen Sie auf Tools -> Referenzen, und markieren Sie "Microsoft DAO 3.6 Object Library", dann "OK":

Public Sub TruncateTables()
'Majority of code taken from a data dictionary script I can no longer source nor find the author

On Error GoTo Error_TruncateTables

Dim DB As DAO.Database
Dim TDF As DAO.TableDef
Dim strSQL_DELETE As String

Set DB = CurrentDb()

    For Each TDF In DB.TableDefs
        If Left(TDF.Name, 4) <> "MSys" Then
            strSQL_DELETE = "DELETE FROM " & TDF.Name & ";"
            DB.Execute strSQL_DELETE
        End If
    Next

MsgBox "Tables have been truncated", vbInformation, "TABLES TRUNCATED"
DB.Close

Exit_Error_TruncateTables:
    Set TDF = Nothing
    Set DB = Nothing
    Exit Sub

Error_TruncateTables:
    Select Case Err.Number
        Case 3376
            Resume Next 'Ignore error if table not found
         Case 3270 'Property Not Found
            Resume Next
        Case Else
            MsgBox Err.Number & ": " & Err.Description
            Resume Exit_Error_TruncateTables
    End Select
End Sub

InformationsquelleAutor Alistair Knock

Super Antwort von Alistair, obwohl es aktualisiert werden muss. Die alten if-Anweisung würde Fehler verursachen, und die alten dynamischen string nicht funktionieren würde, die auf Tabellen mit Namen, die ein Leerzeichen. Es würde zu behandeln, einen Namen wie "personenbezogene Daten" als "person". Ich habe aktualisiert, der code, sondern machte es ein wenig leichter zu Ausnahmen hinzufügen, um die if-Anweisung, wenn Sie möchten, einige Tabellen, seine Daten zu behalten.

 Public Sub TruncateTables()
    'Majority of code taken from a data dictionary script I can no longer source nor find the author

    On Error GoTo Error_TruncateTables

    Dim DB As DAO.Database
    Dim TDF As DAO.TableDef
    Dim strSQL_DELETE As String

    Set DB = CurrentDb()

        For Each TDF In DB.TableDefs
            If Not (TDF.Name Like "MSys*" Or TDF.Name Like "~*" Or Len(TDF.Connect) > 0) Then
                'This will prevent system, temporary and linked tables from being cleared
                strSQL_DELETE = "DELETE FROM " & "[" & TDF.Name & "]"
                DB.Execute strSQL_DELETE
            End If
        Next

    MsgBox "Tables have been truncated", vbInformation, "TABLES TRUNCATED"
    DB.Close

    Exit_Error_TruncateTables:
        Set TDF = Nothing
        Set DB = Nothing
        Exit Sub

    Error_TruncateTables:
        Select Case Err.Number
            Case 3376
                Resume Next 'Ignore error if table not found
             Case 3270 'Property Not Found
                Resume Next
            Case Else
                MsgBox Err.Number & ": " & Err.Description
                Resume Exit_Error_TruncateTables
        End Select
    End Sub

Watch out! Dies wird auch klar, verlinkten Tabelle. Werde ich Bearbeiten, um die Bedingung hinzuzufügen Len(tdf.Connect) = 0 um dies zu verhindern.

InformationsquelleAutor Marcin Deszczynski

0

Da dies eine sich wiederholende Aktion, es wäre besser, wenn Sie ein einfaches SQL-Skript, um dies zu tun.
```
DELETE FROM <table1>;
DELETE FROM <table2>;
...
DELETE FROM <tablen>;
```
- MS-access ist es nicht möglich, mehr als eine DELETE-Abfrage im Skript.
InformationsquelleAutor ksuralta
0

Markieren Sie alle ZEILEN und drücken Sie dann die Entf-Taste auf Ihrer Tastatur. Wenn der Zugriff ist dabei, dass Ding wäre es nicht lassen Sie auf den Grund gehen,dann gehen Sie in eine Zelle und klicken Sie auf Strg+nach-unten-Pfeil. Markieren Sie alle Zeilen, markieren Sie die erste Zeile, und dann scrollen Sie zu der unteren Zeile, und halten Sie shift gedrückt, wählen Sie in der unteren Zeile. Alle Zeilen sollten nun markiert sein.

InformationsquelleAutor user1958446

Dies löscht alle Daten aus allen Tabellen außer Systemtabellen

Dim T As TableDef
DoCmd.SetWarnings False
For Each T In CurrentDb.TableDefs
    If T.Name Like "d2s_*" Then
        DoCmd.RunSQL "DELETE * FROM " & T.Name
    End If
Next T
DoCmd.SetWarnings True

Einen anderen Ansatz: (Basierend auf dem Vorschlag von Christopher Herzog)

Dim T As TableDef
DoCmd.SetWarnings False
For Each T In CurrentDb.TableDefs
    If Not Left(T.Name, 4) = "MSys" Then
        DoCmd.RunSQL "DELETE * FROM [" & T.Name & "]"
    End If
Next T
DoCmd.SetWarnings True

InformationsquelleAutor Adarsh Madrecha

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.