Überprüfen Sie, ob ein Datensatz in einer VB6-Sammlung vorhanden ist.

@Mark Biek Ihre keyExists ehesten entspricht meinem standard Vorhanden ist () - Funktion. Um die Klasse nützlicher für die COM-ausgesetzt Sammlungen und überprüfung von numerischen Indizes, würde ich empfehlen ändern sKey und myCollection nicht eingegeben werden. Wenn die Funktion verwendet wird, mit einer Sammlung von Gegenständen, " set " erforderlich ist (auf der Linie, wo val ist).

BEARBEITEN: Es war nervt mich, ich habe nie bemerkt, die unterschiedliche Anforderungen an eine Objekt-Basis und value-Basis Vorhanden ist () - Funktion. Ich sehr selten verwenden Kollektionen für nicht-Objekte, aber dies schien wie eine perfekte Engpass für einen Fehler, der so schwer auf die Spur, wenn ich benötigt, um zu überprüfen für die Existenz. Da die Fehlerbehandlung schlägt fehl, wenn ein Fehler-handler ist bereits aktiv, zwei Funktionen, die erforderlich sind, um einen neuen Fehler Anwendungsbereich. Nur die Exists () - Funktion muss immer aufgerufen werden:

Public Function Exists(col, index) As Boolean
On Error GoTo ExistsTryNonObject
    Dim o As Object

    Set o = col(index)
    Exists = True
    Exit Function

ExistsTryNonObject:
    Exists = ExistsNonObject(col, index)
End Function

Private Function ExistsNonObject(col, index) As Boolean
On Error GoTo ExistsNonObjectErrorHandler
    Dim v As Variant

    v = col(index)
    ExistsNonObject = True
    Exit Function

ExistsNonObjectErrorHandler:
    ExistsNonObject = False
End Function

Und überprüfen Sie die Funktionalität:

Public Sub TestExists()
    Dim c As New Collection

    Dim b As New Class1

    c.Add "a string", "a"
    c.Add b, "b"

    Debug.Print "a", Exists(c, "a") ' True '
    Debug.Print "b", Exists(c, "b") ' True '
    Debug.Print "c", Exists(c, "c") ' False '
    Debug.Print 1, Exists(c, 1) ' True '
    Debug.Print 2, Exists(c, 2) ' True '
    Debug.Print 3, Exists(c, 3) ' False '
End Sub

InformationsquelleAutor der Antwort Thomas G. Mayfield

Wie bereits von Thomas, die Sie benötigen, um ein Objekt statt Lassen. Hier ist eine Allgemeine Funktion aus meiner Bibliothek, die Werke von Wert und Objekt-Typen:

Public Function Exists(ByVal key As Variant, ByRef col As Collection) As Boolean

'Returns True if item with key exists in collection

On Error Resume Next

Const ERR_OBJECT_TYPE As Long = 438
Dim item As Variant

'Try reach item by key
item = col.item(key)

'If no error occurred, key exists
If Err.Number = 0 Then
    Exists = True

'In cases where error 438 is thrown, it is likely that
'the item does exist, but is an object that cannot be Let
ElseIf Err.Number = ERR_OBJECT_TYPE Then

    'Try reach object by key
    Set item = col.item(key)

    'If an object was found, the key exists
    If Not item Is Nothing Then
        Exists = True
    End If

End If

Err.Clear

End Function

Als auch beraten von Thomas, Sie können ändern Sie den Collection-Typ zu Objekt zu verallgemeinern. Die .Item(key) syntax ist, teilen die meisten collection-Klassen, also das könnte tatsächlich nützlich sein.

BEARBEITEN Scheint, wie ich geschlagen wurde, um den Schlag etwas von Thomas selbst. Aber für die einfachere Wiederverwendung, die ich persönlich bevorzuge eine einzelne Funktion ohne private Abhängigkeiten.

InformationsquelleAutor der Antwort jevakallio

Die Anweisung "error handling schlägt fehl, wenn ein Fehler-handler ist bereits aktiv" ist nur zum Teil richtig.

Können Sie mehrere error-Handler in Ihre routine.

So könnte man Platz für die gleiche Funktionalität in nur einer Funktion.

Einfach ändern Sie Ihren code wie folgt:

Public Function Exists(col, index) As Boolean
Dim v As Variant

TryObject:
    On Error GoTo ExistsTryObject
        Set v = col(index)
        Exists = True
        Exit Function

TryNonObject:
    On Error GoTo ExistsTryNonObject

        v = col(index)
        Exists = True
        Exit Function

ExistsTryObject:
   ' This will reset your Err Handler
   Resume TryNonObject

ExistsTryNonObject:
        Exists = False
End Function

Jedoch, wenn Sie nur integrieren Sie den code in der TryNonObject Abschnitt der routine, würde dies ergeben die gleichen Informationen.

Wird es gelingen, für beide Objekte und nicht-Objekte.
Es wird die Geschwindigkeit Ihres code für nicht-Objekte, da Sie nur zur Ausführung einer einzelnen Anweisung zu behaupten, dass das Element vorhanden in der Sammlung.

InformationsquelleAutor der Antwort R. van Drie

sehen
http://www.visualbasic.happycodings.com/Other/code10.html
die Umsetzung hat dabei den Vorteil, dass auch Optional Rückgabe des gefundenen Elements, und arbeitet mit dem Objekt/native Typen (nach den Kommentaren).

hier wiedergegeben, da der link nicht mehr verfügbar:

Bestimmen, ob ein Element existiert in einer Sammlung

Folgende code zeigt, wie Sie ermitteln, ob ein Element existiert in einer Sammlung.

Option Explicit

'Purpose     :  Determines if an item already exists in a collection
'Inputs      :  oCollection         The collection to test for the existance of the item
'               vIndex              The index of the item.
'               [vItem]             See Outputs
'Outputs     :  Returns True if the item already exists in the collection.
'               [vItem] The value of the item, if it exists, else returns "empty".
'Notes       :
'Example     :

Function CollectionItemExists(vIndex As Variant, oCollection As Collection, Optional vItem As Variant) As Boolean
    On Error GoTo ErrNotExist

    'Clear output result
    If IsObject(vItem) Then
        Set vItem = Nothing
    Else
        vItem = Empty
    End If

    If VarType(vIndex) = vbString Then
        'Test if item exists
        If VarType(oCollection.Item(CStr(vIndex))) = vbObject Then
            'Return an object
            Set vItem = oCollection.Item(CStr(vIndex))
        Else
            'Return an standard variable
            vItem = oCollection.Item(CStr(vIndex))
        End If
    Else
        'Test if item exists
        If VarType(oCollection.Item(Int(vIndex))) = vbObject Then
            'Return an object
            Set vItem = oCollection.Item(Int(vIndex))
        Else
            'Return an standard variable
            vItem = oCollection.Item(Int(vIndex))
        End If
    End If
    'Return success
    CollectionItemExists = True
    Exit Function
ErrNotExist:
    CollectionItemExists = False
    On Error GoTo 0
End Function

'Demonstration routine
Sub Test()
    Dim oColl As New Collection, oValue As Variant

    oColl.Add "red1", "KEYA"
    oColl.Add "red2", "KEYB"
    'Return the two items in the collection
    Debug.Print CollectionItemExists("KEYA", oColl, oValue)
    Debug.Print "Returned: " & oValue
    Debug.Print "-----------"
    Debug.Print CollectionItemExists(2, oColl, oValue)
    Debug.Print "Returned: " & oValue
    'Should fail
    Debug.Print CollectionItemExists("KEYC", oColl, oValue)
    Debug.Print "Returned: " & oValue
    Set oColl = Nothing
End Sub

• Sehen Sie mehr an: https://web.archive.org/web/20140723190623/http://visualbasic.happycodings.com/other/code10.html#sthash.MlGE42VM.dpuf

InformationsquelleAutor der Antwort Vijay