Was sind gute Anwendungen für Klasse Helfer?

Zuerst war ich etwas skeptisch über die Klasse Helfer. Aber dann Las ich einen interessanten blog-Eintrag und jetzt bin ich davon überzeugt, dass Sie tatsächlich nützlich.

Zum Beispiel, wenn Sie zusätzliche Funktionalität, die für eine vorhandene Instanz der Klasse, und aus irgendeinem Grund sind Sie nicht in der Lage, ändern Sie die vorhandene Quelle. Sie können eine Klasse erstellen Helfer, um diese Funktionalität hinzuzufügen.

Beispiel:

type
  TStringsHelper = class helper for TStrings
  public
    function IsEmpty: Boolean;
  end;

function TStringsHelper.IsEmpty: Boolean;
begin
  Result := Count = 0;
end;

Jedes mal, verwenden wir nun eine Instanz (eine Unterklasse von) TStrings, und TStringsHelper ist im Rahmen. Wir haben Zugriff auf die Methode IsEmpty.

Beispiel:

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Memo1.Lines.IsEmpty then
    Button1.Caption := 'Empty'
  else
    Button1.Caption := 'Filled';
end;

Hinweise:

• Klasse Helfer kann werden gespeichert in einer separaten Einheit, so können Sie Ihre eigene raffinierte Klasse Helfer. Sicher sein, geben diese Geräte einen leicht zu merkenden Namen wie ClassesHelpers für Helfer für die unit Classes).
• Es gibt auch aufzeichnen Helfer.
• Wenn es mehrere Klasse Helfern in Umfang, erwarten einige Probleme, die nur ein Helfer kann genutzt werden.

InformationsquelleAutor Toon Krijthe

Sind Sie sehr nützlich für plugins. Zum Beispiel, sagen wir Ihr Projekt definiert eine bestimmte Struktur der Daten und es ist gespeichert auf CD in einer bestimmten Weise. Aber dann ein anderes Programm hat etwas sehr ähnlich, aber die Daten-Datei ist unterschiedlich. Aber Sie wollen nicht, aufblasen Ihrer EXE-Datei mit einer Reihe von import-code für ein feature, dass viele Benutzer nicht brauchen, um zu verwenden. Sie können ein Plug-in framework und Importeure setzen in einem plugin arbeiten würde wie diese:

type
   TCompetitionToMyClass = class helper for TMyClass
   public
      constructor Convert(base: TCompetition);
   end;

Und definieren Sie dann den Konverter. Eine Einschränkung: eine Klasse Helfer ist nicht eine Klasse Freund. Diese Technik funktioniert nur, wenn es möglich ist, komplett die Einrichtung eines neuen TMyClass Objekt durch seine öffentlichen Methoden und Eigenschaften. Aber wenn Sie können, es funktioniert wirklich gut.

InformationsquelleAutor Mason Wheeler

Als GameCat zeigt, TStrings ist ein guter Kandidat, um zu vermeiden, dass einige schreiben:

type
  TMyObject = class
  public
    procedure DoSomething;
  end;

  TMyObjectStringsHelper = class helper for TStrings
  private
    function GetMyObject(const Name: string): TMyObject;
    procedure SetMyObject(const Name: string; const Value: TMyObject);
  public
    property MyObject[const Name: string]: TMyObject read GetMyObject write SetMyObject; default;
  end;

function TMyObjectStringsHelper.GetMyObject(const Name: string): TMyObject;
var
  idx: Integer;
begin
  idx := IndexOf(Name);
  if idx < 0 then
    result := nil
  else
    result := Objects[idx] as TMyObject;
end;

procedure TMyObjectStringsHelper.SetMyObject(const Name: string; const Value:
    TMyObject);
var
  idx: Integer;
begin
  idx := IndexOf(Name);
  if idx < 0 then
    AddObject(Name, Value)
  else
    Objects[idx] := Value;
end;

var
  lst: TStrings;
begin
  ...
  lst['MyName'] := TMyObject.Create; 
  ...
  lst['MyName'].DoSomething;
  ...
end;

Haben Sie jemals brauchen werden, um Zugriff auf multi-line-strings in der registry?

type
  TRegistryHelper = class helper for TRegistry
  public
    function ReadStrings(const ValueName: string): TStringDynArray;
  end;

function TRegistryHelper.ReadStrings(const ValueName: string): TStringDynArray;
var
  DataType: DWord;
  DataSize: DWord;
  Buf: PChar;
  P: PChar;
  Len: Integer;
  I: Integer;
begin
  result := nil;
  if RegQueryValueEx(CurrentKey, PChar(ValueName), nil, @DataType, nil, @DataSize) = ERROR_SUCCESS then begin
    if DataType = REG_MULTI_SZ then begin
      GetMem(Buf, DataSize + 2);
      try
        if RegQueryValueEx(CurrentKey, PChar(ValueName), nil, @DataType, PByte(Buf), @DataSize) = ERROR_SUCCESS then begin
          for I := 0 to 1 do begin
            if Buf[DataSize - 2] <> #0 then begin
              Buf[DataSize] := #0;
              Inc(DataSize);
            end;
          end;

          Len := 0;
          for I := 0 to DataSize - 1 do
            if Buf[I] = #0 then
              Inc(Len);
          Dec(Len);
          if Len > 0 then begin
            SetLength(result, Len);
            P := Buf;
            for I := 0 to Len - 1 do begin
              result[I] := StrPas(P);
              Inc(P, Length(P) + 1);
            end;
          end;
        end;
      finally
        FreeMem(Buf, DataSize);
      end;
    end;
  end;
end;

InformationsquelleAutor Uwe Raabe

Ich gesehen habe Sie verwendet für die Herstellung von verfügbaren Klassen-Methoden konsistent Klassen: Hinzufügen zu Öffnen/Schließen und ein - /Ausblenden, um alle Klassen, die von einem bestimmten "Typ" anstatt nur Aktive und Sichtbare Eigenschaften.

InformationsquelleAutor Jamo