Um einen Parameter im AS3 an den Ereignis-Listener zu übergeben, ist der einfache Weg ... vorhanden?

Erwartet /pseudo Beispiel:

stage.addEventListener(MouseEvent.CLICK, onClick.someWayToPassParameters(true, 123, 4.56, "string"));
function onClick(e:MouseEvent):void {
    trace("Received " + someWayToRetrieveParameters().b/i/n/s + ".");
}

Seit vielen Jahren (3~4), auf jeder website, forum, blog, wo immer ich suchte, die Leute sagen mir es gibt keinen einfachen Weg, dies zu tun. Sie in der Regel vorschlagen:

Fügen Sie den Zuhörer zu einem dynamischen Objekt, wo Sie den Wert festlegen, um eine zusätzliche Eigenschaft und Verweis (e.Ziel.Grundstück /e zu.currentTarget.Eigentum) in die Funktion.

Nicht alle Klassen sind dynamisch. Es wird nicht funktionieren, auf ein Sprite, zum Beispiel.
Erweitern Sie die Klasse des Objekts mit einer benutzerdefinierten Klasse, die Eigenschaft hinzufügen oder einfach nur machen es dynamisch.

Müssen Sie erstellen eine ganz neue tweak class everytime.
Verwenden Sie eine anonyme Funktion als event-handler.

Gibt es keine Referenz (und es ist hässlich). Um den listener entfernen, um Ressourcen freizugeben, die Sie gezwungen sind, es zu tun, von innerhalb der Funktion selbst mit Argumenten.angerufene.
Eine andere Funktion aufrufen, die Verwendung der parameter innerhalb der event-handler.

Ist und wo der event-handler-Aufruf führt der parameter gehen?
Halten Sie die event-handler im gleichen Bereich wie die parameter.

Verletzung zu einem totalen semantischen Chaos.
Kapseln beide event-handler-definition, und Sie addEventListener () - Aufruf in einer Funktion empfängt die Ziel-und Kenngrößen.

Kann es-mix-Bereiche, aber es ist eng. Sie müssen vorsichtig sein, obwohl.

...Unter vielen anderen vorgeschlagenen workarounds.

Alles was ich will ist nur zu pass ein argument zu den event-handler, so dass ich es verwenden kann in seiner Funktion, genau wie eine normale Funktion!

Bin ich zu viel verlangt?

InformationsquelleAutor der Frage user985358 | 2012-11-21

Out of the box: es dauert nur 2 zusätzliche Zeilen eleganten Codes zur Lösung dieses alten Rätsels.

stage.addEventListener(MouseEvent.CLICK, onClick(true, 123, 4.56, "string"));
function onClick(b:Boolean, i:int, n:Number, s:String):Function {
  return function(e:MouseEvent):void {
    trace("Received " + b + ", " + i + ", " + n + " and " + s + ".");
  };
}

Aber am wichtigsten ist, werden Sie sehr wahrscheinlich benötigen, um den listener entfernen später, um Ressourcen freizugeben, so +1 Zeile, um es zu speichern in eine variable:

var functionOnClick:Function = onClick(true, 123, 4.56, "string");
stage.addEventListener(MouseEvent.CLICK, functionOnClick);
function onClick(b:Boolean, i:int, n:Number, s:String):Function {
  return function(e:MouseEvent):void {
    trace("Received " + b + ", " + i + ", " + n + " and " + s + ".");
  };
}

Und Sie werden in der Lage sein, um es zu entfernen in der Regel:

trace("Before: " + stage.hasEventListener(MouseEvent.CLICK));
stage.removeEventListener(MouseEvent.CLICK, functionOnClick);
trace("After: " + stage.hasEventListener(MouseEvent.CLICK));

Hier ist eine mehr ausgearbeitete, dynamische Beispiel zu beweisen:

function onClick(s:String):Function {
  return function(e:MouseEvent):void {
    trace("The square " + s + " at x = " + e.currentTarget.x + "px was clicked");
  };
}
var myFunctions:Array = new Array();
for (var i:int = 0; i < 10; i++) {
  myFunctions.push(onClick("#" + (i+1)));
}
for (i = 0; i < myFunctions.length; i++) {
  var square:Sprite = new Sprite();
  square.name = "sqr" + i;
  square.addChild(new Bitmap(new BitmapData(20, 20, false, 0)));
  square.x = 5 + 25 * i;
  square.addEventListener(MouseEvent.CLICK, myFunctions[i]);
  stage.addChild(square);
}

Keine Eigenschaften durch dynamische Objekte, die keine eigene Klasse, keine losen Funktionen, kein Bereich überlappen. Nur, was Logik erwartet: Sie sind einfach Argumente übergeben.

Und entfernen Sie alle listener richtig, Sie können es tun, wie dies später:

for (i = 0; i < myFunctions.length; i++) {
  square = stage.getChildByName("sqr" + i) as Sprite;
  trace("Before (#" + (i+1) + "): " + square.hasEventListener(MouseEvent.CLICK));
  square.removeEventListener(MouseEvent.CLICK, myFunctions[i]);
  trace("After (#" + (i+1) + "): " + square.hasEventListener(MouseEvent.CLICK));
  stage.removeChild(square);
}

IMHO ist dies die einfachste, aber auch solideste Weg, es zu tun.

InformationsquelleAutor der Antwort

hier ist ein Beispiel

var s1:Boolean = true;

station1.addEventListener(MouseEvent.ROLL_OVER, function(e:MouseEvent) : void { spread(e, s1) });
station1.addEventListener(MouseEvent.ROLL_OUT, function(e:MouseEvent) : void { collapse(e, s1) });


function spread(event:MouseEvent ,bb:Boolean):void {
 if(bb != true) event.currentTarget.gotoAndPlay(2);
}

function collapse(event:MouseEvent,bb:Boolean ):void {
    if(bb != true) event.currentTarget.gotoAndPlay(18);
}

InformationsquelleAutor der Antwort xbraim

Einen parameter übergeben direkt an den event-handler ist nicht möglich.

Die beste Näherung wird durch eine Funktion verwenden, die factory-Methode, IMO

//--EDITIERT:
Ich erstellte eine separate Klasse zu halten parametrisierte Prozeduren finden Sie unter https://gist.github.com/4124722

Nutzung ist einfach:

    public class Usage extends Sprite{

        private var _handlers : ParameterizedHandlerContainer;

        public function ParameterizedEvents()
        {

            _handlers = new ParameterizedHandlerContainer();
            _handlers.registerHandler( this, Event.ADDED_TO_STAGE, someMethod, 3000 );
        }

        private function someMethod( event : Event, amount : uint ):void
        {
            trace( this, 'someMethod', amount );
            _handlers.destroyHandler( arguments.callee, event );
        }


    }

Jetzt können Sie sich registrieren parametrisierten Prozeduren mit ParameterizedHandlerContainer#registerHandler und zerstören Sie Sie mit ParameterizedHandlerContainer#destroyHandler.

Können Sie jede Menge Parameter, die Sie wollen, aber der erste parameter der callback-Methode muss vom Typ Ereignis oder ein Nachkomme.

InformationsquelleAutor der Antwort Creynders

Ich ändern würde, Creynders Beispiel leicht:

    protected function createHandler(handler:Function, ...args):Function
    {
        var h:Function = function(e:Event = null):void
        {
            trace(args);

            if (handler != null)
                handler(e);
        }
        return h;
    }

    sm.addEventListener(StyleEvent.STYLE_CHANGE, 
            createHandler(updateStyle, 1,true,"Lorem",["a","b","c"]), 
            false, 0, true);

diesem Weg können Sie original-event-Handler und injizieren Sie die "Argumente",

auch Sie könnte Ihren Handler, um haben folgende Signatur:

protected function myHandler(e:Event, ...args):void;

dann könnte man Argumente übergeben, die direkt auf das Ziel-hf:

    protected function createHandler(handler:Function, ...args):Function
    {
        var h:Function = function(e:Event = null):void
        {
            //trace(args);

            if (handler != null)
            {
                args.unshift(e);
                handler.apply(this, args);
            }
        }
        return h;
    }

beste Grüße

InformationsquelleAutor der Antwort Lukasz 'Severiaan' Grela

Warum nicht AS3-Signale? Ein parameter übergeben wird, dann ist so einfach wie:

import org.osflash.signals.Signal;

public class AlarmClock 
{
    public var alarm:Signal;

    public function AlarmClock() 
    {
        alarm = new Signal(String);
    }

    public function ring():void
    {
        alarm.dispatch("9 AM");
    }
}

InformationsquelleAutor der Antwort Varnius

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.