Vergleichen Sie Dateien mit awk

Hallo ich habe zwei ähnliche Dateien (mit 3 Spalten). Ich möchte, um zu überprüfen, ob diese beiden Dateien enthält die gleichen Elemente (aber aufgeführt in einer anderen Bestellungen). Zunächst möchte ich vergleichen nur der 1. Spalten

file1.txt 

"aba" 0 0 
"abc" 0 1
"abd" 1 1 
"xxx" 0 0

file2.txt

"xyz" 0 0
"aba" 0 0
"xxx" 0 0
"abc" 1 1

Wie kann ich mit awk? Ich versuchte, einen Blick herum, aber die die ich gefunden habe, nur erschweren Beispiele. Was ist, wenn ich will, auch die anderen beiden Spalten auf der Vergleich? Die Ausgabe sollte mir die Anzahl der übereinstimmenden Elemente.

InformationsquelleAutor Titus Pullo | 2013-02-25
  1. 26

    Drucken die gemeinsame Elemente in beiden Dateien:

    $ awk 'NR==FNR{a[$1];next}$1 in a{print $1}' file1 file2
"aba"
"abc"
"xxx"

    Erklärung:

    NR und FNR sind awk Variablen zu speichern, dass die Gesamtzahl der Datensätze und die Anzahl der Datensätze in der aktuellen Dateien jeweils (Standard-Datensatz ist eine Zeile).

    NR==FNR # Only true when in the first file 
{
    a[$1] # Build associative array on the first column of the file
    next  # Skip all proceeding blocks and process next line
}
($1 in a) # Check in the value in column one of the second files is in the array
{
    # If so print it
    print $1
}

    Wenn Sie wollen, entsprechen die gesamten Zeilen, dann verwenden Sie $0:

    $ awk 'NR==FNR{a[$0];next}$0 in a{print $0}' file1 file2
"aba" 0 0
"xxx" 0 0

    Oder eine bestimmte Gruppe von Spalten:

    $ awk 'NR==FNR{a[$1,$2,$3];next}($1,$2,$3) in a{print $1,$2,$3}' file1 file2
"aba" 0 0
"xxx" 0 0
    • Stimmten up, speziell, weil von der Erklärung des awk-Skript, danke!
    • so drucken 2. cloumn von Datei1, wenn 1. cloumn von Datei2 gefunden in assoziatives array ?
    InformationsquelleAutor Chris Seymour
  2. 6

    Drucken die Anzahl der übereinstimmenden Elemente, hier ist ein Weg, mit awk:

    awk 'FNR==NR { a[$1]; next } $1 in a { c++ } END { print c }' file1.txt file2.txt

    Ergebnisse mit Ihrem input:

    3

    Wenn Sie möchten, fügen Sie zusätzliche Spalten (z.B. Spalten eins, zwei und drei), verwenden Sie eine pseudo-mehrdimensionale Arrays:

    awk 'FNR==NR { a[$1,$2,$3]; next } ($1,$2,$3) in a { c++ } END { print c }' file1.txt file2.txt

    Ergebnisse mit Ihrem input:

    2
    • +1. Da OP ' s Dateien haben nur 3 Spalten, kann es besser sein, benutzen Sie einfach a[$0] statt a[$1,$2,$3]. Aber dann alle nicht unsichtbare Leerzeichen in entweder-Datei kann zu unerwartetem Ausgang. Vielleicht mit rtrim oder gsub für die.
    • Verwendet es so -> za$ awk 'FNR==NR { a[$1]; next } !($1) END { print $1 }' test.csv-test2.csv ausdrucken der unmatching records.
    • Vielen Dank für die Stimmen, aber Sie brauchen nicht Ihre END block
    InformationsquelleAutor Steve
Schreibe einen Kommentar