Überprüfen Sie, ob image-Datei existiert, Robot-Framework, Selenium2Library

Ich würde gerne wissen, ob es möglich ist und wie, um zu überprüfen, ob ein element, die angezeigt werden sollen, ein Bild, nicht wirklich zeigen das Bild.

Sich das Bild in <img src=..> und innerhalb der gleichen Domäne.

InformationsquelleAutor Qwerty | 2014-07-02
  1. 5

    Es ist nicht ganz klar, was Ihre Ziele sind. Ich denke, es ist sicher anzunehmen, dass, wenn Ihr code macht alles richtig (sprich: die URL korrekt ist, und die css-Regeln nicht dazu, dass das element ausgeblendet werden), die der browser wird tun, was es tun soll und das Bild zeigen. Natürlich, wenn Sie auf dem Test-team, das ist eigentlich die Prüfung der browser selbst, das ist ein anderes problem.

    So, vorausgesetzt, dass der browser verhält sich korrekt, hier sind ein paar Vorschläge:

    1. Können Sie die Seite sollte enthalten Bild - Attribut, um zu überprüfen, wird das element in den DOM.

    2. Können Sie die Bekommen Element-Attribut Schlüsselwort, um den Wert der src Attribut, und verwenden Sie dann die Erhalten Schlüsselwort der Anfragen Bibliothek, um zu überprüfen, dass die url gibt einen 200-status-code.

    3. Können Sie die Element sichtbar sein soll Schlüsselwort, um zu überprüfen, dass die css-Regeln erlauben, dass das element angezeigt werden soll.

    Hier ein komplettes Beispiel:

    *** Settings ***
| Library | Selenium2Library
| Library | RequestsLibrary

*** Variables ***
| ${TEST_PAGE} | http://the-internet.herokuapp.com/hovers
| ${BROWSER}   | chrome

*** Keywords ***
| Assert an image is visible
| | [Arguments] | ${element id}
| | [Documentation]
| | ... | This keyword fails if the given image element is not visible.
| | ... | Three checks are performed: that the element is on the page,
| | ... | that selenium thinks the element is visible, and that the 
| | ... | src attribute of the image points to a resource that is 
| | ... | accessible. 
| | 
| | # Step 1: verify the page contains the given element
| | Page should contain image | ${element id}
| | 
| | # Step 2: verify that the element is visible
| | Element should be visible | ${element id}
| | 
| | # Step 3: verify the src attribute of the image is accessible
| | ${img src}= | Get element attribute | ${element id}@src
| | Create session | img-src | ${img src}
| | ${response} | Get | img-src | /| # URL is relative to the session URL
| | Should be equal as integers | ${response.status_code} | 200
| | ... | image url '${img src}' returned unexpected status code '${response.status_code}'
| | ... | show_values=False

*** Test Cases ***
| Example of test to verify an image is visible
| | [Documentation]
| | ... | Verify that the first image on the test page is visible
| | 
| | [Setup] | Open browser | ${TEST_PAGE} | ${BROWSER}
| | Assert an image is visible | //div[@class='figure']/img
| | [Teardown] | Close All Browsers
    • Das ist großartig! Aber wie genau funktioniert das ${variable.something} Arbeit? Außerdem, warum verwenden Sie | in Ihrem code, während ich Verwendung nur Leerzeichen? Es ist nicht das erste mal, dass ich dies sah.
    • Ich verwende pipes anstelle von Leerzeichen, weil ich denke, es macht die tests mehr klar. Es kann schwer sein, den Unterschied zu sehen zwischen einem Raum oder zwei, oder zwischen einem Register und einem Speicherplatz in einigen Fällen. Die ${variable.something} wird als erweiterte variable syntax. Es behandelt variable wie ein Objekt, und something ist ein Attribut auf das Objekt. Dies ist dokumentiert in der Bedienungsanleitung.
    • Gibt es irgendein Nachteil, der nicht ausgeführt wird dieser Schritt Should be equal as integers
    • der einzige Nachteil ist, dass, wenn die Antwort nicht 200 (zB: 404), der test könnte denken, dass das Bild sichtbar ist (weil das DOM-element auf der Seite), wenn das eigentliche Bild nicht (weil die URL falsch ist)
    • Danke für die Erklärung.
    InformationsquelleAutor Bryan Oakley
  2. 1

    Neben dem element sichtbar, Aspekt, können Sie auch überprüfen per javascript, das das image-element ist eigentlich vom browser angezeigt werden und nicht einige fehlende Bild-Symbol angezeigt wird. Sie entweder führen Sie die javascript mit Selenium2Library oder wickeln, die Selenium2Library javascript-Schlüsselwort call-in einem benutzerdefinierten Schlüsselwort, um Sie lesbarer zu machen.

    http://watirmelon.com/2012/11/27/checking-an-image-is-actually-visible-using-webdriver/

    InformationsquelleAutor David
  3. 0

    Soweit ich weiß, gibt es keine Robot Framework-Bibliothek, die testen möchten, dass ein Bild tatsächlich angezeigt. Es gibt ein paar Optionen:

    1. Blick in die Integration von Sikuli mit Robot Framework. Es gibt einige guides gibt, die Sie Schritt für Schritt, obwohl die integration. Sobald Sie haben Sikuli arbeiten mit Robot Framework, nehmen Sie einen screenshot von Ihrem Bild und vergleichen Sie es um die Basis-screenshot. Ich denke, dies ist Ihre beste option.

    2. Gibt es andere tools, die das visuelle Bild-Vergleich. Zum Beispiel, Nadel ist in Python geschrieben, so dass, wenn Sie haben einige Python-Fähigkeiten, die Sie schreiben, könnte eine Bibliothek rund um Nadel Funktionalität.

    InformationsquelleAutor finspin
Schreibe einen Kommentar