Trim führende Leerzeichen einschließlich Tabulatoren

Brauche ich zum Lesen von Dateien mithilfe von vbscript und entfernen Sie alle führenden Leerzeichen, einschließlich aller Registerkarten.
Ich habe jetzt LTRIM entfernt die führenden Leerzeichen, aber wie Entferne ich die tabs auch.

Dank.

InformationsquelleAutor | 2009-07-08

  1. 10

    Diese Funktion entfernt alle führenden whitespace-Zeichen (Leerzeichen, tabs etc.) aus einem string:

    Function LTrimEx(str)
  Dim re
  Set re = New RegExp
  re.Pattern = "^\s*"
  re.Multiline = False
  LTrimEx = re.Replace(str, "")
End Function

    InformationsquelleAutor Helen

  2. 9

    Für beide Links und rechts trimmen (einschließlich Tabulatoren, Wagenrücklauf, Zeilenvorschub, Leerzeichen) in einem mehrzeiligen string, das wird funktionieren.

    Function MultilineTrim (Byval TextData)
    Dim textRegExp
    Set textRegExp = new regexp
    textRegExp.Pattern = "\s{0,}(\S{1}[\s,\S]*\S{1})\s{0,}"
    textRegExp.Global = False
    textRegExp.IgnoreCase = True
    textRegExp.Multiline = True

    If textRegExp.Test (TextData) Then
        MultilineTrim = textRegExp.Replace (TextData, "$1")
    Else
        MultilineTrim = ""
    End If
End Function
    Tolle Funktion, danke!

    InformationsquelleAutor

  3. 0

    Andrew ' s Antwort ist nicht korrekt. LTrim, RTrim und Trim entfernt nur Leerzeichen, keine Tabulatoren.

    Ich neu formatiert Ihren code, und es wurde eine Funktion Hinzugefügt, um Streifen führende oder nachfolgende Zeichen.

    filename="test.txt"

set fso = createobject("scripting.filesystemobject")
set f = fso.opentextfile(filename)

do while not f.AtEndOfStream
  s = TrimChars(f.readline, " " + vbTab)
  wscript.echo "|" & s & "|"
loop

f.close

set f = nothing
set fso = nothing

''---

function TrimChars(s, sChars)
  dim n, nLen, nStart

  nLen = Len(s)
  if nLen = 0 then
    TrimChars = s
    exit function
  end if

  ''- skip leading chars
  n = 1
  do while (n <= nLen) And (InStr(sChars, Mid(s, n, 1)) > 0)
    n = n + 1
  loop
  nStart = n

  ''- skip trailing chars
  n = nLen
  do while (n > nStart) And (InStr(sChars, Mid(s, n, 1)) > 0)
    n = n - 1
  loop

  ''- return remaining chars
  nLen = n - nStart + 1
  if (nLen > 0) and (nStart <= len(s)) then
    TrimChars = Mid(s, nStart, nLen)
  else
    TrimChars = ""
  end if
end function

    InformationsquelleAutor Todd

  4. 0
    Function LTrimEx(str)
    Do Until x
        If Left(str, 1) = Chr(32) Or Left(str, 1) = Chr(9) then
            str = Right(str, Len(str) - 1)
        Else
            x = true
        End If
    Loop
    LTrimEx = str
End Function

    InformationsquelleAutor Tester101

Schreibe einen Kommentar