So verschieben Sie Dateien von einem Verzeichnis in ein anderes Verzeichnis basierend auf der Dateigröße

Derzeit arbeite ich an ein Automatisierungs-Projekt bei der Arbeit. Einer der Schritte, um das Programm, das ich brauche, um separate Dateien, die größer sind als 6000KB von den anderen Dateien in dem Ordner. Ich bin auf der Suche nach einer batch-Datei, die in der Lage ist, Dateien zu verschieben, die größer sind als 6000KB von Ihrem aktuellen Verzeichnis in ein anderes Verzeichnis. Ich brauche diese batch-Datei zu tun, verarbeiten eine batch-Dateien und nicht nur eine. Irgendwelche Gedanken auf, wie man dies in einer batch-Datei?

stackoverflow.com/q/7363523/69820

InformationsquelleAutor CLO_471 | 2011-08-11

Wenn Sie möchten, verwenden Sie VBScript verwenden, können Sie dieses Skript als Grundlage:

' use a default source path or get one from the command line parameters
dim sourcepath: sourcepath = "some\default\path"
if WScript.Arguments.Named.Exists("source") then
    sourcepath = WScript.Arguments.Named("source")
end if

' use a default destination path or get one from the command line
dim destinationpath: destinationpath = "some\default\path"
if WScript.Arguments.Named.Exists("destination") then
    destinationpath = WScript.Arguments.Named("destination")
end if

' use a default file size limit or get one from the command line
' we accept in kbytes so we convert this to bytes
dim sizelimit: sizelimit = 6000 * 1024 ' default 6000 kbytes
if WScript.Arguments.Named.Exists("sizelimit") then
    sizelimit = WScript.Arguments.Named("sizelimit")
end if

' use a Scripting.FileSystemObject to get the file objects of each file
' in the source directory. The file object has a Size property, which
' has the file size in bytes
dim fso: set fso = CreateObject("Scripting.FileSystemObject")
dim sourcefolder: set sourcefolder = fso.GetFolder(sourcepath)
if not fso.FolderExists(destinationpath) then
     ' we'll throw an error if the path is not found but you could instead
     ' create the directory automatically
     err.raise 1,,destinationpath & " not found"
end if

' loop through each file in the directory, compare size property against
' the limit and copy as appropriate
dim file, count: count = 0
for each file in sourcefolder.Files
    if file.size > sizelimit then
         file.Move destinationpath
         count = count + 1
    end if
next

WScript.Echo("complete: " & count & " file(s) moved")

Man könnte dieses (nennen wir es move-files.vbs) aus einer batch-Datei so:

cscript move-files.vbs /source:"C:\Documents and Settings\Username\Desktop" /destination:"F:\backup" /sizelimit:1000

InformationsquelleAutor

2
```
ROBOCOPY c:\From c:\To /E /MOVE /MIN:6144000  /MT:32
```
Ersetzen "c:\From" und "c:\To" Wege zu Ihrem wahren Pfade zu Dateien

/MIN:n : Minimaler Größe - ausschließen von Dateien, die kleiner als n bytes.

/MT[:n] : Multithread kopieren, n = Nein. threads zu verwenden (1-128) ###
default = 8-Gewinde, nicht kompatibel mit /IPG und /EFSRAW
für Windows7

/E : Kopieren Sie die Unterordner, auch die Leeren Unterordner.

/S : Kopieren Sie Die Unterordner.

Robocopy ist ein Standard Windows7 Befehl, um es unter Windowx XP herunterladen und installieren Microsoft Ressource Kit

Details und weitere Parameter für Robocopy sind hier
- Ich arbeite derzeit mit windows xp also diese Befehlszeile nicht ausführen. Ich versuchte, laden Sie das resource kit. Es ist nur ein Buch, oder ist es die software? Ich sah nur Bücher. Noch nie davon gehört.
- microsoft.com/download/en/details.aspx?id=17657 - Sorry, Feste Verbindung zur Resource Kit download-Seite auch in meinem post. Es ist eine software von Microsoft. Installieren Sie es, und dann werden Sie in der Lage, verwenden Sie robocopy-Befehl. BTW /MT:32 parameter ist nicht zugänglich in Windows XP - verwenden Sie "ROBOCOPY c:\From c:\To /E /MOVE /MIN:6144000"
InformationsquelleAutor Cheburek
2

können Sie vbs-Datei mit Objekt: File-Objekt-Referenz

oder Sie können versuchen, zu machen .bat Datei mit diesem Befehl extrahieren Sie die Dateigröße.
```
for %%R in ([filepath and name]) do if %%~zR GTR [file size]
```
dieser Seite: Batch-Datei zu überprüfen, filesize

Ich würde empfehlen, den VBS-Optionen für mehr Sicherheit.

EDIT: das ist eine batch-Datei für die Dateien zu verschieben. Bitte ändern Sie die <move file> zu einem geeigneten Befehl.
```
@echo off
for /F "usebackq tokens=3,4" %%i IN (`dir /-C`) DO CALL :MOVE_FILES %%i %%j 
exit /b 0

:MOVE_FILES
if %1.==. exit /b 0
if %1 GEQ 6000000 <move file>
```
- Ich weiß fast nichts über vbs. Ich muss in der Lage sein, um dieses Skript ausführen täglich auf einen Ordner für Importe. Überprüfen Sie die Größe der Datei und verschieben Sie ALLE Dateien, die größer als 6000 KB in einen anderen Ordner, weil es erfordert eine andere Automatisierung.
InformationsquelleAutor Lucian

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.