VBA - Get Ausgewählten Wert einer Combobox

Wenn Sie Umgang mit Daten Validierung von Listen, können Sie mit dem Worksheet_Change-Ereignis. Klicken Sie rechts auf das Blatt mit der Datenüberprüfung und wählen Sie " Code Anzeigen. Geben Sie dann in diesem:

Private Sub Worksheet_Change(ByVal Target As Range)

    MsgBox Target.Value

End Sub

Wenn Sie den Umgang mit ActiveX-comboboxes, es ist ein wenig komplizierter. Müssen Sie erstellen eine benutzerdefinierte Klasse Modul, um hook up die Ereignisse. Zunächst erstellen Sie ein Klassenmodul mit dem Namen CComboEvent und fügen Sie diesen code in es.

Public WithEvents Cbx As MSForms.ComboBox

Private Sub Cbx_Change()

    MsgBox Cbx.Value

End Sub

Als Nächstes erstellen Sie einen anderen Klassenmodul mit dem Namen CComboEvents. Diese halten alle unsere CComboEvent Instanzen und halten Sie Sie in Rahmen. Fügen Sie diesen code in CComboEvents.

Private mcolComboEvents As Collection

Private Sub Class_Initialize()
    Set mcolComboEvents = New Collection
End Sub

Private Sub Class_Terminate()
    Set mcolComboEvents = Nothing
End Sub

Public Sub Add(clsComboEvent As CComboEvent)

    mcolComboEvents.Add clsComboEvent, clsComboEvent.Cbx.Name

End Sub

Schließlich erstellen Sie eine standard-Modul (kein Klassenmodul). Sie benötigen code, um alle deine comboboxes in der Klasse Module. Sie könnten dies in eine Auto_Open-Prozedur, so es geschieht, wenn die Arbeitsmappe geöffnet wird, aber das ist bis zu Ihnen.

Brauchst du eine Public-variable für eine Instanz von CComboEvents. Öffentlich zu machen, wird kepp es, und alle seine Kinder in scope. Sie müssen Sie im Umfang so, dass die Ereignisse ausgelöst werden. In der Prozedur, die in einer Schleife durch alle comboboxes, die Schaffung einer neuen CComboEvent-Instanz für jeden, und hinzufügen, dass zu CComboEvents.

Public gclsComboEvents As CComboEvents

Public Sub AddCombox()

    Dim oleo As OLEObject
    Dim clsComboEvent As CComboEvent

    Set gclsComboEvents = New CComboEvents

    For Each oleo In Sheet1.OLEObjects
        If TypeName(oleo.Object) = "ComboBox" Then
            Set clsComboEvent = New CComboEvent
            Set clsComboEvent.Cbx = oleo.Object
            gclsComboEvents.Add clsComboEvent
        End If
    Next oleo

End Sub

Nun, wenn eine combobox geändert wird, wird das Ereignis ausgelöst wird und in diesem Beispiel, wird eine Meldung zeigen.

Sehen Sie ein Beispiel, bei https://www.dropbox.com/s/sfj4kyzolfy03qe/ComboboxEvents.xlsm

Vielleicht sind Sie in der Lage, um die Ereignishandler programmgesteuert, mit so etwas wie (pseudocode)

sub myhandler(eventsource)
  process(eventsource.value)
end sub

for each cell
  cell.setEventHandler(myHandler)

Aber ich weiß nicht, die syntax für die Verwirklichung dieses in VB/VBA, oder, wenn überhaupt möglich ist.