T-SQL-trim &nbsp (und andere nicht-alphanumerische Zeichen)

Wir haben einige input-Daten, die manchmal erscheint mit &nbsp Zeichen am Ende.

Die Daten aus dem Quellsystem als varchar() und unsere versuche, zu wirken, als dezimal-fail-b/c dieser Zeichen.

Ltrim und Rtrim entfernen Sie nicht die Zeichen, wir sind also gezwungen, etwas zu tun:

UPDATE myTable
SET myColumn = replace(myColumn,char(160),'')
WHERE charindex(char(160),myColumn) > 0

Dieser arbeitet für die &nbsp, aber es ist ein guter Weg, um dies zu tun, für alle nicht-alphanumerische (oder in diesem Fall numerische) Zeichen?

InformationsquelleAutor jwolly2 | 2008-09-09
  1. 9

    Auf dieser Seite ist ein Beispiel dafür, wie können Sie entfernen von nicht-alphanumerische Zeichen:

    -- Put something like this into a user function:
DECLARE @cString    VARCHAR(32)
DECLARE @nPos    INTEGER
SELECT  @cString = '90$%45623 *6%}~:@'
SELECT  @nPos = PATINDEX('%[^0-9]%', @cString)

WHILE @nPos > 0
BEGIN
SELECT @cString = STUFF(@cString, @nPos, 1, '')
SELECT  @nPos = PATINDEX('%[^0-9]%', @cString)
END

SELECT @cString
    • dies entfernt alle aber 0-9 (zahlen). .... so ist es nicht wirklich zu tun alpha numberic 😛 ..
    InformationsquelleAutor Espo
  2. 17

    Dies wird entfernen Sie alle nicht alphanumerischen chracters

    CREATE FUNCTION [dbo].[fnRemoveBadCharacter]
(
    @BadString nvarchar(20)
)
RETURNS nvarchar(20)
AS
BEGIN

            DECLARE @nPos INTEGER
            SELECT @nPos = PATINDEX('%[^a-zA-Z0-9_]%', @BadString)

            WHILE @nPos > 0
            BEGIN
                        SELECT @BadString = STUFF(@BadString, @nPos, 1, '')
                        SELECT @nPos = PATINDEX('%[^a-zA-Z0-9_]%', @BadString)
            END

            RETURN @BadString
END

    Verwenden Sie die Funktion wie:

    UPDATE TableToUpdate
SET ColumnToUpdate = dbo.fnRemoveBadCharacter(ColumnToUpdate)
WHERE whatever
    • Das ist besser als die akzeptierte Antwort
    InformationsquelleAutor
  3. 1

    Wie wird die Tabelle gefüllt? Während es möglich ist, zu Peeling diese in sql ein besserer Ansatz wäre die änderung der Spalte Typ int und reiben Sie die Daten, bevor es in die Datenbank geladen (SSIS). Ist das eine option?

    InformationsquelleAutor jason saldo
  4. 0

    Für große Datenmengen habe ich mehr Glück gehabt mit dieser Funktion prüft der ASCII-Wert. Ich habe Möglichkeiten, um nur alpha, numerisch oder alphanumerisch auf der Grundlage der Parameter.

    --CleanType 1 - Remove all non alpanumeric
--          2 - Remove only alpha
--          3 - Remove only numeric
CREATE FUNCTION [dbo].[fnCleanString] (
        @InputString    varchar(8000)
    ,   @CleanType      int 
    ,   @LeaveSpaces    bit 
)   RETURNS varchar(8000)
AS 
BEGIN

    -- //Declare variables
    -- ===========================================================
    DECLARE @Length     int
        ,   @CurLength  int = 1
        ,   @ReturnString varchar(8000)=''

    SELECT @Length = len(@InputString)

    -- //Begin looping through each char checking ASCII value
    -- ===========================================================
    WHILE (@CurLength <= (@Length+1))
    BEGIN
        IF  (ASCII(SUBSTRING(@InputString,@CurLength,1)) between 48 and 57      AND @CleanType in (1,3) )
        or  (ASCII(SUBSTRING(@InputString,@CurLength,1))    between 65 and 90   AND @CleanType in (1,2) )
        or  (ASCII(SUBSTRING(@InputString,@CurLength,1))    between 97 and 122  AND @CleanType in (1,2) )
        or  (ASCII(SUBSTRING(@InputString,@CurLength,1))    = 32    AND @LeaveSpaces = 1 )
        BEGIN
            SET @ReturnString = @ReturnString + SUBSTRING(@InputString,@CurLength,1)
        END
        SET @CurLength = @CurLength + 1
    END

    RETURN  @ReturnString
END
    InformationsquelleAutor BrandonNeiger
  5. 0

    Wenn das Handy konnte beginnen mit einem Pluszeichen(+) verwende ich die Funktion wie folgt

    CREATE FUNCTION [dbo].[Mobile_NoAlpha](@Mobile VARCHAR(1000)) 
RETURNS VARCHAR(1000) 
AS 
BEGIN
    DECLARE @StartsWithPlus BIT = 0

    --check if the mobile starts with a plus(+)
    IF LEFT(@Mobile, 1) = '+'
    BEGIN
        SET @StartsWithPlus = 1

        --Take out the plus before using the regex to eliminate invalid characters
        SET @Mobile = RIGHT(@Mobile, LEN(@Mobile)-1) 
    END

    WHILE PatIndex('%[^0-9]%', @Mobile) > 0 
        SET @Mobile = Stuff(@Mobile, PatIndex('%[^0-9]%', @Mobile), 1, '')  

    IF @StartsWithPlus = 1
        SET @Mobile = '+' + @Mobile
    RETURN @Mobile 
END
    InformationsquelleAutor Tobi Adeyemi
Schreibe einen Kommentar