Stata: Extrahieren von Werten und speichern Sie diese als Skalare (und mehr)

Folgende ist im Grunde die gleiche Strategie gefunden hier und basiert auf Ihrem "Endziel". Wieder kann es nützlich sein, abhängig von der Größe Ihrer original-dataset.joinby erstellt Beobachtungen, so können Sie überschreiten die Stata-Grenze. Allerdings glaube ich, dass es das macht, was Sie wollen.

clear all
set more off

set seed 123456
set obs 10
g firmid = _n   /* Observation (firm) id */
g nw = floor(100*runiform())      /* Number of workers in a firm */
g double lat = 39+runiform()      /* Latitude in decimal degree of a firm */
g double lon = -76+runiform()     /* Longitude in decimal degree of a firm */
gen dum = 1
list

* joinby procedure
tempfile main
save "`main'"

rename (firmid lat lon nw) =0
joinby dum using "`main'"
drop dum

* Pretty print
sort firmid0 firmid
order firmid0 firmid
list, sepby(firmid0)

* Uncomment if you do not want to include workers in the "base" firm.
*drop if firmid0 == firmid

* Compute distance
vincenty lat0 lon0 lat lon, hav(distance_km) inkm
keep if distance_km <= 40 //an arbitrary distance
list, sepby(firmid0)

* Compute workers of nearby-firms
collapse (sum) nw_sum=nw (mean) nw0 lat0 lon0, by(firmid0)
list

Was es tut, ist die form paarweisen Kombinationen der Unternehmen zu berechnen Entfernungen und Summe Arbeitnehmer von in der Nähe-Firmen. Kein Grund hier zum extrahieren von skalaren gefragt, wie in Frage 1. Auch, keine Notwendigkeit zu erschweren, die variable firmid Konvertierung zum string.

Den folgenden überwindet das problem der Stata-Begrenzung der Anzahl der Beobachtungen.

clear all
set more off

* Create empty database
gen x = .
tempfile results
save "`results'", replace

* Create input for exercise
set seed 123456
set obs 500
g firmid = _n   /* Observation (firm) id */
g nw = floor(100*runiform())      /* Number of workers in a firm */
g double lat = 39+runiform()      /* Latitude in decimal degree of a firm */
g double lon = -76+runiform()     /* Longitude in decimal degree of a firm */
gen dum = 1
*list

* Save number of firms
local size = _N
display "`size'"

* joinby procedure
tempfile main
save "`main'"

timer clear 1
timer clear 2
timer clear 3
timer clear 4

quietly {
    timer on 1
    forvalues i=1/`size'{
        timer on 2
        use "`main'" in `i', clear //assumed sorted on firmid
        rename (firmid lat lon nw) =0

        joinby dum using "`main'", unmatched(using)
        drop _merge dum
        order firmid0 firmid
        timer off 2

        timer on 3
        vincenty lat0 lon0 lat lon, hav(dist) inkm
        timer off 3
        keep if dist <= 40 //an arbitrary distance

        timer on 4
        collapse (sum) nw_sum=nw (mean) nw0 lat0 lon0, by(firmid0)

        append using "`results'"
        save "`results'", replace
        timer off 4
    }
    timer off 1
}

use "`results'", clear
sort firmid0
drop x
list

timer list

Jedoch inefficicent, einige Tests mit timer zeigt, dass die meiste Rechenzeit geht in die vincenty Befehl, die Sie nicht in der Lage zu entkommen. Das folgende ist die Zeit (in Sekunden) für 10.000 Beobachtungen mit einem Intel-Core-i5-Prozessor und einer herkömmlichen Festplatte (nicht SSD). Timer 1 ist die Summe während 2, 3, 4 sind die Komponenten (ca.). Timer 3 entspricht vincenty:

. timer list
   1:   1953.99 /       1 =    1953.9940
   2:    169.19 /   10000 =       0.0169
   3:   1669.95 /   10000 =       0.1670
   4:     94.47 /   10000 =       0.0094

Natürlich, beachten Sie, dass in beiden codes doppelte Berechnungen von Distanzen vorgenommen werden (z.B. sowohl die Entfernungen zwischen firm1-firm2 und firm2-firm1 berechnet werden) und diese kann Sie wohl vermeiden. So wie es da steht, für 110,000 Beobachtungen es wird eine lange Zeit dauern. Auf der positiven Seite, ich bemerkte, dass diese zweite Einrichtung die Anforderungen sehr wenig RAM im Vergleich zu der gleichen Menge von Beobachtungen in das erste setup. In der Tat, meine 4GB Rechner friert mit der letzteren.

Beachten Sie auch, dass, obwohl ich den gleichen Samen, wie Sie tun, werden die Daten anders, da ich erstellen eine unterschiedliche Anzahl von Beobachtungen (nicht 5000), das macht einen Unterschied in der Variablen-Erstellung.

(By the way, wenn Sie wollten, um den Wert zu speichern als Skalare könnten Sie subscripting: scalar latitude = lat[1]).