Warten für die parallele batch-Skripten

Ich habe 4 batch-Dateien. Ich will laufen one.bat und two.bat auf einmal, gleichzeitig. Nach Fertigstellung dieser zwei batch-Dateien, three.bat und four.bat ausführen sollten, auf einmal, parallel. Ich habe versucht, mit vielen Möglichkeiten, aber mot, funktioniert einwandfrei.

Kann mir jemand helfen über diese?

InformationsquelleAutor sudhakar m | 2012-09-25
  1. 15

    Dies ist leicht getan mit einer wesentlich vereinfachte version der Lösung, die ich zur Verfügung gestellt für Die parallele Ausführung von shell-Prozessen. Finden Sie, dass die Lösung für eine Erklärung von, wie die Datei Verriegelung arbeitet.

    @echo off
setlocal
set "lock=%temp%\wait%random%.lock"

:: Launch one and two asynchronously, with stream 9 redirected to a lock file.
:: The lock file will remain locked until the script ends.
start "" cmd /c 9>"%lock%1" one.bat
start "" cmd /c 9>"%lock%2" two.bat

:Wait for both scripts to finish (wait until lock files are no longer locked)
1>nul 2>nul ping /n 2 ::1
for %%N in (1 2) do (
  ( rem
  ) 9>"%lock%%%N" || goto :Wait
) 2>nul

::delete the lock files
del "%lock%*"

:: Launch three and four asynchronously
start "" cmd /c three.bat
start "" cmd /c four.bat
    • Dieses wirkten groß für meine Bedürfnisse. Danke!!! Was ich auch nötig war, um sicherzustellen, dass diese Befehle lief mit Erfolg. So sieht es eher aus wie: start "" 9>"%sperren%1" CMD /C "ein.Fledermaus > one-log.txt 2>&1 && echo-Erfolg > one-success.txt" ... dann sicherstellen, dass jede -success.txt Datei existiert, und geben Sie die Ausgabe von jedem -log.txt.
    • ich möchte sehen, wie deine Lösung, dass die Kontrollen für den Erfolg in einem code-block, so dass es lesbar ist. Konnte Sie Bearbeiten die obige Antwort oder senden Sie Ihre code-block als Antwort?
    • zu warten, können Sie 1>nul 2>nul timeout 1 statt ping
    • Absolut, obwohl möchten Sie vielleicht werfen auch in der /nobreakoption. Allerdings TIMEOUT ist nicht verfügbar für XP, und das hatte einen signifikanten Marktanteil bei dieser Antwort wurde geschrieben. Zum Glück, XP wird immer weniger und weniger weit verbreitet ist, dass es jetzt nicht mehr unterstützt.
    • In Bezug auf Ihre Linie warten: 1>nul 2>nul ping /n 2 ::1 Was bedeutet die ::1 tun?
    • das ist die IPv6-loopback-Adresse

    InformationsquelleAutor dbenham
  2. 6

    Hatte ich das gleiche dilemma. Hier ist die Art, wie ich dieses Problem gelöst.
    Ich verwendet den Befehl Tasklist, um zu überwachen, ob der Prozess noch läuft oder nicht:

    :Loop
tasklist /fi "IMAGENAME eq <AAA>" /fi "Windowtitle eq <BBB>"|findstr /i /C:"<CCC>" >nul && (
timeout /t 3
GOTO :Loop
)
echo one.bat has stopped
pause

    Müssen Sie zwicken die

    <AAA>, <BBB>, <CCC>

    Werte in das Skript, so dass es richtig zu filtern, die für Ihren Prozess.

    Hoffe, das hilft.

    InformationsquelleAutor Jimbo
  3. 3

    Erstellen Sie einen master.bat-Datei, startet eine.Fledermaus und zwei.bat. Wenn man.Fledermaus und zwei.bat Ende, richtig, Sie echo-Datei, die Sie abgeschlossen haben

    if errorlevel 0 echo ok>c:\temp\OKONE
if errorlevel 0 echo ok>c:\temp\OKTWO

    Dann den master.Fledermaus warten auf die Existenz der beiden Dateien

    del c:\temp\OKONE
del c:\temp\OKTWO
start one.bat
start two.bat
:waitloop
if not exist c:\temp\OKONE (
    sleep 5
    goto waitloop
    )
if not exist c:\temp\OKTWO (
    sleep 5
    goto waitloop
    )
start three.bat
start four.bat

    Andere Möglichkeit ist, zu versuchen, mit dem /WAIT flag

    start /WAIT one.bat
start /WAIT two.bat

    aber Sie haben keine Kontrolle auf Fehler.

    Hier einige Referenzen

    http://malektips.com/xp_dos_0002.html

    http://ss64.com/nt/sleep.html

    http://ss64.com/nt/start.html

    • start /WAIT xxx wartet xxx beenden lassen, bevor die Ausführung übergeben, um die nächste Zeile in der batch-Datei. So one.bat würde zu beenden, bevor two.bat könnte sogar zu starten. Man KÖNNTE davon ausgehen, dass one.bat wird immer als Erster über die Ziellinie und verwenden start /wait two.bat, aber das ist schon eine Vermutung. BTW, du musst nicht start four.bat könnte man einfach call four.bat (oder noch lassen Sie die call wenn nichts anderes gemacht werden, nachdem die Ausführung four.bat ) und speichern Sie den Speicher, der verwendet werden würde durch die Einführung eines anderen Befehls-Prozessor.
    • Markiert als nützlich für die Auffassung geteilt, bevor die Erwähnung von start /WAIT. Auch stellen Sie sicher, dass Sie löschen Sie diese Dateien vom master.bat, bevor Sie starten.Fledermaus und zwei.bat.
    • Danke für die Anregung, bearbeitet die post entsprechend 🙂
    • genau das was ich brauche. Danke!!!
    InformationsquelleAutor Alessandro Da Rugna
Schreibe einen Kommentar