VBA-SVERWEIS über mehrere Blätter hinweg

Also ich habe zwei Listen, die jeweils in einem anderen Blatt. Ich bin der überprüfung, dass die Werte in Blatt B sind auch in Blatt A. ich bin mit SVERWEIS für diese, das problem scheint mit dem Bereich Aussagen, wie dieser Bereich erscheint 'leer'.

Meinen VBA-versuchen, so etwas wie, 

Dim lookupVal As String
Dim myString As String

For i = 1 to N
    lookupVal = Sheets("b").Cells(1 + i, 2)
    myString = Application.WorksheetFunction.VLookup(lookupVal, Sheets("a").range(Sheets("a").Cells(9,3), Sheets("a").Cells(N+8, 3)), 1, False)
    If IsEmpty(myString) Then
        Sheets("b").Cells(1+i, 3) = ""
    Else
        Sheets("b").Cells(1+i, 3) = myString
    End if

Next i

Bekomme ich die Meldung 'Run-time-1004: Application-defined or object-defined error'. Jede Hilfe zu schätzen.

InformationsquelleAutor user2655377 | 2015-05-26
  1. 1

    Gibt es zwei Probleme in deinem code:

    1. für worksheetfunction.vlookup des Suchbereichs nicht flüchtig.
      Also der Weg, um dieses Problem zu lösen, ist die Verwendung zusätzlicher Variablen zu tun es permanent

    2. wenn worksheetfunction.vlookup nicht finden, die Suche Wert, dann wird die Fehlermeldung angezeigt, in diesem Fall müssen Sie zusätzliche manipulation mit Fehlerbehandlung

    3. lookupVal deklariert werden müssen as Range durch formatieren der Zellen (lookup-Bereich und lookup-Wert) kann unterschiedlich sein, aber in deinem code die Zellen Wert wird immer umgewandelt in string-Typ, und Sie werden nicht in der Lage zu finden, die zahlen, wenn Sie konvertiert in string -

    4. myString auch erforderlich deklariert werden as Variant aufgrund der gleichen Grund, wie unter "3." Geben Sie der Zelle double zum Beispiel, aber dein code konvertiert es in string

    damit, Ihre aktualisierte code unten funktioniert einwandfrei

    Sub test()
Dim lookupVal As Range, myString As Variant, Rng$, n&
n = Sheets("b").[B:B].Cells.Find("*", , , , xlByRows, xlPrevious).Row
On Error Resume Next
For i = 1 To n
    Set lookupVal = Sheets("b").Cells(1 + i, 2)
    Rng = Range(Cells(9, 3), Cells(n + 8, 3)).Address
    myString = WorksheetFunction.VLookup(lookupVal, Sheets("a").Range(Rng), 1, False)
    If Err.Number > 0 Then
        Sheets("b").Cells(1 + i, 3) = ""
        Err.Clear
    Else
        Sheets("b").Cells(1 + i, 3) = myString
    End If
Next i
End Sub

    alternative Art und Weise unter

    Sub test()
Dim cl As Range, Dic As Object
Set Dic = CreateObject("Scripting.Dictionary"): Dic.Comparemode = vbTextCompare
With Sheets("a")
    For Each cl In .Range("C9:C" & .Cells(Rows.Count, "C").End(xlUp).Row)
        If Not Dic.exists(cl.Value) Then Dic.Add cl.Value, cl.Row
    Next cl
End With
With Sheets("b")
    For Each cl In .Range("B2:B" & .Cells(Rows.Count, "B").End(xlUp).Row)
        If Dic.exists(cl.Value) Then cl.Offset(, 1).Value = cl.Value
    Next cl
End With
Set Dic = Nothing
End Sub
    InformationsquelleAutor Vasily Ivoyzha
  2. 1

    Ändern Sie den code der unten.

    If IsEmpty(myString) ist der falsche Weg, es zu tun. Im Falle von #N/A, dass die Aussage immer noch wahr sein.

    Ist es das, was Sie versuchen?

    Sub Sample()
    Dim lookupVal As String
    Dim myString As Variant
    Dim rng As Range

    '~~> Change this whatever you want
    n = 5

    For i = 1 To n
        lookupVal = Sheets("b").Cells(1 + i, 2)

        Set rng = Sheets("a").Range(Sheets("a").Cells(9, 3), Sheets("a").Cells(n + 8, 3))

        myString = Application.Evaluate("=VLOOKUP(" & lookupVal & "," & "a!" & rng.Address & ",1,0)")

        Select Case CVErr(myString)
            Case CVErr(xlErrName), CVErr(xlErrNA), CVErr(xlErrRef), CVErr(xlErrValue)
            Case Else: Sheets("b").Cells(1 + i, 3) = myString
        End Select
    Next i
End Sub
    InformationsquelleAutor Siddharth Rout
Schreibe einen Kommentar