VBA MSFORMS vs Steuerelemente - was ist der Unterschied

Hinzufügen UserForm ersten. Dann in VBA-IDE durch drücken von F2, die Objekt-browser erscheint. In der linken oberen Ecke ist das Kombinationsfeld, wählen Sie MSForms. In der Klassen-Liste können Sie sehen, die Klassen, das gehört zu MSForms Bibliothek-Objekt.

Können Sie sehen, CommandButton und Kontrolle in dieser Liste:

Deklarieren Sie eine variable des Typs CommandButton in deinem code:

Dim button1 As MSForms.CommandButton
Dim button2 As CommandButton

Den Variablen button1 ist vom Typ CommandButton MSForms sicher. Die button2 könnte Ihre eigene Klasse definiert, die in Ihrem lokalen VBA-Projekt ... aber wenn Sie Ihre lokale VBA-Projekt enthält keine Klasse mit diesem Namen wird es als MSForms als gut. Allerdings wenn Sie auf ein anderes Objekt Bibliothek sagen 'MSFoo' enthalten wird Klasse CommandButton-wie gut müssen Sie erklären Ihnen vollständig qualifizierten wie diese:

Dim button1 As MSForms.CommandButton
Dim button2 As MSFoo.CommandButton

Deklarieren Sie eine variable vom Typ Control im code:

Dim controlObject As MSForms.Control

Variable vom Typ Control wie eine Art Basisklasse für Steuerelemente. E. g. zu enumarate Controls-Auflistung:

For Each controlObject In Me.Controls
    Debug.Print VBA.TypeName(controlObject)
Next controlObject

Oder als parameter in der Funktion, die erwartet nicht nur eine Art der Steuerung:

Private Sub PrinControlName(ByRef c As MSForms.Control)
    Debug.Print c.Name
End Sub

So vollständig qualifizierten Namen wie MSForms.CommandButton ist im Allgemeinen die richtigen denke ich. Verwendung Zu Steuern.CommandButton ist falsch und wird nicht kompiliert, bis Sie einige Referenz-Objekt-Bibliothek mit dem Namen 'Steuern' mit der Klasse CommandButton.

EDIT:

Hier ein Beispiel von lokal erstellte Klasse mit dem gleichen Namen wie MSForm.Befehlsschaltfläche:

Und wie TypeName und TypeOf Arbeit in diesem Fall:

Option Explicit

Private m_buttonMsForms As MSForms.CommandButton
Private m_buttonLocal As CommandButton

Private Sub UserForm_Initialize()
    Set m_buttonMsForms = Me.Controls.Add( _
        "Forms.CommandButton.1", "testMsButton", True)
    Set m_buttonLocal = New CommandButton

    m_buttonLocal.Name = "testLocalButton"

    Debug.Print "We have two instances of two different button types: " & _
        m_buttonLocal.Name & " and " & m_buttonMsForms.Name

    ' Check instances with TypeName function
    ' TypeName function returns same results
    If VBA.TypeName(m_buttonMsForms) = VBA.TypeName(m_buttonLocal) Then
        Debug.Print "TypeName of both buton types returns same result"
    End If

    ' Check instances with TypeOf operator
    ' TypeOf doen't work with not initialised objects
    If m_buttonLocal Is Nothing Or m_buttonMsForms Is Nothing Then _
        Exit Sub

    ' TypeOf operator can distinguish between
    ' localy declared CommandButton type and MSForms CommandButton
    If TypeOf m_buttonLocal Is MSForms.CommandButton Then _
        Debug.Print "m_buttonLocal Is MSForms.CommandButton"

    If TypeOf m_buttonMsForms Is CommandButton Then _
        Debug.Print "m_buttonMsForms Is CommandButton"

    If TypeOf m_buttonLocal Is CommandButton Then _
        Debug.Print "m_buttonLocal Is CommandButton"

    If TypeOf m_buttonMsForms Is MSForms.CommandButton Then _
        Debug.Print "m_buttonMsForms Is MSForms.CommandButton"

End Sub

Ausgabe:

We have two instances of two different button types: testLocalButton and testMsButton
TypeName of both buton types returns same result
m_buttonLocal Is CommandButton
m_buttonMsForms Is MSForms.CommandButton

InformationsquelleAutor dee