VBScript zum konvertieren von XML in CSV

Ich habe ein VBScript, wandelt XML-Datei in einem Ordner in XLS und löscht dann die XML-Dateien - alle funktioniert.

Jedoch, ich wissen müssen, konvertieren Sie die XML-Dateien in CSV statt XLS.

Was muss ich ändern im script um dies zu ermöglichen? Einfach das ändern der Endung der Ausgabedatei(en) offensichtlich nicht funktioniert.

Dim xlApp, xlWkb, SourceFolder,TargetFolder,file
Set xlApp = CreateObject("excel.application")
Set fs = CreateObject("Scripting.FileSystemObject")

Const xlNormal=1

SourceFolder="c:\xml-to-xls\xml"
TargetFolder="c:\xml-to-xls\xls"

xlApp.Visible = false

for each file in fs.GetFolder(SourceFolder).files
  Set xlWkb = xlApp.Workbooks.Open(file)
  BaseName= fs.getbasename(file)
  FullTargetPath=TargetFolder & "\" & BaseName & ".xls"
  xlWkb.SaveAs FullTargetPath, xlNormal
  xlWkb.close
next

fs.DeleteFile("C:\xml-to-xls\xml\*.xml")

Set xlWkb = Nothing
Set xlApp = Nothing
Set fs = Nothing

Dank

  • Ich habe entfernt alle Kommentare aus dem code. Es ist absolut unnötigen Kommentar wie dieser: xlWkb.close ' close workbook - der code schon sagt, dass. Sie sind im wesentlichen schreiben Sie Ihr Programm zweimal - das ist Unsinn. Tun Sie das nicht.
InformationsquelleAutor chenks | 2013-10-29
  1. 2

    Aktualisierung gemäß den Kommentaren: Danke Jungs

    Const xlCSV = 6
xlWkb.SaveAs FullTargetPath, xlCSV, , , , , , 2
xlWbk.Saved = True
xlWkb.close
    • xlCSV ist nicht verfügbar, wird als name in VBScript, die Sie würde tun müssen, um eine Const xlCSV = 6 vorher.
    • setzen Sie dieses Recht vor dem SaveAs-Zeile ?
    • Ich würde es nach der anderen Const definition.
    • give it a try und sehen, was die Ergebnisse sind
    • Nein, das scheint nicht zu funktionieren, wie es sollte. es wird eine Aufforderung für jede Datei, wenn ich die änderungen speichern möchten, um eine CSV-Datei, die verlangt von mir, klicken Sie auf JA, bevor es abgeschlossen ist. Auch, wenn ich auf JA klicken, wird die resultierende Datei ist nicht das gleiche wie wenn ich manuell speichern Sie die XLS-Datei (mit den origin-vbscript) als CSV-Datei.
    • Geben Sie die ConflictResolution argument (xlWkb.SaveAs FullTargetPath, xlCSV, , , , , , 2. Und wie genau die Ergebnisse sich unterscheiden? CSV ist ein anderes format, dass unterstützt nicht alle Funktionen, XLS(X) liefert.
    • ich meinte, dass einfach, die Datei mit einer CSV-Erweiterung nicht automatisch in eine CSV-Datei, die ist, was das Skript war im wesentlichen zu tun.
    • OK, haben die ConflictResolution als argument erwähnt und diese speichert nun die XML-Dateien zu CSVs. 1 Fragen, obwohl, ich bekomme eine Eingabeaufforderung speichern für jede Datei gefragt, ob ich die änderungen speichern möchten. ich brauche diese, um eine ruhige Prozess, der erfordert keine manuelle Interaktion des Benutzers.
    • Fügen Sie eine Zeile xlWbk.Saved = True bevor Sie die Arbeitsmappe schließen.
    • Wiechers ausgezeichnet ist, dass ein Werk behandeln
    • eine Letzte Frage, was brauche ich, um hinzuzufügen, so dass, wenn es keine Dateien, die sich gegenwärtig in den XML-Ordner, dann wird das Skript beendet mit Fehler. im moment gibt es keine Dateien zu konvertieren, dann erzeugt es eine "Datei nicht gefunden" Fehlermeldung prompt
    • Das ist wahrscheinlich verursacht durch die Linie fs.DeleteFile("C:\xml-to-xls\xml\*.xml"). Um dies zu vermeiden, verschieben Sie die Löschung innerhalb der Schleife und löschen Sie jede Datei, nachdem es verarbeitet wurde (file.Delete).
    • ja, der hat das Kunststück fertig

    InformationsquelleAutor ServerGuy
  2. 2

    danke Jungs... hier ist das fertige Skript

    Dim xlApp, xlWkb, SourceFolder,TargetFolder,file
Set xlApp = CreateObject("excel.application")
Set fs = CreateObject("Scripting.FileSystemObject")

Const xlNormal=1
Const xlCSV=6

SourceFolder="c:\xml-to-xls\xml"
TargetFolder="c:\xml-to-xls\xls"

xlApp.Visible = false

for each file in fs.GetFolder(SourceFolder).files
  Set xlWkb = xlApp.Workbooks.Open(file)
  BaseName= fs.getbasename(file)
  FullTargetPath=TargetFolder & "\" & BaseName & ".csv"
  xlWkb.SaveAs FullTargetPath, xlCSV, , , , , , 2
  xlWkb.Saved = True
  xlWkb.close
  file.Delete
next

Set xlWkb = Nothing
Set xlApp = Nothing
Set fs = Nothing
    InformationsquelleAutor chenks
Schreibe einen Kommentar