tcsh-prüfen, ob Datei existiert im angegebenen Pfad

Zunächst, ich bin neu tcsh und ich merke seine Nachteile und warum es schädlich ist (und ich Stimme zu!).

Jedoch ich don ' T haben eine Wahl, und ich bin benötigen, schreiben Sie eine tcsh-Skript, wo der user ein Verzeichnis als input und das script wird überprüfen, ob es die Datei 'test.txt" in der it.

Das untergeordnete Verzeichnis wäre auch technisch gekennzeichnet werden, als es.

Ich gehe davon aus das müssen Rekursion und ich wissen um zu überprüfen, ob eine Datei existiert und ist eine reguläre Datei, die ich verwenden kann

if ( ! -d $1) then
    echo $1 "is not a directory."
    exit 1
endif

if ( -f test.txt ) then    #BUT LINK IT TO $1, as if test.txt exists in 
                           #given user path or its parent directories

     echo "The path includes the file."
else
     echo "The path does NOT include the file."
endif

Ich will, dass es in der Lage sein, es überprüfen $1 (die Benutzereingabe).

InformationsquelleAutor user3295674 | 2015-03-05

  1. 3

    Können Sie eine einfache while Schleife:

    # Expand parameter to full path
set dir = `readlink -f "$1"`

# Not a directory? Stop now
if ( ! -d "$dir" ) then
    echo "$dir is not a directory."
    exit 1
endif

# Loop forever
while (1)
    # Check if $dir has test.txt, if it does, stop the loop
    if ( -f "$dir/test.txt" ) then
        echo "The path $dir includes the file."
        break
    else
        echo "The path $dir does NOT include the file."
        # Dir is /, we've checked all the dirs, stop loop and exit
        if ( "$dir" == "/" ) then
            echo "file not found, stopping"
            exit 2
            break
        endif

        # Remove last part of $dir, we use this value in the next loop iteration
        set dir = `dirname "$dir"`
    endif
end

echo "File found at $dir/test.txt"

    Die Logik sollte klar sein: ändern Sie den Wert der $dir für jede iteration der Schleife, wenn haben wir die Datei gefunden haben, können wir beenden die Schleife, wenn wir haben geloopt, um die / dir, die Datei nicht vorhanden ist und wir aufhören. Sie können natürlich ändern / zu cwd oder etwas anderes...

    Beispiel-Ausgabe:

    [~]% csh checkdir.csh test/asd/asd/asd/asd/
The path /home/martin/test/asd/asd/asd/asd does NOT include the file.
The path /home/martin/test/asd/asd/asd does NOT include the file.
The path /home/martin/test/asd/asd does NOT include the file.
The path /home/martin/test/asd does NOT include the file.
The path /home/martin/test does NOT include the file.
The path /home/martin does NOT include the file.
The path /home does NOT include the file.
The path /does NOT include the file.
file not found, stopping
Exit 2

[~]% touch test/asd/asd/asd/test.txt
[~]% csh checkdir.csh test/asd/asd/asd/asd
The path /home/martin/test/asd/asd/asd/asd does NOT include the file.
The path /home/martin/test/asd/asd/asd includes the file.
File found at /home/martin/test/asd/asd/asd/test.txt

[~]% rm test/asd/asd/asd/test.txt
The path /home/martin/test/asd/asd/asd/asd does NOT include the file.
The path /home/martin/test/asd/asd/asd does NOT include the file.
The path /home/martin/test/asd/asd does NOT include the file.
The path /home/martin/test/asd does NOT include the file.
The path /home/martin/test does NOT include the file.
The path /home/martin includes the file.
File found at /home/martin/test.txt

    InformationsquelleAutor Martin Tournoij

Schreibe einen Kommentar