So wählen Sie Tabelle löschen-Inhalt zu zerstören, ohne die Tabelle?

Wie etwa:

ACell.ListObject.DataBodyRange.Rows.Delete

Halten Ihre Tisch-Struktur und überschriften, aber klar, alle Daten und Zeilen.

EDIT: ich werde nur ändern einen Abschnitt meiner Antwort von Ihre früheren post, wie es funktioniert meistens, was Sie wollen. Dies lässt nur eine Zeile:

With loSource
   .Range.AutoFilter
   .DataBodyRange.Offset(1).Resize(.DataBodyRange.Rows.Count - 1, .DataBodyRange.Columns.Count).Rows.Delete
   .DataBodyRange.Rows(1).Specialcells(xlCellTypeConstants).ClearContents
End With

Wenn Sie möchten, lassen Sie alle Zeilen intakt mit Ihren Formeln und so weiter, nur:

With loSource
   .Range.AutoFilter
   .DataBodyRange.Specialcells(xlCellTypeConstants).ClearContents
End With

Welche in der Nähe zu dem, was @Readify vorgeschlagen, außer es wird nicht klar Formeln.

Habe ich überarbeitet Doug Glancy ' s Lösung zur Vermeidung von Zeilen löschen, was dazu führen kann, #Ref Problem in den Formeln.

Sub ListReset(lst As ListObject)
'clears a listObject while leaving row 1 empty, with formulae
    With lst
        If .ShowAutoFilter Then .AutoFilter.ShowAllData
        On Error Resume Next
        With .DataBodyRange
            .Offset(1).Rows.Clear
            .Rows(1).SpecialCells(xlCellTypeConstants).ClearContents
        End With
        On Error GoTo 0
        .Resize .Range.Rows("1:2")
    End With
End Sub

Es ist eine Bedingung, dass die meisten dieser Lösungen nicht Adresse. Ich überarbeitete Patrick Honorez Lösung zu behandeln. Ich fühlte, ich musste dieses teilen, weil ich war mein Haar ziehen, wenn die ursprüngliche Funktion wurde gelegentlich clearing-mehr Daten, als ich erwartet hatte.

Die situation passiert, wenn die Tabelle hat nur eine Spalte und die .SpecialCells(xlCellTypeConstants).ClearContents versucht, löschen Sie den Inhalt der oberen Zeile. In dieser situation, nur eine Zelle ausgewählt ist (in der oberen Zeile der Tabelle hat nur eine Spalte) und die SpecialCells-Befehl gilt für das ganze Blatt, statt auf den markierten Bereich. Was mit mir geschah wurde anderen Zellen auf dem Blatt, die waren außerhalb meiner Tabelle wurden auch immer gelöscht.

Ich habe einige Graben und fand diese Ratschläge von Mathieu Guindon:
Bereich SpecialCells ClearContents löscht ganze Blatt

Range({jede einzelne Zelle}).SpecialCells({was auch immer}) scheint zu arbeiten aus dem gesamten Blatt.

Range({mehr als eine Zelle}).SpecialCells({was auch immer}) zu funktionieren scheint aus den angegebenen Zellen.

Wenn die Liste/Tabelle hat nur eine Spalte (Zeile 1), diese revision wird überprüfen, um zu sehen, ob die Zelle eine Formel und wenn nicht, wird es nur löschen Sie den Inhalt der einen Zelle.

Public Sub ClearList(lst As ListObject)
'Clears a listObject while leaving 1 empty row + formula
' https://stackoverflow.com/a/53856079/1898524
'
'With special help from this post to handle a single column table.
'   Range({any single cell}).SpecialCells({whatever}) seems to work off the entire sheet.
'   Range({more than one cell}).SpecialCells({whatever}) seems to work off the specified cells.
' https://stackoverflow.com/questions/40537537/range-specialcells-clearcontents-clears-whole-sheet-instead

    On Error Resume Next

    With lst
        '.Range.Worksheet.Activate ' Enable this if you are debugging 

        If .ShowAutoFilter Then .AutoFilter.ShowAllData
        If .DataBodyRange.Rows.Count = 1 Then Exit Sub ' Table is already clear
        .DataBodyRange.Offset(1).Rows.Clear

        If .DataBodyRange.Columns.Count > 1 Then ' Check to see if SpecialCells is going to evaluate just one cell.
            .DataBodyRange.Rows(1).SpecialCells(xlCellTypeConstants).ClearContents
        ElseIf Not .Range.HasFormula Then
            ' Only one cell in range and it does not contain a formula.
            .DataBodyRange.Rows(1).ClearContents
        End If

        .Resize .Range.Rows("1:2")

        .HeaderRowRange.Offset(1).Select

        ' Reset used range on the sheet
        Dim X
        X = .Range.Worksheet.UsedRange.Rows.Count 'see J-Walkenbach tip 73

    End With

End Sub

Einem letzten Schritt I enthalten ist ein Tipp, zugeschrieben John Walkenbach, manchmal notiert als J-Walkenbach tip 73 Automatisches Zurücksetzen Der Letzten Zelle